plugins/hunk: init

Add support for [hunk.nvim][1], a plugin for splitting diffs.

Also add myself as a maintainer for it.

[1]: https://github.com/julienvincent/hunk.nvim

Author: jalil-salame

lib/maintainers.nix

@@ -136,4 +136,11 @@
     githubId = 85367527;
     name = "Po Co";
   };
+  jalil-salame = {
+    email = "[email protected]";
+    github = "jalil-salame";
+    githubId = 60845989;
+    name = "Jalil David Salamé Messina";
+    keys = [ { fingerprint = "7D6B 4D8F EBC5 7CBC 09AC  331F DA33 17E7 5BE9 485C"; } ];
+  };
 }

plugins/by-name/hunk/default.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  helpers,
+  config,
+  ...
+}:
+lib.nixvim.plugins.mkNeovimPlugin {
+  name = "hunk";
+  packPathName = "hunk.nvim";
+  package = "hunk-nvim";
+
+  maintainers = [ lib.maintainers.jalil-salame ];
+
+  extraOptions = {
+    fileTypeIcons = lib.mkEnableOption ''
+      warning if file type icons are not available.
+    '';
+  };
+
+  extraConfig = cfg: {
+    warnings = lib.nixvim.mkWarnings "plugins.hunk" {
+      when = cfg.fileTypeIcons && (!config.plugins.web-devicons.enable) && (!config.plugins.mini.enable);
+      message = ''
+        You have enabled `fileTypeIcons` but neither
+        `plugins.web-devicons.enable` nor `plugins.mini.enable` are `true`.
+
+        Consider enabling either plugin for proper devicons support.
+      '';
+    };
+    plugins.nui.enable = lib.mkDefault true;
+  };
+
+  settingsExample = {
+    keys.global.quit = [ "x" ];
+
+    ui = {
+      tree = {
+        mode = "flat";
+        width = 40;
+      };
+      layout = "horizontal";
+    };
+
+    hooks = {
+      on_tree_mount =
+        lib.nixvim.nestedLiteralLua # lua
+          ''
+            ---@param _context { buf: number, tree: NuiTree, opts: table }
+            function(_context) end
+          '';
+      on_diff_mount =
+        lib.nixvim.nestedLiteralLua # lua
+          ''
+            ---@param _context { buf: number, win: number }
+            function(_context) end
+          '';
+    };
+  };
+}

tests/test-sources/plugins/by-name/hunk/default.nix

@@ -0,0 +1,100 @@
+{
+  empty = {
+    plugins.hunk.enable = true;
+  };
+
+  with-web-devicons = {
+    plugins.hunk = {
+      enable = true;
+      fileTypeIcons = true;
+    };
+    plugins.web-devicons.enable = true;
+  };
+
+  with-mini = {
+    plugins.hunk = {
+      enable = true;
+      fileTypeIcons = true;
+    };
+    plugins.mini = {
+      enable = true;
+      modules.icons = { };
+    };
+  };
+
+  example.plugins.hunk = {
+    enable = true;
+    settings = {
+      keys.global.quit = [ "x" ];
+
+      ui = {
+        tree = {
+          mode = "flat";
+          width = 40;
+        };
+        layout = "horizontal";
+      };
+
+      hooks = {
+        on_tree_mount.__raw = "function(_context) end";
+        on_diff_mount.__raw = "function(_context) end";
+      };
+    };
+  };
+
+  # Taken directly from the plugin docs: https://github.com/julienvincent/hunk.nvim#configuration
+  defaults.plugins.hunk = {
+    enable = true;
+    settings = {
+      keys = {
+        global = {
+          quit = [ "q" ];
+          accept = [ "<leader><Cr>" ];
+          focus_tree = [ "<leader>e" ];
+        };
+
+        tree = {
+          expand_node = [
+            "l"
+            "<Right>"
+          ];
+          collapse_node = [
+            "h"
+            "<Left>"
+          ];
+
+          open_file = [ "<Cr>" ];
+
+          toggle_file = [ "a" ];
+        };
+
+        diff = {
+          toggle_line = [ "a" ];
+          toggle_hunk = [ "A" ];
+        };
+      };
+
+      ui = {
+        tree = {
+          mode = "nested";
+          width = 35;
+        };
+        layout = "vertical";
+      };
+
+      icons = {
+        selected = "󰡖";
+        deselected = "";
+        partially_selected = "󰛲";
+
+        folder_open = "";
+        folder_closed = "";
+      };
+
+      hooks = {
+        on_tree_mount.__raw = "function(_context) end";
+        on_diff_mount.__raw = "function(_context) end";
+      };
+    };
+  };
+}