android-colors/build.gradle at master · freefair/android-colors · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
buildscript {
    repositories {
        mavenCentral()
        google()
        gradlePluginPortal()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.3.2'
    }
}

plugins {
    id "io.freefair.git-version"
    id "io.freefair.maven-central.validate-poms" apply false
    id "io.github.gradle-nexus.publish-plugin" version "2.0.0"
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
    group = 'io.freefair.android-colors'
}

subprojects {
    apply plugin: 'com.android.library'
    apply plugin: 'maven-publish'
    apply plugin: "signing"
    apply plugin: "io.freefair.maven-central.validate-poms"

    android {
        compileSdkVersion 33

        defaultConfig {
            versionCode 1
            versionName project.version
            minSdkVersion 1
            targetSdkVersion 33
        }

        publishing {
            singleVariant('release') {
                withSourcesJar()
            }
        }
    }

    publishing {
        publications.withType(MavenPublication) {
            pom {
                url = 'https://github.com/freefair/android-colors'
                name = provider { project.description }
                description = provider { project.description }
                inceptionYear = '2015'
                licenses {
                    license {
                        name = 'The MIT License'
                        url = 'https://github.com/freefair/android-colors/blob/master/LICENSE'
                    }
                }
                organization {
                    name = 'FreeFair'
                    url = 'https://github.com/freefair'
                }
                developers {
                    developer {
                        id = 'larsgrefer'
                        name = 'Lars Grefer'
                        email = 'github@larsgrefer.de'
                        timezone = 'Europe/Berlin'
                    }
                }
                ciManagement {
                    system = 'GitHub Actions'
                    url = 'https://github.com/freefair/android-colors/actions'
                }
                issueManagement {
                    system = 'GitHub'
                    url = 'https://github.com/freefair/android-colors/issues'
                }
                scm {
                    connection = 'scm:git:https://github.com/freefair/android-colors.git'
                    developerConnection = 'scm:git:git@github.com:freefair/android-colors.git'
                    url = 'https://github.com/freefair/android-colors/'
                }
            }
        }
    }

    signing {
        required { !version.endsWith('SNAPSHOT') && gradle.taskGraph.hasTask("publish") }

        def signingKey = findProperty("signingKey")
        def signingPassword = findProperty("signingPassword")
        useInMemoryPgpKeys(signingKey, signingPassword)
    }

    project.afterEvaluate {
        publishing {
            publications {
                // Creates a Maven publication called "release".
                release(MavenPublication) {
                    // Applies the component for the release build variant.
                    from components.release

                    signing.sign it
                }
            }
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            stagingProfileId = '7e6204597a774f'
        }
    }
}

tasks.named('wrapper') {
    distributionType = Wrapper.DistributionType.ALL
}