Add json-in-json.

Author: treeform

README.md

@@ -222,7 +222,7 @@ Gives us:
 "10/13"
 ```
 
-### Static writing with `toStaticJson`.
+## Static writing with `toStaticJson`.
 
 Some times you have or const json and you want to write it in a static way. There is a special function for that:
 
@@ -232,7 +232,7 @@ thing.toStaticJson()
 
 Make sure `thing` is a `static` or a `const` value and you will get a compile time string with your JSON.
 
-### Full support for case variant objects.
+## Full support for case variant objects.
 
 Case variant objects like this are fully supported:
 
@@ -246,3 +246,16 @@ t=oe RefNode = ref object
 The discriminator do no have to come first, if they do come in the middle this
 library will scan the object, find the discriminator field, then rewind and
 parse the object normally.
+
+
+## Full support for json-in-json.
+
+Some times your json objects could contain arbitrary json structures,
+maybe event user defined, that could only be walked as json nodes. This library allows you to parse json-in-json were you parse some of the structure as real nim objects but leave some parts of it as Json Nodes to be walked later with code:
+
+```nim
+type Entry = object
+  name: string
+  data: JsonNode
+entry.toJson.fromJson(Entry)
+```

src/jsony.nim

@@ -1,4 +1,4 @@
-import jsony/objvar, strutils, tables, unicode
+import jsony/objvar, strutils, tables, unicode, json
 
 type JsonError* = object of ValueError
 
@@ -13,6 +13,7 @@ proc parseHook*[T: object|ref object](s: string, i: var int, v: var T)
 proc parseHook*[T](s: string, i: var int, v: var Table[string, T])
 proc parseHook*[T: tuple](s: string, i: var int, v: var T)
 proc parseHook*[T: array](s: string, i: var int, v: var T)
+proc parseHook*(s: string, i: var int, v: var JsonNode)
 
 template error(msg: string, i: int) =
   ## Shortcut to raise an exception.
@@ -334,6 +335,66 @@ proc parseHook*[T](s: string, i: var int, v: var Table[string, T]) =
       break
   eatChar(s, i, '}')
 
+proc parseHook*(s: string, i: var int, v: var JsonNode) =
+  ## Parses a regular json node.
+  eatSpace(s, i)
+  if i < s.len and s[i] == '{':
+    v = newJObject()
+    eatChar(s, i, '{')
+    while i < s.len:
+      eatSpace(s, i)
+      if i < s.len and s[i] == '}':
+        break
+      var k: string
+      parseHook(s, i, k)
+      eatChar(s, i, ':')
+      var e: JsonNode
+      parseHook(s, i, e)
+      v[k] = e
+      eatSpace(s, i)
+      if i < s.len and s[i] == ',':
+        inc i
+    eatChar(s, i, '}')
+  elif i < s.len and s[i] == '[':
+    v = newJArray()
+    eatChar(s, i, '[')
+    while i < s.len:
+      eatSpace(s, i)
+      if i < s.len and s[i] == ']':
+        break
+      var e: JsonNode
+      parseHook(s, i, e)
+      v.add(e)
+      eatSpace(s, i)
+      if i < s.len and s[i] == ',':
+        inc i
+    eatChar(s, i, ']')
+  elif i < s.len and s[i] == '"':
+    var str: string
+    parseHook(s, i, str)
+    v = newJString(str)
+  else:
+    var data = parseSymbol(s, i)
+    if data == "null":
+      v = newJNull()
+    elif data == "true":
+      v = newJBool(true)
+    elif data == "false":
+      v = newJBool(false)
+    elif data.len > 0 and data[0] in {'0'..'9'}:
+      if "." in data:
+        try:
+          v = newJFloat(parseFloat(data))
+        except ValueError:
+          error("Invalid integer.", i)
+      else:
+        try:
+          v = newJInt(parseInt(data))
+        except ValueError:
+          error("Invalid float.", i)
+    else:
+      error("Unexpected.", i)
+
 proc fromJson*[T](s: string, x: typedesc[T]): T =
   ## Takes json and outputs the object it represents.
   ## * Extra json fields are ignored.
@@ -342,6 +403,11 @@ proc fromJson*[T](s: string, x: typedesc[T]): T =
   var i = 0
   s.parseHook(i, result)
 
+proc fromJson*(s: string): JsonNode =
+  ## Takes json parses it into `JsonNode`s.
+  var i = 0
+  s.parseHook(i, result)
+
 proc dumpHook*(s: var string, v: bool)
 proc dumpHook*(s: var string, v: uint|uint8|uint16|uint32|uint64)
 proc dumpHook*(s: var string, v: int|int8|int16|int32|int64)
@@ -526,6 +592,40 @@ proc dumpHook*(s: var string, v: ref object) =
   else:
     s.dumpHook(v[])
 
+proc dumpHook*(s: var string, v: JsonNode) =
+  ## Dumps a regular json node.
+  case v.kind:
+  of JObject:
+    s.add '{'
+    var i = 0
+    for k, e in v.pairs:
+      if i != 0:
+        s.add ","
+      s.dumpHook(k)
+      s.add ':'
+      s.dumpHook(e)
+      inc i
+    s.add '}'
+  of JArray:
+    s.add '['
+    var i = 0
+    for e in v:
+      if i != 0:
+        s.add ","
+      s.dumpHook(e)
+      inc i
+    s.add ']'
+  of JNull:
+    s.add "null"
+  of JInt:
+    s.dumpHook(v.getInt)
+  of JFloat:
+    s.dumpHook(v.getFloat)
+  of JString:
+    s.dumpHook(v.getStr)
+  of JBool:
+    s.dumpHook(v.getBool)
+
 proc toJson*[T](v: T): string =
   dumpHook(result, v)
 

tests/fuzz.nim

@@ -45,8 +45,8 @@ for i in 0 ..< 10000:
     data = treeStr
     pos = rand(data.len)
     value = rand(255).char
-    # pos = 2284
-    # value = 152.char
+    #pos = 18716
+    #value = 125.char
 
   data[pos] = value
   echo &"{i} {pos} {value.uint8}"
@@ -56,9 +56,22 @@ for i in 0 ..< 10000:
   except JsonError:
     discard
 
-  data = data[0 ..< pos]
+  var data2 = data[0 ..< pos]
   try:
-    let node = data.fromJson(Node)
+    let node = data2.fromJson(Node)
+    doAssert node != nil
+  except JsonError:
+    discard
+
+  # JsonNode
+  try:
+    let node = data.fromJson()
+    doAssert node != nil
+  except JsonError:
+    discard
+
+  try:
+    let node = data2.fromJson()
     doAssert node != nil
   except JsonError:
     discard

tests/test_json_in_json.nim

@@ -0,0 +1,23 @@
+import jsony, strutils, json
+
+block:
+  type Entry = object
+    name: string
+    data: JsonNode
+
+  var entry = Entry()
+  entry.name = "json-in-json"
+  entry.data = %*{
+    "random-data": "here",
+    "number": 123,
+    "number2": 123.456,
+    "array": @[1, 2, 3],
+    "active": true,
+    "null": nil
+  }
+
+  doAssert entry.toJson() == """{"name":"json-in-json","data":{"random-data":"here","number":123,"number2":123.456,"array":[1,2,3],"active":true,"null":null}}"""
+  doAssert $entry.toJson.fromJson(Entry) == """(name: "json-in-json", data: {"random-data":"here","number":123,"number2":123.456,"array":[1,2,3],"active":true,"null":null})"""
+
+  let s = """{"name":"json-in-json","data":{"random-data":"here","number":123,"number2":123.456,"array":[1,2,3],"active":true,"null":null}}"""
+  doAssert $s.fromJson() == """{"name":"json-in-json","data":{"random-data":"here","number":123,"number2":123.456,"array":[1,2,3],"active":true,"null":null}}"""