Add notice_error function for rescued exceptions

lib/new_relic.ex

@@ -289,6 +289,25 @@ defmodule NewRelic do
   defdelegate increment_custom_metric(name, count \\ 1),
     to: NewRelic.Harvest.Collector.Metric.Harvester
 
+  @doc """
+  Report an Exception inside a Transaction.
+
+  This should only be used when you `rescue` an exception inside a Transaction,
+  but still want to report it. All un-rescued exceptions are already reported as errors.
+
+  ## Example
+
+  ```elixir
+  try do
+    raise RuntimeError
+  rescue
+    exception -> NewRelic.notice_error(exception, __STACKTRACE__)
+  end
+  ```
+  """
+  @spec notice_error(Exception.t(), Exception.stacktrace()) :: :ok
+  defdelegate notice_error(exception, stacktrace), to: NewRelic.Transaction.Reporter
+
   @doc false
   defdelegate enable_erlang_trace, to: NewRelic.Transaction.ErlangTraceManager
 

lib/new_relic/transaction/reporter.ex

@@ -84,6 +84,14 @@ defmodule NewRelic.Transaction.Reporter do
     :ok
   end
 
+  def notice_error(exception, stacktrace) do
+    if NewRelic.Config.feature?(:error_collector) do
+      error(%{kind: :error, reason: exception, stack: stacktrace})
+    end
+
+    :ok
+  end
+
   def error(error) do
     Transaction.Sidecar.add(transaction_error: {:error, error})
   end

test/other_transaction_test.exs

@@ -246,4 +246,30 @@ defmodule OtherTransactionTest do
 
     refute spansaction.attributes[:error]
   end
+
+  test "Report a raise that is rescued inside a Transaction" do
+    TestHelper.restart_harvest_cycle(Collector.TransactionErrorEvent.HarvestCycle)
+
+    {:ok, pid} =
+      Task.start(fn ->
+        NewRelic.start_transaction("TestTransaction", "Rescued")
+
+        try do
+          raise RuntimeError, "RESCUED"
+        rescue
+          exception ->
+            NewRelic.notice_error(exception, __STACKTRACE__)
+            :move_on
+        end
+      end)
+
+    Process.monitor(pid)
+    assert_receive {:DOWN, _ref, :process, ^pid, _reason}, 1_000
+
+    events = TestHelper.gather_harvest(Collector.TransactionErrorEvent.Harvester)
+
+    assert Enum.find(events, fn [intrinsic, _, _] ->
+             intrinsic[:"error.message"] =~ "RESCUED"
+           end)
+  end
 end