melange-re.github.io/flake.nix at ceb4fbecb835f9999880b00d457712b4b4d6df03 · melange-re/melange-re.github.io · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
{
  description = "Melange Nix Flake";

  inputs.nixpkgs.url = "github:nix-ocaml/nix-overlays";

  outputs = { self, nixpkgs, flake-utils }:
    let
      forAllSystems = f: nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed (system:
        let
          pkgs = nixpkgs.legacyPackages.${system}.extend (self: super: {

            ocamlPackages = super.ocaml-ng.ocamlPackages_5_4.overrideScope (oself: osuper: with oself; {
              cmarkit = osuper.cmarkit.overrideAttrs (_: {
                src = super.fetchFromGitHub {
                  owner = "dbuenzli";
                  repo = "cmarkit";
                  rev = "6d6f2d289fb336e7d3c15cfe5bbda2c180c95727";
                  hash = "sha256-3VWZJ4p+f/1blsevtXLwFsUD8RrHGI84gehId/twJHc=";
                };
                # propagatedBuildInputs = (o.propagatedBuildInputs or [ ]) ++ (with oself; [ cmdliner ]);
                buildPhase = ''
                  runHook preBuild
                  ${topkg.run} build --with-cmdliner false
                  runHook postBuild
                '';
              });
              melange-playground = buildDunePackage {
                pname = "melange-playground";
                inherit (melange) src version;
                # nativeBuildInputs = [ cppo reason ];
                # propagatedBuildInputs = [ melange reason ];
                nativeBuildInputs = [ cppo js_of_ocaml ]; # nodejs menhir
                propagatedBuildInputs = [ js_of_ocaml-compiler melange reason reason-react-ppx ];

              };
              melange = osuper.melange.overrideAttrs (_: {
                src = super.fetchFromGitHub {
                  owner = "melange-re";
                  repo = "melange";
                  rev = "6.0.1-54";
                  hash = "sha256-CvIIRYW7VfUxNOMCgltUAQcmwM4sB0eFYm/70dQO/i8=";
                  fetchSubmodules = true;
                };
              });
            });
          });
        in
        f pkgs);
    in
    {
      devShells = forAllSystems (pkgs:
        let
          python3Packages = pkgs.python3.pkgs.overrideScope (pyself: pysuper: {
            mkdocs-print-site-plugin = pyself.buildPythonPackage rec {
              pname = "mkdocs-print-site-plugin";
              version = "2.8";
              pyproject = true;
              build-system = [ pyself.setuptools ];
              src = pkgs.fetchFromGitHub {
                owner = "timvink";
                repo = "mkdocs-print-site-plugin";
                rev = "v${version}";
                hash = "sha256-ItBpovQ6emFYrlcVlCPjc21aInX/5hvk14QpkAdBSAA=";
              };
              propagatedBuildInputs = with pyself; [
                setuptools-scm
                mkdocs-material
              ];
              checkInputs = with pyself; [ pytest ];
            };
          });
        in

        {
          default = pkgs.mkShell {
            nativeBuildInputs = with pkgs.ocamlPackages; [
              dune
              ocaml
              findlib
              melange
              melange-playground
              reason
            ];
            buildInputs = with python3Packages; [
              mkdocs
              mkdocs-print-site-plugin
              pkgs.yarn
            ] ++ (with pkgs.ocamlPackages;  [
              reason-react
              reason-react-ppx
              ocamlformat
              js_of_ocaml
              cmarkit
              ocamlformat-lib

            ]);
          };
        });
    };
}