Add notify_service support to dropin_file (#191)

It is very common that a drop in file should notify a service that's
managed elsewhere. This adds a parameter to do so which then uses a
collector.

Author: ekohl

REFERENCE.md

@@ -374,6 +374,7 @@ The following parameters are available in the `systemd::dropin_file` defined typ
 * [`group`](#group)
 * [`mode`](#mode)
 * [`show_diff`](#show_diff)
+* [`notify_service`](#notify_service)
 * [`unit`](#unit)
 * [`filename`](#filename)
 * [`ensure`](#ensure)
@@ -462,6 +463,14 @@ Whether to show the diff when updating dropin file
 
 Default value: ``true``
 
+##### <a name="notify_service"></a>`notify_service`
+
+Data type: `Boolean`
+
+Notify a service for the unit, if it exists
+
+Default value: ``false``
+
 ##### <a name="unit"></a>`unit`
 
 Data type: `Systemd::Unit`

manifests/dropin_file.pp

@@ -40,6 +40,9 @@
 # @param show_diff
 #   Whether to show the diff when updating dropin file
 #
+# @param notify_service
+#   Notify a service for the unit, if it exists
+#
 define systemd::dropin_file (
   Systemd::Unit                               $unit,
   Systemd::Dropin                             $filename                = $name,
@@ -53,6 +56,7 @@
   String                                      $group                   = 'root',
   String                                      $mode                    = '0444',
   Boolean                                     $show_diff               = true,
+  Boolean                                     $notify_service          = false,
 ) {
   include systemd
 
@@ -65,8 +69,10 @@
     }
   }
 
+  $full_filename = "${path}/${unit}.d/${filename}"
+
   if $ensure != 'absent' {
-    ensure_resource('file', "${path}/${unit}.d", {
+    ensure_resource('file', dirname($full_filename), {
         ensure                  => directory,
         owner                   => 'root',
         group                   => 'root',
@@ -76,7 +82,7 @@
     })
   }
 
-  file { "${path}/${unit}.d/${filename}":
+  file { $full_filename:
     ensure                  => $_ensure,
     content                 => $content,
     source                  => $source,
@@ -87,4 +93,12 @@
     selinux_ignore_defaults => $selinux_ignore_defaults,
     show_diff               => $show_diff,
   }
+
+  if $notify_service {
+    File[$full_filename] ~> Service <| title == $unit or name == $unit |>
+    if $unit =~ /\.service$/ {
+      $short_service_name = regsubst($unit, /\.service$/, '')
+      File[$full_filename] ~> Service <| title == $short_service_name or name == $short_service_name |>
+    }
+  }
 }

spec/defines/dropin_file_spec.rb

@@ -35,6 +35,36 @@
           )
         }
 
+        context 'notifies services' do
+          let(:params) do
+            super().merge(notify_service: true)
+          end
+          let(:filename) { "/etc/systemd/system/#{params[:unit]}.d/#{title}" }
+          let(:pre_condition) do
+            <<-PUPPET
+            service { ['test', 'test.service']:
+            }
+            PUPPET
+          end
+
+          it { is_expected.to compile.with_all_deps }
+          it { is_expected.to contain_service('test').that_subscribes_to("File[#{filename}]") }
+          it { is_expected.to contain_service('test.service').that_subscribes_to("File[#{filename}]") }
+
+          context 'with overridden name' do
+            let(:pre_condition) do
+              <<-PUPPET
+              service { 'myservice':
+                name => 'test',
+              }
+              PUPPET
+            end
+
+            it { is_expected.to compile.with_all_deps }
+            it { is_expected.to contain_service('myservice').that_subscribes_to("File[#{filename}]") }
+          end
+        end
+
         context 'with selinux_ignore_defaults set to true' do
           let(:params) do
             super().merge(selinux_ignore_defaults: true)