Add chainlink-ton-extras pkg

Author: krebernisak

cmd/chainlink-ton-extras/default.nix

@@ -0,0 +1,57 @@
+{
+  pkgs,
+  rev,
+}: let
+  lock = pkgs.callPackage ./lock.nix {inherit pkgs;};
+  package-info = builtins.fromJSON (builtins.readFile ../../pkg/package.json);
+
+  # Fetch karalabe/hid for HIDAPI C sources and headers
+  karalabe-hid = pkgs.fetchFromGitHub {
+    owner = "karalabe";
+    repo = "hid";
+    rev = "821c38d2678e741180ec60b2512b408fa8bab99e";
+    sha256 = "sha256-z3KSqKrIoy6WR2HUPjKJEm93NvuN0m9Edcq5BtGO5yA=";
+  };
+in
+  pkgs.buildGo124Module rec {
+    inherit (package-info) version;
+    pname = "chainlink-ton-extras";
+
+    # source at the root of the module
+    src = ./../..;
+    subPackages = ["cmd/explorer"];
+
+    nativeBuildInputs = [pkgs.gcc pkgs.pkg-config];
+    buildInputs = [pkgs.libusb1]; # for Linux builds
+    # Export CGO_CFLAGS so the C compiler can find vendored hidapi sources
+    preBuild = ''
+      export CGO_ENABLED=1
+
+      # Ensure the C compiler can find hidapi headers:
+      # point directly at the hidapi/hidapi subdir which contains hidapi.h
+      export CGO_CFLAGS="-I${karalabe-hid}/hidapi/hidapi -I${karalabe-hid} -I${pkgs.libusb1}/include"
+
+      export CGO_LDFLAGS="-L${pkgs.libusb1}/lib -lusb-1.0"
+    '';
+
+    ldflags = [
+      "-X main.Version=${package-info.version}"
+      "-X main.GitCommit=${rev}"
+    ];
+
+    # pin the vendor hash (update using 'pkgs.lib.fakeHash')
+    vendorHash = lock.chainlink-ton-extras;
+
+    # postInstall script to write version and rev to share folder
+    postInstall = ''
+      mkdir $out/share
+      echo ${package-info.version} > $out/share/.version
+      echo ${rev} > $out/share/.rev
+    '';
+
+    meta = with pkgs.lib; {
+      inherit (package-info) description;
+      license = licenses.mit;
+      changelog = "https://github.com/smartcontractkit/chainlink-ton/releases/tag/v${version}";
+    };
+  }

cmd/chainlink-ton-extras/lock.nix

@@ -0,0 +1,5 @@
+# Notice: `pkgs.lib.fakeHash` can be used as a placeholder,
+#   but `nix-lock-tidy` will only replace actual hashes.
+{pkgs}: {
+  chainlink-ton-extras = "sha256-jtaFXUcjqQgoJLpOibc2RcL+2JmdZ/c0HX8DNjud9FY=";
+}

cmd/chainlink-ton/default.nix

@@ -11,7 +11,7 @@ in
 
     # source at the root of the module
     src = ./../..;
-    subPackages = ["cmd/chainlink-ton"];
+    subPackages = ["cmd/chainlink-ton" "cmd/explorer"];
 
     ldflags = [
       "-X main.Version=${package-info.version}"

docs/.misc/dev-guides/explorer/usage.md

@@ -10,6 +10,16 @@ Three ways to run:
 2. **Hash + Address**: `./explorer <tx-hash> <address>`
 3. **Hash only**: `./explorer <tx-hash>` (testnet/mainnet only)
 
+## Run with Nix
+
+The `explorer` binary is packaged with `chainlink-ton-extras` pkg bundle.
+
+We can start a dev shell including specific pkg contents and execute a bash cmd:
+
+```bash
+nix shell .#chainlink-ton-extras -c explorer https://testnet.tonscan.org/tx/1d2080630f8a2dab1ba73c309fc5fe81268f3c2b116a91fd7c5e3018f7fce676
+```
+
 ## Build
 
 ```bash

flake.nix

@@ -29,6 +29,7 @@
 
       # Resolve root module
       chainlink-ton = pkgs.callPackage ./cmd/chainlink-ton commonArgs;
+      chainlink-ton-extras = pkgs.callPackage ./cmd/chainlink-ton-extras commonArgs;
       # Resolve sub-modules
       contracts = pkgs.callPackage ./contracts commonArgs;
       integration-tests = pkgs.callPackage ./integration-tests {
@@ -71,6 +72,7 @@
         {
           # Chainlink core node plugin (default + alias)
           inherit chainlink-ton;
+          inherit chainlink-ton-extras;
           default = chainlink-ton;
           # Dependency analyzer
           dependency-analyzer = dependency-analyzer.packages.default;