gotify-desktop: init module

Co-authored-by: Austin Horstman <[email protected]>

Author: Joker9944

modules/misc/news/2025/11/2025-11-24_12-05-54.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+{
+  time = "2025-11-24T11:05:54+00:00";
+  condition = pkgs.stdenv.hostPlatform.isLinux;
+  message = ''
+    A new module is available: 'services.gotify-desktop'
+
+    gotify-desktop is a small daemon to receive messages from a Gotify server
+    and forward them as desktop notifications. It supports message priorities,
+    automatic reconnection, retrieval of missed messages
+    and automatic deletion of shown messages.
+  '';
+}

modules/services/gotify-desktop.nix

@@ -0,0 +1,112 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+let
+  cfg = config.services.gotify-desktop;
+  tomlFormat = pkgs.formats.toml { };
+in
+{
+  meta.maintainers = with lib.hm.maintainers; [
+    joker9944
+  ];
+
+  options.services.gotify-desktop =
+    let
+      inherit (lib)
+        mkEnableOption
+        mkPackageOption
+        mkOption
+        literalExpression
+        types
+        ;
+    in
+    {
+      enable = mkEnableOption "Gotify daemon to receive messages and forward them as desktop notifications";
+
+      package = mkPackageOption pkgs "gotify-desktop" { };
+
+      url = mkOption {
+        type = types.str;
+        example = "wss://gotify.example.com:8443";
+        description = ''
+          Gotify server websocket URL, use wss:// prefix for TLS, or ws:// for unencrypted.
+        '';
+      };
+
+      token = mkOption {
+        type = types.oneOf [
+          types.str
+          (types.submodule {
+            options = {
+              command = mkOption {
+                type = types.str;
+              };
+            };
+          })
+        ];
+        example = literalExpression ''
+          "gotify-token"
+          or
+          { command = "''${lib.getExe pkgs.libsecret} lookup Title 'Gotify token'"; }
+          or
+          { command = "''${lib.getExe' pkgs.coreutils "cat"} /foo/bar/token"; }
+        '';
+        description = ''
+          Secret Gotify client token.
+          Either directly as string or as command for fetching client token.
+        '';
+      };
+
+      settings = mkOption {
+        inherit (tomlFormat) type;
+        default = { };
+        example = literalExpression ''
+          {
+            # optional, if true, deletes messages that have been handled, defaults to false
+            gotify.auto_delete = true;
+
+            # optional, ignores messages with priority lower than given value, defaults to 0
+            notification.min_priority = 1;
+
+            # optional, run the given command for each message, with the following environment variables set: GOTIFY_MSG_PRIORITY, GOTIFY_MSG_TITLE and GOTIFY_MSG_TEXT.
+            action.on_msg_command = "/usr/bin/beep";
+          }
+        '';
+        description = ''
+          Configuration settings for gotify-desktop. All available options can be found here:
+          <https://github.com/desbma/gotify-desktop/blob/master/README.md#configuration>
+        '';
+      };
+    };
+
+  config =
+    lib.mkIf cfg.enable {
+      assertions = [
+        (lib.hm.assertions.assertPlatform "services.gotify-desktop" pkgs lib.platforms.linux)
+      ];
+
+      xdg.configFile."gotify-desktop/config.toml".source =
+        tomlFormat.generate "gotify-desktop-config.toml"
+          (lib.recursiveUpdate cfg.settings { gotify = { inherit (cfg) url token; }; });
+
+      # Based on systemd service example provided by package
+      # https://github.com/desbma/gotify-desktop/blob/521dbf4d175833b6338856248c7c6b383c1e5fa6/gotify-desktop.service
+      systemd.user.services.gotify-desktop = {
+        Unit = {
+          Description = "Gotify daemon to send desktop notifications";
+          PartOf = [ "graphical-session.target" ];
+        };
+
+        Service = {
+          ExecStart = lib.getExe cfg.package;
+          Restart = "always";
+          RestartSec = "5s";
+        };
+
+        Install.WantedBy = [ "graphical-session.target" ];
+      };
+    };
+}

tests/modules/services/gotify-desktop/config-command-token.toml

@@ -0,0 +1,5 @@
+[gotify]
+url = "wss://foo.bar"
+
+[gotify.token]
+command = "secret-token-command"

tests/modules/services/gotify-desktop/config-settings.toml

@@ -0,0 +1,6 @@
+[foo]
+bar = "extra"
+
+[gotify]
+token = "secret-token"
+url = "wss://foo.bar"

tests/modules/services/gotify-desktop/config-str-token.toml

@@ -0,0 +1,3 @@
+[gotify]
+token = "secret-token"
+url = "wss://foo.bar"

tests/modules/services/gotify-desktop/default.nix

@@ -0,0 +1,7 @@
+{ lib, pkgs, ... }:
+
+lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
+  gotify-dekstop-str-token = ./gotify-dekstop-str-token.nix;
+  gotify-dekstop-command-token = ./gotify-dekstop-command-token.nix;
+  gotify-dekstop-settings = ./gotify-dekstop-settings.nix;
+}

tests/modules/services/gotify-desktop/gotify-dekstop-command-token.nix

@@ -0,0 +1,17 @@
+{
+  services.gotify-desktop = {
+    enable = true;
+    url = "wss://foo.bar";
+    token.command = "secret-token-command";
+  };
+
+  nmt.script = ''
+    servicePath=home-files/.config/systemd/user
+    configPath=home-files/.config/gotify-desktop
+
+    assertFileExists $servicePath/gotify-desktop.service
+    assertFileExists $configPath/config.toml
+
+    assertFileContent $configPath/config.toml ${./config-command-token.toml}
+  '';
+}

tests/modules/services/gotify-desktop/gotify-dekstop-settings.nix

@@ -0,0 +1,20 @@
+{
+  services.gotify-desktop = {
+    enable = true;
+    url = "wss://foo.bar";
+    token = "secret-token";
+    settings = {
+      foo.bar = "extra";
+    };
+  };
+
+  nmt.script = ''
+    servicePath=home-files/.config/systemd/user
+    configPath=home-files/.config/gotify-desktop
+
+    assertFileExists $servicePath/gotify-desktop.service
+    assertFileExists $configPath/config.toml
+
+    assertFileContent $configPath/config.toml ${./config-settings.toml}
+  '';
+}

tests/modules/services/gotify-desktop/gotify-dekstop-str-token.nix

@@ -0,0 +1,17 @@
+{
+  services.gotify-desktop = {
+    enable = true;
+    url = "wss://foo.bar";
+    token = "secret-token";
+  };
+
+  nmt.script = ''
+    servicePath=home-files/.config/systemd/user
+    configPath=home-files/.config/gotify-desktop
+
+    assertFileExists $servicePath/gotify-desktop.service
+    assertFileExists $configPath/config.toml
+
+    assertFileContent $configPath/config.toml ${./config-str-token.toml}
+  '';
+}