|
| 1 | +locals { |
| 2 | + versioning_mfa_status = { |
| 3 | + "ENABLED" = "Enabled" |
| 4 | + "DISABLED" = "Disabled" |
| 5 | + "SUSPENDED" = "Suspended" |
| 6 | + } |
| 7 | + |
| 8 | + lifecycle_rules = { |
| 9 | + for rule in var.lifecycle_rules : |
| 10 | + rule.id => rule |
| 11 | + } |
| 12 | +} |
| 13 | + |
| 14 | + |
| 15 | +################################################### |
| 16 | +# Versioning for S3 Bucket |
| 17 | +################################################### |
| 18 | + |
| 19 | +# TODO: `expected_bucket_owner` |
| 20 | +resource "aws_s3_bucket_versioning" "this" { |
| 21 | + bucket = aws_s3_bucket.this.bucket |
| 22 | + |
| 23 | + mfa = try(var.versioning_mfa_deletion.device, null) |
| 24 | + |
| 25 | + versioning_configuration { |
| 26 | + status = local.versioning_mfa_status[var.versioning_status] |
| 27 | + mfa_delete = try(var.versioning_mfa_deletion.enabled, false) ? "Enabled" : "Disabled" |
| 28 | + } |
| 29 | +} |
| 30 | + |
| 31 | + |
| 32 | +################################################### |
| 33 | +# Lifecycle Rules for S3 Bucket |
| 34 | +################################################### |
| 35 | + |
| 36 | +# TODO: `expected_bucket_owner` |
| 37 | +resource "aws_s3_bucket_lifecycle_configuration" "this" { |
| 38 | + bucket = aws_s3_bucket.this.bucket |
| 39 | + |
| 40 | + dynamic "rule" { |
| 41 | + for_each = var.lifecycle_rules |
| 42 | + |
| 43 | + content { |
| 44 | + id = rule.value.id |
| 45 | + status = try(rule.value.enabled, true) ? "Enabled" : "Disabled" |
| 46 | + |
| 47 | + dynamic "abort_incomplete_multipart_upload" { |
| 48 | + for_each = try([rule.value.days_to_abort_incomplete_multipart_upload], []) |
| 49 | + |
| 50 | + content { |
| 51 | + days_after_initiation = abort_incomplete_multipart_upload.value |
| 52 | + } |
| 53 | + } |
| 54 | + |
| 55 | + ## Single Filter |
| 56 | + dynamic "filter" { |
| 57 | + for_each = sum([ |
| 58 | + try(rule.value.prefix != null ? 1 : 0, 0), |
| 59 | + try(rule.value.min_object_size != null ? 1 : 0, 0), |
| 60 | + try(rule.value.max_object_size != null ? 1 : 0, 0), |
| 61 | + ]) == 1 ? ["go"] : [] |
| 62 | + |
| 63 | + content { |
| 64 | + prefix = try(rule.value.prefix, null) |
| 65 | + |
| 66 | + object_size_greater_than = try(rule.value.min_object_size, null) |
| 67 | + object_size_less_than = try(rule.value.max_object_size, null) |
| 68 | + } |
| 69 | + } |
| 70 | + |
| 71 | + ## Multi Filter |
| 72 | + dynamic "filter" { |
| 73 | + for_each = sum([ |
| 74 | + try(rule.value.prefix != null ? 1 : 0, 0), |
| 75 | + try(rule.value.tags != null ? 2 : 0, 0), |
| 76 | + try(rule.value.min_object_size != null ? 1 : 0, 0), |
| 77 | + try(rule.value.max_object_size != null ? 1 : 0, 0), |
| 78 | + ]) > 1 ? ["go"] : [] |
| 79 | + |
| 80 | + content { |
| 81 | + and { |
| 82 | + prefix = try(rule.value.prefix, null) |
| 83 | + tags = try(rule.value.tags, null) |
| 84 | + |
| 85 | + object_size_greater_than = try(rule.value.min_object_size, null) |
| 86 | + object_size_less_than = try(rule.value.max_object_size, null) |
| 87 | + } |
| 88 | + } |
| 89 | + } |
| 90 | + |
| 91 | + dynamic "expiration" { |
| 92 | + for_each = try([rule.value.expiration], []) |
| 93 | + |
| 94 | + content { |
| 95 | + date = try(expiration.value.date, null) |
| 96 | + days = try(expiration.value.days, 0) |
| 97 | + |
| 98 | + expired_object_delete_marker = try(expiration.value.expired_object_delete_marker, false) |
| 99 | + } |
| 100 | + } |
| 101 | + |
| 102 | + dynamic "noncurrent_version_expiration" { |
| 103 | + for_each = try([rule.value.noncurrent_version_expiration], []) |
| 104 | + |
| 105 | + content { |
| 106 | + noncurrent_days = try(noncurrent_version_expiration.value.days, null) |
| 107 | + newer_noncurrent_versions = try(noncurrent_version_expiration.value.count, null) |
| 108 | + } |
| 109 | + } |
| 110 | + |
| 111 | + dynamic "transition" { |
| 112 | + for_each = try(rule.value.transitions, []) |
| 113 | + |
| 114 | + content { |
| 115 | + date = try(transition.value.date, null) |
| 116 | + days = try(transition.value.days, null) |
| 117 | + |
| 118 | + storage_class = transition.value.storage_class |
| 119 | + } |
| 120 | + } |
| 121 | + |
| 122 | + dynamic "noncurrent_version_transition" { |
| 123 | + for_each = try(rule.value.noncurrent_version_transitions, []) |
| 124 | + |
| 125 | + content { |
| 126 | + noncurrent_days = try(noncurrent_version_transition.value.days, null) |
| 127 | + newer_noncurrent_versions = try(noncurrent_version_transition.value.count, null) |
| 128 | + |
| 129 | + storage_class = noncurrent_version_transition.value.storage_class |
| 130 | + } |
| 131 | + } |
| 132 | + } |
| 133 | + } |
| 134 | + |
| 135 | + depends_on = [ |
| 136 | + aws_s3_bucket_versioning.this, |
| 137 | + ] |
| 138 | +} |
0 commit comments