shell.nix

# Note that we do a lot of cursed things, so the probability of something breaking is quite high.
#
# This was last tested on:
# - nixpkgs-unstable ~2026-07-01
# - rustc 1.98.0-nightly (4c9d2bfe4 2026-07-01)

{ pkgs ? import <nixpkgs> {} }:
let
  aux-normalization = pkgs.callPackage ./normalization/aux-normalization.nix { inherit pkgs; };
  metis-normalized = pkgs.callPackage ./metis-normalized.nix { inherit aux-normalization pkgs; };

  overrides = (builtins.fromTOML (builtins.readFile ./rust-toolchain.toml));

  libPath = with pkgs; lib.makeLibraryPath [
    aux-normalization
  ];

  testgraphs = pkgs.fetchzip rec {
    name = "metis-testgraphs";
    version = "1";
    url = "https://github.com/gfaster/metis-testgraphs/archive/v${version}.tar.gz";
    hash = "sha256-jovqebWIo5QcnuEevqjt2WXZriEQMN1ffvlLBPjQS9k=";
  };

  gklib = pkgs.stdenv.mkDerivation rec {
    pname = "gklib";
    version = "dev";

    src = pkgs.fetchFromGitHub {
      owner = "KarypisLab";
      repo = "GKlib";

      # from Jul 5 2025
      rev = "6e7951358fd896e2abed7887196b6871aac9f2f8";
      hash = "sha256-jT0hT5Y3E8GnE8OJWzDj5rtz9s59sMEXLduUnBV0I0Y=";
    };

    patches = [
      ./gk_fifo.patch
    ];

    cmakeFlags = [
      "-DCMAKE_C_FLAGS_RELEASE=-O2"
      "-DASSERT=ON"
    ];

    nativeBuildInputs = with pkgs; [ cmake ];
  };

  # modified from nixos-26.05
  # not overriding because this will stay constant
  new_metis = pkgs.stdenv.mkDerivation (finalAttrs: {
    pname = "metis";
    version = "5.2.1";

    src = pkgs.fetchFromGitHub {
      owner = "KarypisLab";
      repo = "METIS";

      # From Jul 4 2025
      rev = "a6e6a2cfa92f93a3ee2971ebc9ddfc3b0b581ab2";
      hash = "sha256-VObeibIQtZ8bFnFo2jXsCh8pqEdVkVOtCBBSvZ4lDEM=";
    };

    buildInputs = [ gklib ];
    nativeBuildInputs = [ pkgs.cmake ];

    preConfigure = ''
      mkdir -p build/xinclude
      echo "#define IDXTYPEWIDTH 32" > build/xinclude/metis.h
      echo "#define REALTYPEWIDTH 32" >> build/xinclude/metis.h
      cat include/metis.h >> build/xinclude/metis.h
      cp include/CMakeLists.txt build/xinclude
    '';

    dontStrip = true;

    cmakeFlags = [
      "-DCMAKE_C_FLAGS_RELEASE=-O3"
      "-DCMAKE_C_FLAGS=-w"
      "-DGKLIB_PATH=${gklib}"
      # "-DASSERT=ON"
    ];
  });

in
  pkgs.mkShell rec {
    name = "metis";

    METIS_NORM = metis-normalized;
    METIS_NORM_SRC = metis-normalized.src;

    METIS_NORM_FUNCTIONS = pkgs.lib.makeLibraryPath [ aux-normalization ];

    METIS_TESTGRAPHS_DIR = testgraphs;

    buildInputs = with pkgs; [
      clang
      llvmPackages_latest.bintools
      rustup
      new_metis

      cloc
      valgrind
      guile
      hyperfine
      # ocamlPackages.magic-trace
    ];
    RUSTC_VERSION = overrides.toolchain.channel;
    # https://github.com/rust-lang/rust-bindgen#environment-variables
    LIBCLANG_PATH = pkgs.lib.makeLibraryPath [ pkgs.llvmPackages_latest.libclang.lib ];

    # See: https://sourceware.org/gdb/current/onlinedocs/gdb.html/File-Options.html
    # See: https://nixos.wiki/wiki/Debug_Symbols
    shellHook = ''
      export PATH=$PATH:''${CARGO_HOME:-~/.cargo}/bin
      export PATH=$PATH:''${RUSTUP_HOME:-~/.rustup}/toolchains/$RUSTC_VERSION-x86_64-unknown-linux-gnu/bin/

      # use our debug helpers
      alias norm-gdb="gdb -d ${metis-normalized.src}/programs -d \
        ${metis-normalized.src}/libmetis -d ${metis-normalized.src}/include -x gdb/options_pp.scm"
      '';

    LD_LIBRARY_PATH = libPath;
    # Add glibc, clang, glib, and other headers to bindgen search path
    BINDGEN_EXTRA_CLANG_ARGS = 
      # Includes normal include path
      (builtins.map (a: ''-I"${a}/include"'') [
        # add dev libraries here (e.g. pkgs.libvmi.dev)
        pkgs.glibc.dev
      ])
      # Includes with special directory paths
      ++ [
        ''-I"${pkgs.llvmPackages_latest.libclang.lib}/lib/clang/${pkgs.llvmPackages_latest.libclang.version}/include"''
        ''-I"${pkgs.glib.dev}/include/glib-2.0"''
        ''-I${pkgs.glib.out}/lib/glib-2.0/include/''
      ];

    # needed for dyncall system
    # hardeningDisable = ["bindnow"];
    hardeningDisable = ["all"];
  }