Improve NFApi.updateMovedPath/Cref

Fixes OpenModelica#15065

Author: perost

OMCompiler/Compiler/Script/NFApi.mo

@@ -2868,21 +2868,24 @@ algorithm
   if AbsynUtil.pathIsFullyQualified(qualified_path) then
     qualified_path := AbsynUtil.makeNotFullyQualified(qualified_path);
 
-    if AbsynUtil.pathIsQual(qualified_path) then
-      // If the path is qualified it needs to be joined with the original path,
-      // but we remove any part of the path that's the same as the destination.
+    if AbsynUtil.pathIsIdent(qualified_path) and
+       AbsynUtil.pathFirstIdent(qualified_path) == AbsynUtil.pathFirstIdent(env.destinationPath) then
+      // Special case, the path refers to the destination package, e.g. moving A.B.C into A.
+      path := AbsynUtil.pathRest(path);
+    else
+      // Remove any part of the qualified path that's the same as the destination.
       opt_path := AbsynUtil.pathStripSamePrefix(qualified_path, env.destinationPath);
 
+      // Replace the first identifier in the original path with the remaining qualified path.
       if isSome(opt_path) then
         SOME(qualified_path) := opt_path;
 
-        if AbsynUtil.pathIsQual(qualified_path) then
-          path := AbsynUtil.joinPaths(AbsynUtil.pathPrefix(qualified_path), path);
+        if AbsynUtil.pathIsQual(path) then
+          path := AbsynUtil.joinPaths(qualified_path, AbsynUtil.pathRest(path));
+        else
+          path := qualified_path;
         end if;
       end if;
-    elseif AbsynUtil.pathFirstIdent(qualified_path) == AbsynUtil.pathFirstIdent(env.destinationPath) then
-      // Special case, the path refers to the destination package, e.g. moving path A.B.C into A.
-      path := AbsynUtil.pathRest(path);
     end if;
   end if;
 end updateMovedPath;
@@ -2967,6 +2970,7 @@ function updateMovedCref
   input MoveEnv env;
 protected
   Absyn.Path qualified_path;
+  Absyn.ComponentRef qualified_cref;
   Option<Absyn.Path> opt_path;
 algorithm
   if AbsynUtil.crefIsFullyQualified(cref) or AbsynUtil.crefIsWild(cref) then
@@ -2987,21 +2991,25 @@ algorithm
   if AbsynUtil.pathIsFullyQualified(qualified_path) then
     qualified_path := AbsynUtil.makeNotFullyQualified(qualified_path);
 
-    if AbsynUtil.pathIsQual(qualified_path) then
-      // If the path is qualified it needs to be joined with the original cref,
-      // but we remove any part of the path that's the same as the destination.
+    if AbsynUtil.pathIsIdent(qualified_path) and
+       AbsynUtil.pathFirstIdent(qualified_path) == AbsynUtil.pathFirstIdent(env.destinationPath) then
+      // Special case, the cref refers to the destination package, e.g. moving A.B.C into A.
+      cref := AbsynUtil.crefStripFirst(cref);
+    else
+      // Remove any part of the qualified path that's the same as the destination.
       opt_path := AbsynUtil.pathStripSamePrefix(qualified_path, env.destinationPath);
 
+      // Replace the first identifier in the original cref with the remaining qualified path.
       if isSome(opt_path) then
         SOME(qualified_path) := opt_path;
+        qualified_cref := AbsynUtil.pathToCref(qualified_path);
 
-        if AbsynUtil.pathIsQual(qualified_path) then
-          cref := AbsynUtil.joinCrefs(AbsynUtil.pathToCref(AbsynUtil.pathPrefix(qualified_path)), cref);
+        if AbsynUtil.crefIsQual(cref) then
+          cref := AbsynUtil.joinCrefs(qualified_cref, AbsynUtil.crefStripFirst(cref));
+        else
+          cref := qualified_cref;
         end if;
       end if;
-    elseif AbsynUtil.pathFirstIdent(qualified_path) == AbsynUtil.pathFirstIdent(env.destinationPath) then
-      // Special case, the cref refers to the destination package, e.g. moving path A.B.C into A.
-      cref := AbsynUtil.crefStripFirst(cref);
     end if;
   end if;
 end updateMovedCref;

testsuite/openmodelica/interactive-API/CopyClass8.mos

@@ -0,0 +1,36 @@
+// name:     CopyClass8
+// keywords:
+// status:   correct
+//
+
+loadString("
+  package Modelica
+    package Constants
+      constant Real pi = 3.14;
+    end Constants;
+  end Modelica;
+
+  package ImportDup
+    import C = Modelica.Constants;
+    import M = Modelica;
+
+    model Orig
+      parameter Real foo = C.pi*2;
+      package Consts = C;
+      package PM = M;
+    end Orig;
+  end ImportDup;
+");
+
+copyClass(ImportDup.Orig, "Duplicate");
+list(Duplicate);
+
+// Result:
+// true
+// true
+// "model Duplicate
+//   parameter Real foo = Modelica.Constants.pi*2;
+//   package Consts = Modelica.Constants;
+//   package PM = Modelica;
+// end Duplicate;"
+// endResult

testsuite/openmodelica/interactive-API/Makefile

@@ -34,6 +34,7 @@ CopyClass4.mos \
 CopyClass5.mos \
 CopyClass6.mos \
 CopyClass7.mos \
+CopyClass8.mos \
 CopyClassInvalid1.mos \
 CopyClassRedeclare1.mos \
 DefaultComponentName.mos \