build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    apply from: "ext.gradle"

    repositories {
        jcenter()
    }
    dependencies {
        classpath _android.plugin

        classpath _kotlin.kotlin_gradle_plugin
        classpath _kotlin.kotlin_android_extensions
    }
}

allprojects {
    repositories {
        jcenter()
    }
}

subprojects {

    def isAppModule = it.name.equals('app') || it.name.equals('testapk')

    apply plugin: isAppModule? 'com.android.application': 'com.android.library'

    apply plugin: 'kotlin-android'
    apply plugin: 'kotlin-android-extensions'   // 拓展

    android {
        compileSdkVersion _android.compileSdkVersion as Integer
        buildToolsVersion _android.buildToolsVersion as String

        defaultConfig {
            minSdkVersion _android.minSdkVersion as Integer
            targetSdkVersion 22 // 未处理6.0权限，直接写死 22
            versionCode _android.versionCode as Integer
            versionName _android.versionName as String
        }

        buildTypes {
            release {
                minifyEnabled false
                proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            }
        }

        sourceSets {
            main.java.srcDirs += 'src/main/kotlin'
        }
    }

    dependencies {
        // kotlin
        compile _kotlin.kotlin_stdlib

        // rxjava
        compile rx.rxjava2
        compile rx.rxandroid2
    }
}