Matter #11535
Replies: 3 comments 5 replies
-
|
@SuGlider Can you help with the question? |
Beta Was this translation helpful? Give feedback.
-
Yes, there are many ways to make it work: 1- Creating a new Class that heritages from MatterOnOffLight Class with the proper code for the callback. |
Beta Was this translation helpful? Give feedback.
-
|
From all those 3 options, I'd say that the best one would be (2), using lambda function with a capture value, such as the index of an array of MatterOnOffLight objects. Target example: 6 MatterOnOffLight endpoints using the same onChangeOnOff() callback code, but addressing different GPIOs, one for each endpoint. something like this: #include <Matter.h>
#include <WiFi.h>
const char *ssid = "SSID"; // Change this to your WiFi SSID
const char *password = "PWD"; // Change this to your WiFi password
//number of On-Off Lights:
const uint8_t MAX_LIGHT_NUMBER = 6;
// array of OnOffLight endpoints
MatterOnOffLight OnOffLight[MAX_LIGHT_NUMBER];
// all pins, one for each on-off light
uint8_t lightPins[MAX_LIGHT_NUMBER] = { 2, 4, 6, 8, 10, 12 }; // must replace it by the real pin for the target SoC and application
// friendly OnOffLights names used for printing a message in the callback
const char *lightName[MAX_LIGHT_NUMBER] = {
"Room 1",
"Room 2",
"Room 3",
"Room 4",
"Room 5",
"Room 6",
};
// simple setup() function
void setup() {
Serial.begin(115200); // callback will just print a message in the console
Serial.print("Connecting to ");
Serial.println(ssid);
// Manually connect to WiFi
WiFi.begin(ssid, password);
// Wait for connection
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("\r\nWiFi connected");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
// setup all the OnOff Light endpoint and their lambda callback functions
for (uint8_t i = 0; i < MAX_LIGHT_NUMBER; i++) {
pinMode( lightPins[i], OUTPUT); // set the GPIO function
OnOffLight[i].begin(false); // off
// inline lambda function using capture array index -> it will just print a message in the console
OnOffLight[i].onChangeOnOff([i](bool state) -> bool {
// Display message with the specific light name and details
Serial.printf("Matter App Control: '%s' (OnOffLight[%d], Endpoint %d, GPIO %d) changed to: %s\r\n",
lightName[i], i, OnOffLight[i].getEndPointId(),
lightPins[i], state ? "ON" : "OFF");
return true;
});
}
// last step, starting Matter Stack
Matter.begin();
}
void loop() {
}Output using Arduino Core 3.1.3 and the ESP32-C6: |
Beta Was this translation helpful? Give feedback.
-
The availalbe release of the Arduino Core for the IDE offers the Arduino Matter library as a pre-compiled binary code with a limit of 16 endpoints, including mandatory EP 0. Therefore, if the application needs to create more endpoints, it will require it to be built using Arduino as IDF Component and changing the sdkconfig file to set the necessary quantity of endpoints. Another option would be using Arduino Lib Builder project to build a new Arduino Matter Library with a higher number of endpoints, also changing the sdkconfig settings. More endpoints require more SRAM and a bigger firmware size. |
Beta Was this translation helpful? Give feedback.
-
|
@SuGlider a gently requests, can you just increase a bit number of endpoints from 16 to 24 at least,this will be helpful. We can get benefits to use the board with PSRAM like ESP32s3. Please help us |
Beta Was this translation helpful? Give feedback.
-
|
OK. I'll get it increased to 24 or 32 for the Arduino Core 3.3.0 release which also uses BLE commissioning. @me-no-dev --- I'll set it in the lib Builder again for the IDF 5.5 / Arduino 3.3.x release. Thanks. |
Beta Was this translation helpful? Give feedback.
-
Beta Was this translation helpful? Give feedback.
-
|
@Nezaemmy @tv4you2016 - If we get this PR into Arduino 3.3.0 release, it will increase the number of endpoints to 64 for the ESP32, ESP32-S3 and ESP32-C6. These 3 SoC have more SRAM available and are able to run Matter Stack with a higher memory allocation. |
Beta Was this translation helpful? Give feedback.
Uh oh!
There was an error while loading. Please reload this page.
-
Hi @SuGlider
I know this problem has nothing to do with you, but GURU is GURU, maybe you can help me!! 😄
I used this example:
https://github.com/espressif/arduino-esp32/blob/master/libraries/Matter/examples/MatterComposedLights/MatterComposedLights.ino
and a question arose:
Let's suppose I have a dynamic list where I can receive up to 30 MatterOnOffLight , I will have to create it 30 times
bool setLightOnOff3(bool state) {
Serial.printf("Light3 changed state to: %s\r\n", state ? "ON" : "OFF");
return true;
}
Is there a way to use the same callback and check which endpoint it comes from?
Beta Was this translation helpful? Give feedback.
All reactions