Low-Pass Filter on audio from A2DP

[skyycode-0]

Has anyone ever tried filtering audio from A2DP using the audio-tools lib (from the same dev)? I honestly need help on how to implement it since I don't quite understand on how to run the audio data through a FIR filter.

Currently, here's my code:

#include <Arduino.h>
#include "AudioTools.h"
#include "BluetoothA2DPSinkQueued.h"

const uint8_t S_CLK = 25;
const uint8_t S_WS = 32;
const uint8_t S_OUT = 27;
const uint8_t S_SHUT = 4;

const uint8_t led = 2;
const uint16_t channels = 2;

AudioInfo to_info(48000, 2, 16);

I2SStream out;
Equalizer3Bands eq(out);
BluetoothA2DPSinkQueued a2dp_sink(out);

FilteredStream<int16_t, float> inFiltered(out, channels);  
StreamCopy copier(out, inFiltered);  

float coef[] = { 0.0209967345, 0.0960112308, 0.1460005493, 0.0960112308, 0.0209967345 };


ConfigEqualizer3Bands cfg_eq;
const uint16_t low_freq = 300;
const uint16_t high_freq = 11000;

void read_data_stream(const uint8_t *data, uint32_t length) {
  eq.write(data, length);
}


void setup() {

  Serial.begin(115200);

  AudioLogger::instance().begin(Serial, AudioLogger::Warning); 

  pinMode(led, OUTPUT);
  pinMode(S_SHUT, OUTPUT);

  digitalWrite(S_SHUT, HIGH);

  inFiltered.setFilter(0, new FIR<float>(coef));
  inFiltered.setFilter(1, new FIR<float>(coef));

  auto cfg = out.defaultConfig(TX_MODE);
    cfg.pin_bck = S_CLK;
    cfg.pin_ws = S_WS;
    cfg.pin_data = S_OUT;

    cfg.copyFrom(to_info);
    out.begin(cfg);

    cfg_eq = eq.defaultConfig();
    cfg_eq.setAudioInfo(to_info);
    cfg_eq.freq_low = low_freq;
    cfg_eq.freq_high = high_freq;

    cfg_eq.gain_low = 1.1;
    cfg_eq.gain_medium = 1.1;
    cfg_eq.gain_high = 0.9;
    eq.begin(cfg_eq);

    a2dp_sink.set_stream_reader(read_data_stream, false);
    a2dp_sink.set_auto_reconnect(true);
    a2dp_sink.start("current.speaker");

}

void loop() {

  copier.copy();

  if (a2dp_sink.is_connected()) {
    digitalWrite(led, HIGH);
  } else {
    digitalWrite(led, LOW);
  }

}

With this current code, nothing really happens and an "handle is NULL" appears in serial logs. Any help is appreciated ^^,,

[pschatzmann]

I am sorry, but this does not make any sense at all!
Try to explain first what you try to do...

If you just want to send the output to the filter, delete

• Equalizer3Bands
• StreamCopy
• read_data_stream callback

and send the output for a2dp to the filter with

• BluetoothA2DPSinkQueued a2dp_sink(inFiltered);

maybe a better name should be outFiltered instead of inFiltered...

[skyycode-0]

Apologies for my confusing code, but what I intended to do was to utilise some type of audio filter in order to create a high-pass filter to cut frequencies below 65Hz. I tried to do it first using the equaliser class, but from testing, it cannot eliminate the lower frequencies completely. And just now, I tested what you said in sending A2DP's output to the filter directly and then to I2S, but now, all I get from my speaker is distorted sound.

By the way, the coefficients in this version of code were generated from FIIR, as a test.

The code currently:

#include <Arduino.h>
#include "AudioTools.h"
#include "BluetoothA2DPSinkQueued.h"

const uint8_t S_CLK = 25;
const uint8_t S_WS = 32;
const uint8_t S_OUT = 27;
const uint8_t S_SHUT = 4;

const uint8_t led = 2;
const uint16_t channels = 2;

AudioInfo to_info(48000, 2, 16);

I2SStream out;
FilteredStream<int16_t, float> inFiltered(out, channels);
BluetoothA2DPSinkQueued a2dp_sink(inFiltered);

float coef[] = { 0.000000000000000000,
-0.000008298796584027,
-0.000024529690129973,
-0.000030184971440723,
0.000000000000000000,
0.000096315421362142,
0.000290626330640629,
0.000610757313924047,
0.001072662675969502,
0.001670904958528908,
0.002368608528180132,
0.003088626766331078,
0.003708009817476209,
0.004057857890662478,
0.003930220819905166,
0.003092863147626782,
0.001311545903366397,
-0.001621851038327727,
-0.005858308712727381,
-0.011461664028353555,
-0.018383999193995318,
-0.026450627151825973,
-0.035358013018822868,
-0.044686500806321548,
-0.053927818940078392,
-0.062525285970878600,
-0.069922740983630854,
-0.075616785258198010,
-0.079206186772494871,
0.919567591519672600,
-0.079206186772494871,
-0.075616785258198010,
-0.069922740983630854,
-0.062525285970878600,
-0.053927818940078386,
-0.044686500806321569,
-0.035358013018822888,
-0.026450627151825962,
-0.018383999193995321,
-0.011461664028353566,
-0.005858308712727384,
-0.001621851038327728,
0.001311545903366397,
0.003092863147626785,
0.003930220819905171,
0.004057857890662478,
0.003708009817476213,
0.003088626766331081,
0.002368608528180131,
0.001670904958528909,
0.001072662675969501,
0.000610757313924047,
0.000290626330640629,
0.000096315421362142,
0.000000000000000000,
-0.000030184971440723,
-0.000024529690129973,
-0.000008298796584027,
0.000000000000000000
};

void setup() {

  Serial.begin(115200);

  AudioLogger::instance().begin(Serial, AudioLogger::Warning); 

  pinMode(led, OUTPUT);
  pinMode(S_SHUT, OUTPUT);

  digitalWrite(S_SHUT, HIGH);

  inFiltered.setFilter(0, new FIR<float>(coef));
  inFiltered.setFilter(1, new FIR<float>(coef));

  auto cfg = out.defaultConfig(TX_MODE);
    cfg.pin_bck = S_CLK;
    cfg.pin_ws = S_WS;
    cfg.pin_data = S_OUT;

    cfg.copyFrom(to_info);
    out.begin(cfg);

    a2dp_sink.set_auto_reconnect(true);
    a2dp_sink.start("current.speaker");

}

void loop() {

  if (a2dp_sink.is_connected()) {
    digitalWrite(led, HIGH);
  } else {
    digitalWrite(led, LOW);
  }

}

[pschatzmann]

Floating point multiplications in Microcontrollers are usually quite slow: You are using a filter with 59 taps (elements): this is creating 59 * 2 = 118 floating point multiplications for each generated sample.

I guess this is not generating the requested number of samples in the available time.
Try to decrease the number of taps or/and downample the data to a lower sample rate...

ps. The sample rate should be 44100.

[skyycode-0]

I barely noticed that my sample rate was set to 48k instead of 44.1k. Thanks for that. Changed it now, and it works! But now, the issue is that whenever I start audio playback from A2DP, the filter works when music is played and immediately doesn't apply it again the moment I pause and then play another song. Why could that be?

Ex.

First start-up > Audio plays (filter applies) > Audio paused for 2 seconds > Audio played again (filter doesn't apply and never does until restart)

[pschatzmann]

This is calling end() on the defined output. It seems that for the FilteredStream this is dropping the assigned filters, so that they would need to be assigned again.

I redesigned the FilteredStream class to keep the assignenmants...

As an alternative workaround you could wrap the FilteredStream in a CallbackStream or VolumeStream.

[skyycode-0]

Ah, that's interesting. I may consider using that, but upon further testing, a filter with 17 taps was the maximum that I could apply that prevents slowdowns in audio output, but it was not sufficient enough to provide enough accuracy to filter sub-bass frequencies all while preserving mid-high bass. I'm going to opt for the equalizer instead, but thanks for all the help, Phil.