Merge branch 'support-move-x-function'

Close gh-23.

Author: kana

autoload/textobj/user.vim

@@ -394,12 +394,22 @@ endfunction
 
 
 function! s:plugin.define_interface_key_mappings()  "{{{3
-  let RHS_PATTERN = ':<C-u>call g:__textobj_' . self.name . '.%s'
-  \                 . '("%s", "%s", "<mode>")<Return>'
-  let RHS_FUNCTION = ':<C-u>call <SID>select_function_wrapper('
-  \                  .   'g:__textobj_' . self.name . '.obj_specs["%s"]["%s"],'
-  \                  .   '"<mode>"'
-  \                  . ')<Return>'
+  let RHS_PATTERN =
+  \   ':<C-u>call g:__textobj_' . self.name . '.%s('
+  \ .   '"%s",'
+  \ .   '"%s",'
+  \ .   '"<mode>"'
+  \ . ')<Return>'
+  let RHS_SELECT_FUNCTION =
+  \   ':<C-u>call <SID>select_function_wrapper('
+  \ .   'g:__textobj_' . self.name . '.obj_specs["%s"]["%s"],'
+  \ .   '"<mode>"'
+  \ . ')<Return>'
+  let RHS_MOVE_FUNCTION =
+  \   ':<C-u>call <SID>move_function_wrapper('
+  \ .   'g:__textobj_' . self.name . '.obj_specs["%s"]["%s"],'
+  \ .   '"%s"'
+  \ . ')<Return>'
 
   for [obj_name, specs] in items(self.obj_specs)
     for spec_name in filter(keys(specs), 's:is_ui_property_name(v:val)')
@@ -409,7 +419,11 @@ function! s:plugin.define_interface_key_mappings()  "{{{3
       " rhs
       let _ = spec_name . '-function'
       if has_key(specs, _)
-        let rhs = printf(RHS_FUNCTION, obj_name, _)
+        if spec_name =~# '^select'
+          let rhs = printf(RHS_SELECT_FUNCTION, obj_name, _)
+        else
+          let rhs = printf(RHS_MOVE_FUNCTION, obj_name, _, spec_name)
+        endif
       elseif has_key(specs, 'pattern')
         if spec_name =~# '^move-[npNP]$'
           let flags = ''
@@ -524,6 +538,24 @@ endfunction
 
 
 
+" "move-function" wrapper  "{{{3
+function! s:move_function_wrapper(function_name, spec_name)
+  let ORIG_POS = s:gpos_to_spos(getpos('.'))
+
+  let _ = function(a:function_name)()
+  if _ is 0
+    call cursor(ORIG_POS)
+  else
+    " FIXME: Support motion_type.  But unlike selecting a text object, the
+    " motion_type must be known before calling a user-given function.
+    let [motion_type, start_position, end_position] = _
+    call setpos('.', a:spec_name =~# '[np]$' ? start_position : end_position)
+  endif
+endfunction
+
+
+
+
 " Etc  "{{{2
 
 function! textobj#user#_sid()

t/move-x-function.vim

@@ -0,0 +1,117 @@
+describe 'move-x-function'
+  before
+    new
+
+    " Anchored-word is <a> <word> <like> <this>.
+    " But <> is not valid, because it doesn't contain a word.
+
+    function! b:move_next()
+      while !0
+        let [bl, bc] = searchpos('<', 'W')
+        let [el, ec] = searchpos('>', 'W')
+        if bl == 0 || el == 0
+          return 0
+        else
+          if bl == el && bc + 1 < ec
+            return ['v', [0, bl, bc, 0], [0, el, ec, 0]]
+          else
+            continue
+          endif
+        endif
+      endwhile
+    endfunction
+
+    function! b:move_previous()
+      while !0
+        let [el, ec] = searchpos('>', 'bW')
+        let [bl, bc] = searchpos('<', 'bW')
+        if bl == 0 || el == 0
+          return 0
+        else
+          if bl == el && bc + 1 < ec
+            return ['v', [0, bl, bc, 0], [0, el, ec, 0]]
+          else
+            continue
+          endif
+        endif
+      endwhile
+    endfunction
+
+    call textobj#user#plugin('anchoredword', {
+    \   '-': {
+    \     'move-n': '<buffer> [n]',
+    \     'move-n-function': 'b:move_next',
+    \     'move-N': '<buffer> [N]',
+    \     'move-N-function': 'b:move_next',
+    \     'move-p': '<buffer> [p]',
+    \     'move-p-function': 'b:move_previous',
+    \     'move-P': '<buffer> [P]',
+    \     'move-P-function': 'b:move_previous',
+    \   }
+    \ })
+  end
+
+  after
+    close!
+  end
+
+  it 'is used to move the cursor to a text object'
+    put ='The <quick> brown fox jumps <over> the lazy <dog'
+    put ='The> quick <brown> fox <jumps over the> lazy dog'
+    1 delete _
+
+    let cases = [
+    \   [1,  4, 'n', 1,  5],
+    \   [1,  5, 'n', 1, 29],
+    \   [1,  6, 'n', 1, 29],
+    \   [1, 11, 'n', 1, 29],
+    \   [1, 12, 'n', 1, 29],
+    \   [1, 28, 'n', 1, 29],
+    \   [1, 29, 'n', 2, 12],
+    \   [2, 21, 'n', 2, 24],
+    \   [2, 23, 'n', 2, 24],
+    \   [2, 24, 'n', 2, 24],
+    \   [2, 26, 'n', 2, 26],
+    \   [1,  4, 'N', 1, 11],
+    \   [1,  5, 'N', 1, 34],
+    \   [1,  6, 'N', 1, 34],
+    \   [1, 11, 'N', 1, 34],
+    \   [1, 12, 'N', 1, 34],
+    \   [1, 28, 'N', 1, 34],
+    \   [1, 29, 'N', 2, 18],
+    \   [2, 21, 'N', 2, 39],
+    \   [2, 23, 'N', 2, 39],
+    \   [2, 24, 'N', 2, 24],
+    \   [2, 26, 'N', 2, 26],
+    \   [1,  4, 'p', 1,  4],
+    \   [1,  5, 'p', 1,  5],
+    \   [1,  6, 'p', 1,  6],
+    \   [1, 11, 'p', 1, 11],
+    \   [1, 12, 'p', 1,  5],
+    \   [1, 28, 'p', 1,  5],
+    \   [1, 29, 'p', 1,  5],
+    \   [2, 21, 'p', 2, 12],
+    \   [2, 23, 'p', 2, 12],
+    \   [2, 24, 'p', 2, 12],
+    \   [2, 26, 'p', 2, 12],
+    \   [1,  4, 'P', 1,  4],
+    \   [1,  5, 'P', 1,  5],
+    \   [1,  6, 'P', 1,  6],
+    \   [1, 11, 'P', 1, 11],
+    \   [1, 12, 'P', 1, 11],
+    \   [1, 28, 'P', 1, 11],
+    \   [1, 29, 'P', 1, 11],
+    \   [2, 21, 'P', 2, 18],
+    \   [2, 23, 'P', 2, 18],
+    \   [2, 24, 'P', 2, 18],
+    \   [2, 26, 'P', 2, 18],
+    \ ]
+    for [il, ic, d, el, ec] in cases
+      call cursor(il, ic)
+      Expect [il, ic] == getpos('.')[1:2]
+      execute 'silent! normal' printf('[%s]', d)
+      let [_, al, ac, _] = getpos('.')
+      Expect [il, ic, d, al, ac] == [il, ic, d, el, ec]
+    endfor
+  end
+end