drone: split builds into pipelines

Use starlark to de-duplicate most of the configuration.

Use rust:buster-slim base as there is a problem with rust on alpine
currently: rust-lang/rust#40174

Signed-off-by: Joe Groocock <me@frebib.net>

Author: frebib

.drone.star

@@ -0,0 +1,52 @@
+cmd = 'cargo check'
+deps = 'clang make automake libc-dev libclang-dev pkg-config gnupg protobuf-compiler libgmp-dev nettle-dev'
+
+def main(ctx):
+  return [
+    cargo('format', cmd='cargo fmt -- --check', deps=None, pre=['rustup component add rustfmt']),
+    cargo('test', cmd='cargo test'),
+    cargo('all', '--all --tests', env={'RUSTFLAGS': '-D warnings'}),
+    cargo('graph', feat='use-protobuf use-tcp use-unix-socket use-graph'),
+    cargo('blackhole', feat='use-protobuf use-tcp use-unix-socket use-black-hole'),
+    cargo('randomresp', feat='use-protobuf use-tcp use-unix-socket use-random-response'),
+  ]
+
+
+# name      string, name of the pipeline. must be valid yaml word with no breaks
+# args      string, arguments for provided cmd
+# deps      string, list of packages to install with the package manager
+# pre       list,   commands to run after installing packages, before cargo cmd
+# feat      string, features to use instead of default in cargo cmd
+# env       dict,   environment variables to pass to the container
+def cargo(name, args='', cmd=cmd, deps=deps, pre=[], feat=None, env=None):
+  step = {
+    "name": "build-%s" % name,
+    "image": "rust:slim-buster",    # Because rust is broken on musl at the moment:
+    "commands": [],                 # https://github.com/rust-lang/rust/issues/40174
+  }
+
+  if env:
+    step['environment'] = env
+  if deps:
+    step['commands'].insert(0, 'apt-get -qq update')
+    step['commands'].insert(1, 'apt-get -qq install %s' % deps)
+  if pre:
+    step['commands'] += pre
+
+  if feat:
+    cmd += ' --no-default-features --features="%s"' % feat
+  if args != '':
+    cmd += ' ' + args
+
+  step['commands'].append(cmd)
+
+  return {
+    "kind": "pipeline",
+    "name": "cargo-build-%s" % name,
+    "platform": {
+      "os": "linux",
+    },
+    "steps": [step],
+  }
+
+# vim: ft=python sw=2