main.nf

#!/usr/bin/env nextflow

/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    IMPORT FUNCTIONS / MODULES / SUBWORKFLOWS / WORKFLOWS
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/

nextflow.enable.dsl=2

include { ALIGN_MINIMAP2         } from './modules/align_minimap2'
include { SAMTOOLS_FLAGSTAT      } from './modules/samtools_flagstat'
include { SAMTOOLS_STATS         } from './modules/samtools_stats'
include { MOSDEPTH               } from './modules/mosdepth'
include { CRAMINO                } from './modules/cramino'

include { SNIFFLES_SINGLE        } from './modules/sniffles_single'
include { SNIFFLES_MERGE         } from './modules/sniffles_merge'
include { SNIFFLES_SPLIT_SINGLE  } from './modules/sniffles_split_single'
include { SNIFFLES_SPLIT_COHORT  } from './modules/sniffles_split_cohort'

include {
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_SINGLE_FULL
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_SINGLE_BND
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_SINGLE_NONBND    
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_COHORT_FULL
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_COHORT_BND
    VCF_SV_SUMMARY as VCF_SV_SUMMARY_COHORT_NONBND
} from './modules/vcf_sv_summary'

include {
    VCF_BCFTOOLS_STATS as VCF_BCFTOOLS_STATS_DV_SINGLE
} from './modules/vcf_bcftools_stats'


include { SNIFFLES2_PLOT_SINGLE  } from './modules/sniffles2_plot_single'
include { SNIFFLES2_PLOT_MULTI   } from './modules/sniffles2_plot_multi'

include { CLAIRSTO_SINGLE        } from './modules/clairsto_single'
include { SMALLVAR_MERGE_SINGLE  } from './modules/smallvar_merge_single'
include { SMALLVAR_SPLIT_SINGLE  } from './modules/smallvar_split_single'
include { SMALLVAR_SUMMARY       } from './modules/smallvar_summary'
include { SMALLVAR_COHORT_TABLE  } from './modules/smallvar_cohort_table'

include { MULTIQC                } from './modules/multiqc'


def validateParams() {
    if( !params.samplesheet ) error "Missing --samplesheet"
    if( !params.reference_mmi ) error "Missing --reference_mmi"
    if( !params.reference_fasta ) error "Missing --reference_fasta"

    if( !file(params.samplesheet).exists() ) error "Samplesheet not found: ${params.samplesheet}"
    if( !file(params.reference_mmi).exists() ) error "Reference MMI not found: ${params.reference_mmi}"
    if( !file(params.reference_fasta).exists() ) error "Reference FASTA not found: ${params.reference_fasta}"
    if( params.tandem_repeats && !file(params.tandem_repeats).exists() ) error "Tandem repeats BED not found: ${params.tandem_repeats}"
}

/*

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    RUN MAIN WORKFLOW
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/

workflow {

    main:
    validateParams()

    samples_ch = channel
        .fromPath(params.samplesheet)
        .splitCsv(header: true)
        .map { row ->
            if( !row.sample_id ) error "Samplesheet row missing sample_id: ${row}"
            if( !row.fastq_dir ) error "Samplesheet row missing fastq_dir: ${row}"
            tuple(row.sample_id as String, file(row.fastq_dir))
        }

    ref_mmi_ch   = channel.value(file(params.reference_mmi))
    ref_fasta = file(params.reference_fasta)
    ref_fai = file(params.reference_fai)
    tr_bed_val   = params.tandem_repeats ? file(params.tandem_repeats) : null

    /*
     * Alignment + BAM QC
     */
    bam_ch      = ALIGN_MINIMAP2(samples_ch, ref_mmi_ch)
    flagstat_ch = SAMTOOLS_FLAGSTAT(bam_ch)
    stats_ch    = SAMTOOLS_STATS(bam_ch)
    mosdepth_ch = MOSDEPTH(bam_ch)
    cramino_ch  = CRAMINO(bam_ch)

    /*
     * Sniffles single
     */
    sniffles_input_ch = bam_ch.map { x ->
        tuple(x[0], x[1], x[2], tr_bed_val, ref_fasta)
    }
    sniffles_single_ch = SNIFFLES_SINGLE(sniffles_input_ch)

    /*
     * Sniffles cohort
     */
    snf_files_ch = sniffles_single_ch
        .map { x -> x[3] }
        .collect()

    cohort_ch = SNIFFLES_MERGE(snf_files_ch, tr_bed_val, ref_fasta)

    /*
     * Split Sniffles outputs
     */
    sniffles_split_single_ch = SNIFFLES_SPLIT_SINGLE(sniffles_single_ch)
    sniffles_split_cohort_ch = SNIFFLES_SPLIT_COHORT(cohort_ch)

    /*
     * Full SV summaries
     */
    full_sv_summary_input_single_ch = sniffles_single_ch.map { x ->
        tuple("${x[0]}.full_sv", x[1], x[2])
    }
    full_sv_summary_single_ch = VCF_SV_SUMMARY_SINGLE_FULL(full_sv_summary_input_single_ch)

    // full_sv_stats_input_single_ch = sniffles_single_ch.map { x ->
    //     tuple("${x[0]}.full_sv", x[1], x[2])
    // }
    // full_sv_stats_single_ch = VCF_BCFTOOLS_STATS_SINGLE_FULL(full_sv_stats_input_single_ch)

    full_sv_summary_input_cohort_ch = cohort_ch.map { x ->
        tuple("cohort.full_sv", x[0], x[1])
    }
    full_sv_summary_cohort_ch = VCF_SV_SUMMARY_COHORT_FULL(full_sv_summary_input_cohort_ch)

    // full_sv_stats_input_cohort_ch = cohort_ch.map { x ->
    // tuple("cohort.full_sv", x[0], x[1])
    // }
    // full_sv_stats_cohort_ch = VCF_BCFTOOLS_STATS_COHORT_FULL(full_sv_stats_input_cohort_ch)

    /*
     * BND summaries
     */
    bnd_summary_input_single_ch = sniffles_split_single_ch.map { x ->
        tuple("${x[0]}.bnd", x[1], x[2])
    }
    bnd_summary_single_ch = VCF_SV_SUMMARY_SINGLE_BND(bnd_summary_input_single_ch)

    // bnd_stats_input_single_ch = sniffles_split_single_ch.map { x ->
    //     tuple("${x[0]}.bnd", x[1], x[2])
    // }
    // bnd_stats_single_ch = VCF_BCFTOOLS_STATS_SINGLE_BND(bnd_stats_input_single_ch)

    bnd_summary_input_cohort_ch = sniffles_split_cohort_ch.map { x ->
        tuple("cohort.bnd", x[0], x[1])
    }
    bnd_summary_cohort_ch = VCF_SV_SUMMARY_COHORT_BND(bnd_summary_input_cohort_ch)

    // bnd_stats_input_cohort_ch = sniffles_split_cohort_ch.map { x ->
    //     tuple("cohort.bnd", x[0], x[1])
    // }
    // bnd_stats_cohort_ch = VCF_BCFTOOLS_STATS_COHORT_BND(bnd_stats_input_cohort_ch)

    /*
     * non-BND summaries
     */
    nonbnd_summary_input_single_ch = sniffles_split_single_ch.map { x ->
        tuple("${x[0]}.nonbnd", x[3], x[4])
    }
    nonbnd_summary_single_ch = VCF_SV_SUMMARY_SINGLE_NONBND(nonbnd_summary_input_single_ch)

    // nonbnd_stats_input_single_ch = sniffles_split_single_ch.map { x ->
    //     tuple("${x[0]}.nonbnd", x[3], x[4])
    // }
    // nonbnd_stats_single_ch = VCF_BCFTOOLS_STATS_SINGLE_NONBND(nonbnd_stats_input_single_ch)

    nonbnd_summary_input_cohort_ch = sniffles_split_cohort_ch.map { x ->
        tuple("cohort.nonbnd", x[2], x[3])
    }
    nonbnd_summary_cohort_ch = VCF_SV_SUMMARY_COHORT_NONBND(nonbnd_summary_input_cohort_ch)

    // nonbnd_stats_input_cohort_ch = sniffles_split_cohort_ch.map { x ->
    //     tuple("cohort.nonbnd", x[2], x[3])
    // }
    // nonbnd_stats_cohort_ch = VCF_BCFTOOLS_STATS_COHORT_NONBND(nonbnd_stats_input_cohort_ch)

    /*
     * Sniffles plots
     */
    sniffles2_plot_single_ch = SNIFFLES2_PLOT_SINGLE(sniffles_single_ch)

    sniffles2_plot_multi_ch = SNIFFLES2_PLOT_MULTI(cohort_ch)

    /*
     * ClairS-TO per sample
     */
    clairsto_input_ch = bam_ch.map { x ->
        tuple(x[0], x[1], x[2], ref_fasta, ref_fai)
    }

    clairsto_ch = CLAIRSTO_SINGLE(clairsto_input_ch)

    smallvar_merged_ch = SMALLVAR_MERGE_SINGLE(clairsto_ch)
    smallvar_split_ch  = SMALLVAR_SPLIT_SINGLE(smallvar_merged_ch)
    smallvar_summary_ch = SMALLVAR_SUMMARY(smallvar_split_ch)

    smallvar_cohort_input_ch = smallvar_merged_ch
        .map { x -> x[1] }
        .collect()

    smallvar_cohort_table_ch = SMALLVAR_COHORT_TABLE(smallvar_cohort_input_ch)

    /*
     * MultiQC
     */
    if( params.run_multiqc ) {
        multiqc_input_ch = flagstat_ch
            .mix(stats_ch)
            .mix(mosdepth_ch)
            .mix(cramino_ch)
            .mix(full_sv_summary_single_ch)
            .mix(full_sv_summary_cohort_ch)
            .mix(bnd_summary_single_ch)
            .mix(bnd_summary_cohort_ch)
            .mix(nonbnd_summary_single_ch)
            .mix(nonbnd_summary_cohort_ch)
            .mix(smallvar_summary_ch)
            .mix(smallvar_cohort_table_ch)
            .collect()

        MULTIQC(multiqc_input_ch)
    }


    bam_ch
    sniffles_single_ch
    cohort_ch
    clairsto_ch
    smallvar_merged_ch
    sniffles2_plot_single_ch
    sniffles2_plot_multi_ch
}

/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    THE END
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/