atapp/MonoM.sc at master · nthhhhhhh/atapp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
/*

for information about monome devices:
monome.org

written by:
raja das
https://github.com/Karaokaze

*/

MonoM {

    classvar seroscnet, discovery, <>rows, <>columns, <>portlst;
    var <>prefix, <>rot, <>dvcnum, oscout;

    *initClass {

        var sz, rw, cl;

        portlst = List.new(0);
        rows = List.new(0);
        columns = List.new(0);
        seroscnet = NetAddr.new("localhost", 12002);
        seroscnet.sendMsg("/serialosc/list", "127.0.0.1", NetAddr.localAddr.port);

        StartUp.add {

            discovery = OSCdef.newMatching(\monomediscover,
                {|msg, time, addr, recvPort|

                    sz = msg[2].asString.replace("monome","").replace("40h",64).asInteger;
                    rw = case
                    {sz == 64} {8}
                    {sz == 128}{8}
                    {sz == 256}{16};
                    cl = case
                    {sz == 64} {8}
                    {sz == 128}{16}
                    {sz == 256}{16};
                    rows.add(rw);
                    columns.add(cl);
                    portlst.add(msg[3]);
                    ("Device connected on port:"++msg[3]).postln;
                    msg[1].postln;
                    msg[2].postln;

            }, '/serialosc/device', seroscnet);

        }

    }

    *new { arg prefix, rot;

        ^super.new.init
        (prefix, rot);

    }

    init { arg prefix_, rot_;

        prefix = prefix_;
        rot = rot_;

    }

    deviceList {

        portlst.clear; rows.clear; columns.clear;
        seroscnet.sendMsg("/serialosc/list", "127.0.0.1", NetAddr.localAddr.port);

    }

    printOn { arg stream;
        stream << "Ports:" << portlst;

    }


    useDevice { arg devicenum;

        dvcnum = devicenum;
        oscout = NetAddr.new("localhost", portlst[devicenum].value);
        Post << "Using device on port#" << portlst[devicenum].value << Char.nl;

        oscout.sendMsg("/sys/port", NetAddr.localAddr.port);
        oscout.sendMsg("/sys/prefix", prefix);
        oscout.sendMsg("/sys/rotation", rot);
    }

    usePort { arg portnum;

        dvcnum = portlst.indexOf(portnum);
        oscout = NetAddr.new("localhost", portnum);
        Post << "Using device#" << dvcnum << Char.nl;

        oscout.sendMsg("/sys/port", NetAddr.localAddr.port);
        oscout.sendMsg("/sys/prefix", prefix);
        oscout.sendMsg("/sys/rotation", rot);
    }

    prt {
        ^portlst[dvcnum];
    }

    rws {
        ^rows[dvcnum];
    }

    cls {
        ^columns[dvcnum];
    }
    // See here: http://monome.org/docs/tech:osc
    // if you need further explanation of the led methods below
    ledset	{ arg col, row, noff;
        oscout.sendMsg(prefix++"/grid/led/set", col, row, noff);
    }

    ledall 	{ arg noff;
        oscout.sendMsg(prefix++"/grid/led/all", noff);
    }

    ledmap	{ arg exoff, whyoff, larr;
        oscout.sendMsg(prefix++"/grid/led/map", exoff, whyoff, *larr);

    }

    ledrow	{ arg exoff, why, bit1, bit2;
        oscout.sendMsg(prefix++"/grid/led/row", exoff, why, bit1, bit2);
    }

    ledcol	{ arg ex, whyoff, bit1, bit2;
        oscout.sendMsg(prefix++"/grid/led/col", ex, whyoff, bit1, bit2);
    }

    intensity	{ arg shitisintensyo;
        oscout.sendMsg(prefix++"/grid/led/intensity", shitisintensyo);
    }

    levset	{ arg col, row, lev;
        oscout.sendMsg(prefix++"/grid/led/level/set", col, row, lev);
    }

    levall	{ arg lev;
        oscout.sendMsg(prefix++"/grid/led/level/all", lev);
    }

    levmap	{ arg exoff, whyoff, larr;
        oscout.sendMsg(prefix++"/grid/led/level/map", exoff, whyoff, *larr);

    }

    levrow	{ arg exoff, why, larr;
        oscout.sendMsg(prefix++"/grid/led/level/row", exoff, why,*larr);

    }

    levcol	{ arg ex, whyoff, larr;
        oscout.sendMsg(prefix++"/grid/led/level/col", ex, whyoff,*larr);

    }


    tiltnoff { arg sens, noff;
        oscout.sendMsg(prefix++"/tilt/set", sens, noff);
    }

    darkness {

        this.ledall(0);
        discovery.free;
        oscout.disconnect;
        seroscnet.disconnect;
    }

}