terraform-aws-observability/modules/cloudwatch-log-group/main.tf at main · tedilabs/terraform-aws-observability · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
locals {
  metadata = {
    package = "terraform-aws-observability"
    version = trimspace(file("${path.module}/../../VERSION"))
    module  = basename(path.module)
    name    = var.name
  }
  module_tags = var.module_tags_enabled ? {
    "module.terraform.io/package"   = local.metadata.package
    "module.terraform.io/version"   = local.metadata.version
    "module.terraform.io/name"      = local.metadata.module
    "module.terraform.io/full-name" = "${local.metadata.package}/${local.metadata.module}"
    "module.terraform.io/instance"  = local.metadata.name
  } : {}
}


###################################################
# CloudWatch Log Group
###################################################

# INFO: Not supported attributes
# - `name_prefix` (Not used)
resource "aws_cloudwatch_log_group" "this" {
  name         = var.name
  skip_destroy = var.skip_destroy

  retention_in_days = var.retention_in_days
  kms_key_id        = var.encryption_kms_key

  tags = merge(
    {
      "Name" = local.metadata.name
    },
    local.module_tags,
    var.tags,
  )
}


###################################################
# Log Streams for CloudWatch Log Group
###################################################

resource "aws_cloudwatch_log_stream" "this" {
  for_each = var.streams

  name           = each.key
  log_group_name = aws_cloudwatch_log_group.this.name
}


###################################################
# Metric Filters for CloudWatch Log Group
###################################################

resource "aws_cloudwatch_log_metric_filter" "this" {
  for_each = {
    for metric_filter in var.metric_filters :
    metric_filter.name => metric_filter
  }

  log_group_name = aws_cloudwatch_log_group.this.name
  name           = each.key
  pattern        = each.value.pattern

  dynamic "metric_transformation" {
    for_each = [each.value.metric]
    iterator = metric

    content {
      namespace = metric.value.namespace
      name      = metric.value.name

      value         = metric.value.value
      default_value = metric.value.default_value
      dimensions    = metric.value.dimensions
      unit          = metric.value.unit
    }
  }
}