Adding out-of-tree tree-sitter grammars

[menixator]

nvim-tree-sitter comes with a subset of pkgs.tree-sitter.grammars packages ( see list here ). If you want to add your own grammar or replace an existing grammar with an updated one, it's very simple to do so but I haven't seen it documented so I thought I'd leave this here.

{ pkgs, ... }:
let

  #example of adding your own grammar:
  treesitter-nu-grammar = pkgs.tree-sitter.buildGrammar {
    language = "nu";
    version = "0.0.0+rev=0bb9a60";
    src = pkgs.fetchFromGitHub {
      owner = "nushell";
      repo = "tree-sitter-nu";
      rev = "0bb9a602d9bc94b66fab96ce51d46a5a227ab76c";
      hash = "sha256-A5GiOpITOv3H0wytCv6t43buQ8IzxEXrk3gTlOrO0K0=";
    };
    meta.homepage = "https://github.com/nushell/tree-sitter-nu";
  };

  # or you can use the tree-sitter.grammars.${package}
  # treesitter-nu-grammar = pkgs.tree-sitter-grammars.tree-sitter-nu;

  # the src sometimes have queries for highlights, indentation etc in the `queries` folder. 
  # It HAS to be in the queries/${language}  folder
  treesitter-nginx-grammar =
    (pkgs.tree-sitter.buildGrammar {
      language = "nginx";
      version = "0.0.0+rev=b4b61db4";
      src = pkgs.fetchFromGitLab {
        owner = "joncoole";
        repo = "tree-sitter-nginx";
        rev = "b4b61db443602b69410ab469c122c01b1e685aa0";
        hash = "sha256-Sa7audtwH8EgrHJ5XIUKTdveZU2pDPoUq70InQ6qcKA=";
      };
      meta.homepage = "https://gitlab.com/joncoole/tree-sitter-nginx";
    }).overrideAttrs
      (drv: {
        fixupPhase =
          drv.fixupPhase 
          + ''
            mkdir -p $out/queries/nginx
            mv $out/queries/*.scm $out/queries/nginx/
          '';
      });

in

{

  programs.nixvim.plugins = {
    treesitter = {
      enable = true;
      indent = true;
      grammarPackages = pkgs.vimPlugins.nvim-treesitter.passthru.allGrammars ++ [
        treesitter-nu-grammar
        treesitter-nginx-grammar
      ];
    };
  };

  programs.nixvim.extraConfigLua =
    # lua
    ''
      do
        local parser_config = require "nvim-treesitter.parsers".get_parser_configs()
        parser_config.nu = {
          install_info = {
            url = "${treesitter-nu-grammar}", -- local path or git repo
            files = {"src/parser.c"}, -- note that some parsers also require src/scanner.c or src/scanner.cc
            -- optional entries:
            --  branch = "main", -- default branch in case of git repo if different from master
            -- generate_requires_npm = false, -- if stand-alone parser without npm dependencies
            -- requires_generate_from_grammar = false, -- if folder contains pre-generated src/parser.c
          },
          filetype = "nu", -- if filetype does not match the parser name
        }

        parser_config.nginx = {
          install_info = {
            url = "${treesitter-nginx-grammar}", -- local path or git repo
            files = {"src/parser.c"}, -- note that some parsers also require src/scanner.c or src/scanner.cc
            -- optional entries:
            --  branch = "main", -- default branch in case of git repo if different from master
            -- generate_requires_npm = false, -- if stand-alone parser without npm dependencies
            -- requires_generate_from_grammar = false, -- if folder contains pre-generated src/parser.c
            branch = "main";
          },
          filetype = "nginx", -- if filetype does not match the parser name
        }
      end
    '';

  # add them as extra plugins so that neovim can pick up the queries.
  programs.nixvim.extraPlugins = [
    treesitter-nu-grammar
    treesitter-nginx-grammar
  ];

}

[MattSturgeon]

Thanks for bringing this up, with an excellent example!

It'd be great to have this included in our docs. (PRs welcome if you have the time, no pressures of course! 😉)

First we'd have to consider if is best as an FAQ, a "user-guide", and/or document it as part of the plugin "description".

[menixator]

Of course. I added it as part of the plugin description in this pr: #2061