cardano-ledger-rdf/justfile at main · lambdasistemi/cardano-ledger-rdf · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
default:
    just --list

format:
    find . -type f -name '*.hs' -not -path '*/dist-newstyle/*' -exec fourmolu -i {} +
    cabal-fmt -i cardano-ledger-rdf.cabal

hlint:
    find . -type f -name '*.hs' -not -path '*/dist-newstyle/*' -exec hlint {} +

build:
    cabal build all -O0

unit match="":
    #!/usr/bin/env bash
    set -euo pipefail
    cabal build exe:cq-rdf -O0 >/dev/null
    cabal build cardano-ledger-rdf:exe:tx-view -O0 >/dev/null
    cq_rdf="$(cabal list-bin exe:cq-rdf -O0)"
    tx_graph_link="$(mktemp -d)/tx-graph"
    ln -s "$cq_rdf" "$tx_graph_link"
    export CQ_RDF_EXE="$cq_rdf"
    export TX_GRAPH_EXE="$tx_graph_link"
    export TX_VIEW_EXE="$(cabal list-bin cardano-ledger-rdf:exe:tx-view -O0)"
    if [[ '{{ match }}' == "" ]]; then
        cabal test cardano-ledger-rdf:unit-tests -O0 --test-show-details=direct
    else
        cabal test cardano-ledger-rdf:unit-tests -O0 \
            --test-show-details=direct \
            --test-option=--match \
            --test-option="{{ match }}"
    fi

smoke-graph:
    #!/usr/bin/env bash
    set -euo pipefail
    cabal build exe:cq-rdf -O0 >/dev/null
    "$(cabal list-bin exe:cq-rdf -O0)" --help >/dev/null

smoke-view:
    #!/usr/bin/env bash
    set -euo pipefail
    cabal build cardano-ledger-rdf:exe:tx-view -O0 >/dev/null
    "$(cabal list-bin cardano-ledger-rdf:exe:tx-view -O0)" --help >/dev/null

vocab-validate:
    python3 scripts/validate-ttl.py

vocab-owl-smoke:
    python3 scripts/owl-smoke.py

vocab-accessibility:
    python3 scripts/vocab-accessibility.py
    python3 scripts/vocab-accessibility.py --self-test

ci:
    just build
    just unit
    just smoke-graph
    just smoke-view
    just vocab-validate
    just vocab-owl-smoke
    just vocab-accessibility
    cabal-fmt -c cardano-ledger-rdf.cabal
    find . -type f -name '*.hs' -not -path '*/dist-newstyle/*' -exec fourmolu -m check {} +
    find . -type f -name '*.hs' -not -path '*/dist-newstyle/*' -exec hlint {} +

serve-docs:
    mkdocs serve

build-docs:
    mkdocs build --strict