less: enable options to be specified multiple times

modules/programs/less.nix

@@ -37,11 +37,14 @@ in
       options = lib.mkOption {
         type =
           with lib.types;
-          attrsOf (oneOf [
-            bool
-            int
-            str
-          ]);
+          let
+            scalar = oneOf [
+              bool
+              int
+              str
+            ];
+          in
+          attrsOf (either scalar (listOf scalar));
         default = { };
         description = "GNU-style options to be set via {env}`$LESS`.";
         example = {
@@ -59,9 +62,33 @@ in
     xdg.configFile."lesskey" = lib.mkIf (cfg.config != "") { text = cfg.config; };
 
     programs.less.config = lib.mkIf (cfg.options != { }) (
+      let
+        color = lib.intersectAttrs {
+          color = null;
+          D = null;
+        } cfg.options;
+        prompt = lib.intersectAttrs {
+          prompt = null;
+          P = null;
+        } cfg.options;
+        otherOptions = lib.removeAttrs cfg.options [
+          "color"
+          "D"
+          "P"
+          "prompt"
+        ];
+
+        toCommandLine = lib.cli.toGNUCommandLineShell { };
+
+        orderedOptions = lib.filter (x: x != { }) [
+          otherOptions
+          color # colors need to come after `--use-color`.
+          prompt # the prompt has to be the last option.
+        ];
+      in
       lib.mkBefore ''
         #env
-        LESS = ${lib.cli.toGNUCommandLineShell { } cfg.options}
+        LESS = ${lib.concatMapStringsSep " " toCommandLine orderedOptions}
       ''
     );
   };

tests/modules/programs/less/correct-option-order.nix

@@ -0,0 +1,21 @@
+{
+  programs.less = {
+    enable = true;
+    options = {
+      color = [
+        "HkK" # header: gray
+        "Mkb" # marks: blue
+      ];
+      prompt = "s%f";
+      quiet = true;
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/lesskey
+    assertFileContent home-files/.config/lesskey ${builtins.toFile "lesskey.expected" ''
+      #env
+      LESS = --quiet --color HkK --color Mkb --prompt s%f
+    ''}
+  '';
+}

tests/modules/programs/less/default.nix

@@ -1,4 +1,5 @@
 {
+  less-correct-option-order = ./correct-option-order.nix;
   less-custom-config = ./custom-config.nix;
   less-custom-options = ./custom-options.nix;
   less-custom-options-and-config = ./custom-options-and-config.nix;