Added examples

Author: j54n1n

README.md

@@ -4,6 +4,41 @@ TFT LCD screen. It simplifies the process for drawing shapes, lines, images, and
 text to the screen. See also
 [the original TFT library](https://github.com/arduino-libraries/TFT).
 
+The Arduino TFT library extends the Adafruit GFX, and ILI9163 libraries that it
+is based on. The GFX library is responsible for the drawing routines, while the
+ST7735 library is specific to the screen on the Arduino GTFT. The Arduino
+specific additions were designed to work as similarly to the Processing API as
+possible.
+
+Onboard the screen is a SD card slot, which can be used through the SD library.
+The TFT library relies on the SPI library for communication with the screen and
+SD card, and needs to be included in all sketches.
+
+* https://github.com/adafruit/Adafruit-GFX-Library
+* https://github.com/adafruit/Adafruit-ST7735-Library
+* http://www.arduino.cc/en/Reference/SD
+* http://www.arduino.cc/en/Reference/SPI
+
+See also:
+* [Adafruit GFX Graphics Library](https://learn.adafruit.com/adafruit-gfx-graphics-library)
+Processing subset:
+* [PImage](https://processing.org/reference/PImage.html)
+* [loadImage()](https://processing.org/reference/loadImage_.html)
+* [image()](https://processing.org/reference/image_.html)
+* [background()](https://processing.org/reference/background_.html)
+* [fill()](http://processing.org/reference/fill_.html)
+* [noFill()](http://processing.org/reference/noFill_.html)
+* [stroke()](http://processing.org/reference/stroke_.html)
+* [noStroke()](http://processing.org/reference/noStroke_.html)
+* [text()](https://processing.org/reference/text_.html)
+* [textSize()](https://processing.org/reference/textSize_.html)
+* circle()
+* [point()](https://processing.org/reference/point_.html)
+* [line()](https://processing.org/reference/line_.html)
+* [quad()](https://processing.org/reference/quad_.html)
+* [rect()](https://processing.org/reference/rect_.html)
+* [triangle()](https://processing.org/reference/triangle_.html)
+
 This library requires at least
 [Arduino IDE](https://www.arduino.cc/en/Main/Software) v1.6.8, where v1.8.3 or
 newer is recommended.

examples/Arduino/TFTBitmapLogo/TFTBitmapLogo.ino

@@ -0,0 +1,108 @@
+/*
+
+ Arduino TFT Bitmap Logo example
+
+ This example reads an image file from a micro-SD card
+ and draws it on the screen, at random locations.
+
+ In this sketch, the Arduino logo is read from a micro-SD card.
+ There is a .bmp file included with this sketch.
+ - open the sketch folder (Ctrl-K or Cmd-K)
+ - copy the "arduino.bmp" file to a micro-SD
+ - put the SD into the SD slot of the Arduino TFT module.
+
+ This example code is in the public domain.
+
+ Created 19 April 2013 by Enrico Gueli
+
+ http://www.arduino.cc/en/Tutorial/TFTBitmapLogo
+
+ */
+
+// include the necessary libraries
+#include <SPI.h>
+#include <SD.h>
+#include <LcdScreen.h>  // Arduino LCD library
+
+// pin definition for the Uno
+#define sd_cs  4
+#define lcd_cs 10
+#define dc     9
+#define rst    8
+
+// pin definition for the Leonardo
+//#define sd_cs  8
+//#define lcd_cs 7
+//#define dc     0
+//#define rst    1
+
+LcdScreen TFTscreen = LcdScreen(lcd_cs, dc, rst);
+
+// this variable represents the image to be drawn on screen
+PImage logo;
+
+
+void setup() {
+  // initialize the GLCD and show a message
+  // asking the user to open the serial line
+  TFTscreen.begin();
+  TFTscreen.background(255, 255, 255);
+
+  TFTscreen.stroke(0, 0, 255);
+  TFTscreen.println();
+  TFTscreen.println(F("Arduino TFT Bitmap Example"));
+  TFTscreen.stroke(0, 0, 0);
+  TFTscreen.println(F("Open serial monitor"));
+  TFTscreen.println(F("to run the sketch"));
+
+  // initialize the serial port: it will be used to
+  // print some diagnostic info
+  Serial.begin(9600);
+  while (!Serial) {
+    // wait for serial port to connect. Needed for native USB port only
+  }
+
+  // clear the GLCD screen before starting
+  TFTscreen.background(255, 255, 255);
+
+  // try to access the SD card. If that fails (e.g.
+  // no card present), the setup process will stop.
+  Serial.print(F("Initializing SD card..."));
+  if (!SD.begin(sd_cs)) {
+    Serial.println(F("failed!"));
+    return;
+  }
+  Serial.println(F("OK!"));
+
+  // initialize and clear the GLCD screen
+  TFTscreen.begin();
+  TFTscreen.background(255, 255, 255);
+
+  // now that the SD card can be access, try to load the
+  // image file.
+  logo = TFTscreen.loadImage("arduino.bmp");
+  if (!logo.isValid()) {
+    Serial.println(F("error while loading arduino.bmp"));
+  }
+}
+
+void loop() {
+  // don't do anything if the image wasn't loaded correctly.
+  if (logo.isValid() == false) {
+    return;
+  }
+
+  Serial.println(F("drawing image"));
+
+  // get a random location where to draw the image.
+  // To avoid the image to be draw outside the screen,
+  // take into account the image size.
+  int x = random(TFTscreen.width() - logo.width());
+  int y = random(TFTscreen.height() - logo.height());
+
+  // draw the image to the screen
+  TFTscreen.image(logo, x, y);
+
+  // wait a little bit before drawing again
+  delay(1500);
+}

examples/Arduino/TFTColorPicker/TFTColorPicker.ino

@@ -0,0 +1,67 @@
+/*
+
+ TFT Color Picker
+
+ This example for the Arduino screen reads the input of
+ potentiometers or analog sensors attached to A0, A1,
+ and A2 and uses the values to change the screen's color.
+
+ This example code is in the public domain.
+
+ Created 15 April 2013 by Scott Fitzgerald
+
+ http://www.arduino.cc/en/Tutorial/TFTColorPicker
+
+ */
+
+// pin definition for the Uno
+#define cs   10
+#define dc   9
+#define rst  8
+
+// pin definition for the Leonardo
+// #define cs   7
+// #define dc   0
+// #define rst  1
+
+#include <LcdScreen.h>  // Arduino LCD library
+#include <SPI.h>
+
+LcdScreen TFTscreen = LcdScreen(cs, dc, rst);
+
+void setup() {
+  // begin serial communication
+  Serial.begin(9600);
+
+  // initialize the display
+  TFTscreen.begin();
+
+  // set the background to white
+  TFTscreen.background(255, 255, 255);
+
+}
+
+void loop() {
+
+  // read the values from your sensors and scale them to 0-255
+  int redVal = map(analogRead(A0), 0, 1023, 0, 255);
+  int greenVal = map(analogRead(A1), 0, 1023, 0, 255);
+  int blueVal = map(analogRead(A2), 0, 1023, 0, 255);
+
+  // draw the background based on the mapped values
+  TFTscreen.background(redVal, greenVal, blueVal);
+
+  // send the values to the serial monitor
+  Serial.print("background(");
+  Serial.print(redVal);
+  Serial.print(" , ");
+  Serial.print(greenVal);
+  Serial.print(" , ");
+  Serial.print(blueVal);
+  Serial.println(")");
+
+  // wait for a moment
+  delay(33);
+
+}
+

examples/Arduino/TFTDisplayText/TFTDisplayText.ino

@@ -0,0 +1,74 @@
+/*
+  Arduino TFT text example
+
+  This example demonstrates how to draw text on the
+  TFT with an Arduino. The Arduino reads the value
+  of an analog sensor attached to pin A0, and writes
+  the value to the LCD screen, updating every
+  quarter second.
+
+  This example code is in the public domain
+
+  Created 15 April 2013 by Scott Fitzgerald
+
+  http://www.arduino.cc/en/Tutorial/TFTDisplayText
+
+ */
+
+#include <LcdScreen.h>  // Arduino LCD library
+#include <SPI.h>
+
+// pin definition for the Uno
+#define cs   10
+#define dc   9
+#define rst  8
+
+// pin definition for the Leonardo
+// #define cs   7
+// #define dc   0
+// #define rst  1
+
+// create an instance of the library
+LcdScreen TFTscreen = LcdScreen(cs, dc, rst);
+
+// char array to print to the screen
+char sensorPrintout[4];
+
+void setup() {
+
+  // Put this line at the beginning of every sketch that uses the GLCD:
+  TFTscreen.begin();
+
+  // clear the screen with a black background
+  TFTscreen.background(0, 0, 0);
+
+  // write the static text to the screen
+  // set the font color to white
+  TFTscreen.stroke(255, 255, 255);
+  // set the font size
+  TFTscreen.setTextSize(2);
+  // write the text to the top left corner of the screen
+  TFTscreen.text("Sensor Value :\n ", 0, 0);
+  // ste the font size very large for the loop
+  TFTscreen.setTextSize(5);
+}
+
+void loop() {
+
+  // Read the value of the sensor on A0
+  String sensorVal = String(analogRead(A0));
+
+  // convert the reading to a char array
+  sensorVal.toCharArray(sensorPrintout, 4);
+
+  // set the font color
+  TFTscreen.stroke(255, 255, 255);
+  // print the sensor value
+  TFTscreen.text(sensorPrintout, 0, 20);
+  // wait for a moment
+  delay(250);
+  // erase the text you just wrote
+  TFTscreen.stroke(0, 0, 0);
+  TFTscreen.text(sensorPrintout, 0, 20);
+}
+

examples/Arduino/TFTEtchASketch/TFTEtchASketch.ino

@@ -0,0 +1,83 @@
+/*
+
+ TFT EtchASketch
+
+ This example for the Arduino screen draws a white point
+ on the GLCD based on the values of 2 potentiometers.
+ To clear the screen, press a button attached to pin 2.
+
+ This example code is in the public domain.
+
+ Created 15 April 2013 by Scott Fitzgerald
+
+ http://www.arduino.cc/en/Tutorial/TFTEtchASketch
+
+ */
+
+#include <LcdScreen.h>  // Arduino LCD library
+#include <SPI.h>
+
+// pin definition for the Uno
+#define cs   10
+#define dc   9
+#define rst  8
+
+// pin definition for the Leonardo
+// #define cs   7
+// #define dc   0
+// #define rst  1
+
+LcdScreen TFTscreen = LcdScreen(cs, dc, rst);
+
+// initial position of the cursor
+int xPos = TFTscreen.width() / 2;
+int yPos = TFTscreen.height() / 2;
+
+// pin the erase switch is connected to
+int erasePin = 2;
+
+void setup() {
+  // declare inputs
+  pinMode(erasePin, INPUT);
+  // initialize the screen
+  TFTscreen.begin();
+  // make the background black
+  TFTscreen.background(0, 0, 0);
+}
+
+void loop() {
+  // read the potentiometers on A0 and A1
+  int xValue = analogRead(A0);
+  int yValue = analogRead(A1);
+
+  // map the values and update the position
+  xPos = xPos + (map(xValue, 0, 1023, 2, -2));
+  yPos = yPos + (map(yValue, 0, 1023, -2, 2));
+
+  // don't let the point go past the screen edges
+  if (xPos > 159) {
+    (xPos = 159);
+  }
+
+  if (xPos < 0) {
+    (xPos = 0);
+  }
+  if (yPos > 127) {
+    (yPos = 127);
+  }
+
+  if (yPos < 0) {
+    (yPos = 0);
+  }
+
+  // draw the point
+  TFTscreen.stroke(255, 255, 255);
+  TFTscreen.point(xPos, yPos);
+
+  // read the value of the pin, and erase the screen if pressed
+  if (digitalRead(erasePin) == HIGH) {
+    TFTscreen.background(0, 0, 0);
+  }
+
+  delay(33);
+}