justfile

set working-directory := "codex-rs"
set positional-arguments

rust_min_stack := "8388608" # 8 MiB

# Display help
help:
    just -l

# `codex`
alias c := codex
codex *args:
    cargo run --bin codex -- "$@"

# `codex exec`
exec *args:
    cargo run --bin codex -- exec "$@"

# Start `codex exec-server` and run codex-tui.
[no-cd]
tui-with-exec-server *args:
    {{ justfile_directory() }}/scripts/run_tui_with_exec_server.sh "$@"

# Run the CLI version of the file-search crate.
file-search *args:
    cargo run --bin code-file-search -- "$@"

# format code
fmt:
    cargo fmt -- --config imports_granularity=Item 2>/dev/null

fix *args:
    cargo clippy --fix --tests --allow-dirty "$@"

clippy *args:
    cargo clippy --tests "$@"

install:
    rustup show active-toolchain
    cargo fetch

# Run `cargo nextest` since it's faster than `cargo test`, though including
# --no-fail-fast is important to ensure all tests are run.
#
# Run `cargo install --locked cargo-nextest` if you don't have it installed.
# Prefer this for routine local runs. Workspace crate features are banned, so
# there should be no need to add `--all-features`.
test:
    RUST_MIN_STACK={{ rust_min_stack }} cargo nextest run --no-fail-fast

# Build and run Codex from source using Bazel.
# Note we have to use the combination of `[no-cd]` and `--run_under="cd $PWD &&"`
# to ensure that Bazel runs the command in the current working directory.
[no-cd]
bazel-codex *args:
    bazel run //codex-rs/cli:codex --run_under="cd $PWD &&" -- "$@"

[no-cd]
bazel-lock-update:
    bazel mod deps --lockfile_mode=update

[no-cd]
bazel-lock-check:
    {{ justfile_directory() }}/scripts/check-module-bazel-lock.sh

[no-cd]
local-code-rebuild:
    ./scripts/local/rebuild-path-code.sh

[no-cd]
local-code-rebuild-preflight:
    ./scripts/local/rebuild-path-code.sh --preflight

[no-cd]
local-code-rebuild-preflight-check:
    ./scripts/local/check-code-rebuild-preflight.sh

[no-cd]
local-remove-homebrew-code-link:
    ./scripts/local/remove-homebrew-code-link.sh

[no-cd]
local-upstream-import:
    ./scripts/local/update-from-upstream.sh

[no-cd]
local-upstream-cursors *args:
    ./scripts/local/upstream-cursors.sh "$@"

[no-cd]
local-release-notes:
    ./scripts/local/release-notes.sh

[no-cd]
local-product-health:
    ./scripts/local/fork-health.sh

[no-cd]
local-fork-health:
    ./scripts/local/fork-health.sh

[no-cd]
harness-smoke:
    ./tools/code-exec-harness/run-deterministic.sh

[no-cd]
local-cleanup-space *args:
    ./scripts/local/cleanup-space.sh "$@"

bazel-test:
    bazel test --test_tag_filters=-argument-comment-lint //... --keep_going

[no-cd]
bazel-clippy:
    bazel_targets="$({{ justfile_directory() }}/scripts/list-bazel-clippy-targets.sh)" && bazel build --config=clippy -- ${bazel_targets}

[no-cd]
bazel-argument-comment-lint:
    bazel build --config=argument-comment-lint -- $({{ justfile_directory() }}/tools/argument-comment-lint/list-bazel-targets.sh)

bazel-remote-test:
    bazel test --test_tag_filters=-argument-comment-lint //... --config=remote --platforms=//:rbe --keep_going

build-for-release:
    bazel build //codex-rs/cli:release_binaries --config=remote

# Run the MCP server
mcp-server-run *args:
    cargo run -p code-mcp-server -- "$@"