less: list options in correct order

Author: bmrips

modules/programs/less.nix

@@ -62,9 +62,37 @@ in
     xdg.configFile."lesskey" = lib.mkIf (cfg.config != "") { text = cfg.config; };
 
     programs.less.config = lib.mkIf (cfg.options != { }) (
+      let
+        color = lib.intersectAttrs {
+          color = null;
+          D = null;
+        } cfg.options;
+        prompt = lib.intersectAttrs {
+          prompt = null;
+          P = null;
+        } cfg.options;
+        otherOptions = lib.removeAttrs cfg.options [
+          "color"
+          "D"
+          "P"
+          "prompt"
+        ];
+
+        toCommandLine = lib.cli.toCommandLineShell (k: {
+          option = if builtins.stringLength k == 1 then "-${k}" else "--${k}";
+          sep = null; # options and values must be separate strings
+          explicitBool = false;
+        });
+
+        orderedOptions = lib.filter (x: x != { }) [
+          otherOptions
+          color # colors need to come after `--use-color`.
+          prompt # the prompt has to be the last option.
+        ];
+      in
       lib.mkBefore ''
         #env
-        LESS = ${lib.cli.toGNUCommandLineShell { } cfg.options}
+        LESS = ${lib.concatMapStringsSep " " toCommandLine orderedOptions}
       ''
     );
   };

tests/modules/programs/less/correct-option-order.nix

@@ -0,0 +1,21 @@
+{
+  programs.less = {
+    enable = true;
+    options = {
+      color = [
+        "HkK" # header: gray
+        "Mkb" # marks: blue
+      ];
+      prompt = "s%f";
+      quiet = true;
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/lesskey
+    assertFileContent home-files/.config/lesskey ${builtins.toFile "lesskey.expected" ''
+      #env
+      LESS = --quiet --color HkK --color Mkb --prompt s%f
+    ''}
+  '';
+}

tests/modules/programs/less/default.nix

@@ -1,4 +1,5 @@
 {
+  less-correct-option-order = ./correct-option-order.nix;
   less-custom-config = ./custom-config.nix;
   less-custom-options = ./custom-options.nix;
   less-custom-options-and-config = ./custom-options-and-config.nix;