build.gradle

plugins {
    id 'java'
    id 'io.spring.dependency-management' version "1.0.9.RELEASE"
    id 'org.springframework.boot' version '2.2.5.RELEASE'
    id 'org.sonarqube' version '3.0'
    id 'jacoco'

    id 'pl.allegro.tech.build.axion-release' version '1.10.1'
    id 'com.palantir.docker' version '0.25.0'
    id 'com.palantir.docker-run' version '0.25.0'

    id 'jp.classmethod.aws.cloudformation' version '0.41'
}

version = scmVersion.version

repositories {
    mavenCentral()
    jcenter()
}


dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-devtools'
    implementation group: 'com.h2database', name: 'h2', version: '1.3.148'
    
    compileOnly 'org.projectlombok:lombok:1.18.12'
    annotationProcessor 'org.projectlombok:lombok:1.18.12'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'

}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

jacocoTestReport {
    dependsOn test 
    reports {
        xml.enabled true
    }   
}

sonarqube {
    properties {
        property 'sonar.projectName', 'kudos-backend'
        property 'sonar.host.url', 'http://ec2-3-235-176-239.compute-1.amazonaws.com:9000'
    }
}

apply plugin: 'org.sonarqube'

String dockerHubUsernameProperty = findProperty('dockerHubUsername') ?: 'rthirumal1999'
String imageName = "rthirumal1999/kudos-backend:$version"

docker {
    name imageName
    files "build/libs/${bootJar.archiveFileName.get()}"
    buildArgs([JAR_FILE: bootJar.archiveFileName.get()])
}

dockerRun {
    name project.name
    image imageName
    ports '8080:8080'
    clean true
}

import com.amazonaws.services.cloudformation.model.Capability

aws {
    region = findProperty('region') ?: 'us-east-1'
}

cloudFormation {
    stackName "kudos-backend-stack"
    stackParams([
            SubnetID: findProperty('subnetId') ?: 'subnet-378eaa09',
            ServiceName: 'kudos-backend',
            ServiceVersion: project.version,
            DockerHubUsername: dockerHubUsernameProperty
    ])
    templateFile project.file("ecs.yml")
}