-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathUR.sol
executable file
·204 lines (193 loc) · 8.25 KB
/
UR.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;
import {ERC165, IERC165} from "./ERC165.sol";
import {ENS} from "@ensdomains/ens-contracts/contracts/registry/ENS.sol";
import {IExtendedResolver} from "@ensdomains/ens-contracts/contracts/resolvers/profiles/IExtendedResolver.sol";
import {
OffchainLookup,
OffchainLookupTuple,
CCIPReadProtocol
} from "@unruggable/CCIPReader.sol/contracts/CCIPReadProtocol.sol";
import {IBatchedGateway, BatchedGatewayQuery} from "./IBatchedGateway.sol";
import {IResolveMulticall} from "./IResolveMulticall.sol";
import {IUR, Lookup, Response, ResponseBits, LengthMismatch} from "./IUR.sol";
import {DNSCoder} from "./DNSCoder.sol";
contract UR is IUR, IERC165 {
address public immutable registry; // not typed so the header is dependancy-free
string[] public batchedGateways;
constructor(address ens, string[] memory gateways) {
registry = ens;
batchedGateways = gateways;
}
function supportsInterface(bytes4 x) external pure returns (bool) {
return type(IERC165).interfaceId == x || type(IUR).interfaceId == x;
}
function lookupName(bytes memory dns) public view returns (Lookup memory lookup) {
// https://docs.ens.domains/ensip/10
uint256 offset;
address resolver;
(bytes32 node, uint256 next) = DNSCoder.namehash(dns, 0);
lookup.dns = dns;
lookup.node = node;
while (true) {
resolver = ENS(registry).resolver(node);
if (resolver != address(0)) break;
if (node == bytes32(0)) return lookup; // no match
offset = next;
(node, next) = DNSCoder.namehash(dns, next);
}
if (ERC165.supportsInterface(resolver, type(IExtendedResolver).interfaceId)) {
lookup.extended = true;
} else if (offset != 0) {
return lookup; // non-extended resolver requires exact match
}
lookup.resolver = resolver;
lookup.basenode = node; // node of resolver
lookup.offset = offset;
}
function resolve(bytes memory dns, bytes[] memory calls, string[] memory gateways)
external
view
returns (Lookup memory lookup, Response[] memory res)
{
lookup = lookupName(dns);
if (lookup.resolver == address(0)) return (lookup, res);
res = new Response[](calls.length); // create result storage
if (gateways.length == 0) gateways = batchedGateways; // use default
bytes[] memory offchainCalls = new bytes[](calls.length);
uint256 offchain; // count how many offchain
for (uint256 i; i < res.length; i++) {
bytes memory call = _injectNode(calls[i], lookup.node);
(bool ok, bytes memory v) = _callResolver(lookup, call);
Response memory r = res[i];
r.call = call; // remember calldata (post-inject, pre-resolve)
r.data = v;
if (!ok && bytes4(v) == OffchainLookup.selector) {
// note: until ERC-3668 is fixed, all offchain are batched
r.bits |= ResponseBits.OFFCHAIN | ResponseBits.BATCHED;
offchainCalls[offchain++] = call;
} else {
if (!ok) r.bits |= ResponseBits.ERROR;
r.bits |= ResponseBits.RESOLVED;
}
}
if (offchain > 1) {
assembly {
mstore(offchainCalls, offchain)
}
(bool ok, bytes memory v) =
_callResolver(lookup, abi.encodeCall(IResolveMulticall.multicall, (offchainCalls)));
if (!ok && bytes4(v) == OffchainLookup.selector) {
Response[] memory multi = new Response[](1);
multi[0].data = v;
_revertOffchain(lookup, multi, res, gateways);
}
}
_revertOffchain(lookup, res, new Response[](0), gateways);
}
function _callResolver(Lookup memory lookup, bytes memory call) internal view returns (bool ok, bytes memory v) {
if (lookup.extended) call = abi.encodeCall(IExtendedResolver.resolve, (lookup.dns, call)); // wrap
(ok, v) = lookup.resolver.staticcall(call); // call it
if (ok && lookup.extended) v = abi.decode(v, (bytes)); // unwrap
}
function _revertOffchain(
Lookup memory lookup,
Response[] memory res,
Response[] memory alt,
string[] memory gateways
) internal view {
BatchedGatewayQuery[] memory queries = new BatchedGatewayQuery[](res.length);
uint256 missing;
for (uint256 i; i < res.length; i++) {
Response memory r = res[i];
if ((r.bits & ResponseBits.RESOLVED) == 0) {
OffchainLookupTuple memory x = CCIPReadProtocol.decode(r.data);
queries[missing++] = BatchedGatewayQuery(x.sender, x.gateways, x.request);
}
}
if (missing > 0) {
assembly {
mstore(queries, missing)
}
revert OffchainLookup(
address(this),
gateways,
abi.encodeCall(IBatchedGateway.query, (queries)),
this.resolveCallback.selector,
abi.encode(lookup, res, alt, gateways) // batchedCarry
);
}
}
function resolveCallback(bytes calldata ccip, bytes calldata batchedCarry)
external
view
returns (Lookup memory lookup, Response[] memory res)
{
Response[] memory alt;
string[] memory gateways;
(lookup, res, alt, gateways) = abi.decode(batchedCarry, (Lookup, Response[], Response[], string[]));
(bool[] memory failures, bytes[] memory responses) = abi.decode(ccip, (bool[], bytes[]));
if (failures.length != responses.length) revert LengthMismatch();
uint256 expected;
for (uint256 i; i < res.length; i++) {
Response memory r = res[i];
if ((r.bits & ResponseBits.RESOLVED) == 0) {
bytes memory v = responses[expected];
if (failures[expected++]) {
r.bits |= ResponseBits.RESOLVED | ResponseBits.ERROR; // ccip-read failed
} else {
OffchainLookupTuple memory x = CCIPReadProtocol.decode(r.data);
bool ok;
(ok, v) = x.sender.staticcall(abi.encodeWithSelector(x.selector, v, x.carry));
if (ok) {
if (bytes4(x.request) == IExtendedResolver.resolve.selector) {
v = abi.decode(v, (bytes)); // unwrap
}
r.bits |= ResponseBits.RESOLVED;
} else if (bytes4(v) != OffchainLookup.selector) {
r.bits |= ResponseBits.RESOLVED | ResponseBits.ERROR; // callback failed
}
}
r.data = v;
}
}
if (expected != responses.length) revert LengthMismatch();
_revertOffchain(lookup, res, alt, gateways);
if (alt.length > 0) {
if ((res[0].bits & ResponseBits.ERROR) != 0) {
_revertOffchain(lookup, alt, new Response[](0), gateways); // try separate
} else {
_decodeMulticall(res[0].data, alt);
res = alt;
}
}
}
// utils
function _decodeMulticall(bytes memory encoded, Response[] memory res) internal pure {
bytes[] memory m = abi.decode(encoded, (bytes[]));
uint256 expected;
for (uint256 i; i < res.length; i++) {
Response memory r = res[i];
if ((r.bits & ResponseBits.RESOLVED) == 0) {
bytes memory v = m[expected++];
r.data = v;
if ((v.length & 31) != 0) r.bits |= ResponseBits.ERROR;
r.bits |= ResponseBits.RESOLVED;
}
}
if (expected != m.length) revert LengthMismatch();
}
function _injectNode(bytes memory v, bytes32 node) internal pure returns (bytes memory) {
bytes32 node0;
assembly {
node0 := mload(add(v, 36)) // old node
}
if (node0 == bytes32(0)) {
v = abi.encodePacked(v); // make copy
assembly {
mstore(add(v, 36), node) // inject new node
}
}
return v;
}
}