raspiblitz-web/flake.nix at master · raspiblitz/raspiblitz-web · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
{
  description = "A mobile-first responsive Web UI for the RaspiBlitz";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = inputs @ {
    self,
    nixpkgs,
    flake-utils,
  }: let
    name = "blitz-web";

    systems =
      flake-utils.lib.eachDefaultSystem
      (system: let
        pkgs = nixpkgs.legacyPackages.${system};
      in {
        packages = {
          default = self.packages.${system}.${name};
          ${name} =
            pkgs.buildNpmPackage
            {
              name = "${name}";
              buildInputs = [pkgs.nodejs_22];
              src = ./.;

              npmDepsHash = "sha256-DT5+1KH06cMLHgMMPIiL1LMfxoOM4i15Z1MQok/eLS8=";

              preBuild = ''
                sed -i "s(const BACKEND_SERVER = "http://localhost:8000";(const BACKEND_SERVER = "http://127.0.0.1";(" vite.config.ts
              '';

              installPhase = ''
                mkdir $out
                npm run build
                cp -r build/* $out
              '';
            };
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [self.packages.${system}.${name}];
          packages = with pkgs; [nodejs_22 alejandra];
        };
      });

    overlays.overlays = {
      default = final: prev: {
        ${name} = self.packages.${prev.stdenv.hostPlatform.system}.${name};
      };
    };

    module = {
      nixosModules.default = {
        pkgs,
        lib,
        config,
        ...
      }: {
        imports = [./modules/raspiblitz-web.nix];
        nixpkgs.overlays = [self.overlays.default];
      };
    };
  in
    systems // overlays // module;
}