build.gradle

plugins {
    id 'java'
    id 'maven'
    id 'signing'
    id 'jacoco'
}

archivesBaseName = "jsonrpc4j-jsonSchema"
description 'This module is jackson-module-jsonschema wrapper for the creation of api document (like JSON-Schema) from POJO of jsonrpc4j service classes.'
group 'com.github.hiwayama'
version '0.4'

sourceCompatibility = 1.8
targetCompatibility = 1.8

// zip sources
task sourceJar(type : Jar) {
    from sourceSets.main.allJava
}
// zip javadocs
task javadocJar(type : Jar, dependsOn : javadoc) {
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar, sourceJar
}

signing {
    sign configurations.archives
}

jacoco {
    toolVersion = '0.8.2'
}

jacocoTestReport {
  reports {
    xml.enabled false
    csv.enabled false
    html.destination files("${buildDir}/jacocoHtml")
  }
}

uploadArchives {
    repositories {
        mavenDeployer {
            def ossuname = project.hasProperty("ossrhUsername") ? project.property("ossrhUsername") : ""
            def osspass = project.hasProperty("ossrhPassword") ? project.property("ossrhPassword") : ""


            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossuname, password: osspass)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossuname, password: osspass)
            }

            pom.project {
                name project.name
                packaging 'jar'
                description project.description
                url 'https://github.com/hiwayama/jsonrpc-jsonSchema'

                scm {
                    url 'https://github.com/hiwayama/jsonrpc-jsonSchema'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        name 'Hiromasa IWAYAMA'
                        email 'iwayma1880@gmail.com'
                    }
                }
            }
        }
    }
}

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'com.kjetland', name: 'mbknor-jackson-jsonschema_2.12', version: '1.0.30'
    compile ('com.github.briandilley.jsonrpc4j:jsonrpc4j:1.5.3') {
        transitive = false
    }
    testCompile group: 'junit', name: 'junit', version: '4.12'
}