Handle rust_library_group dependencies in more places (#3617)

This gives downstream rules more flexibility in how deps are supplied to
various attributes

Co-authored-by: UebelAndre <[email protected]>

Author: dzbarsky

cargo/private/cargo_build_script.bzl

@@ -6,7 +6,7 @@ load("@rules_cc//cc:action_names.bzl", "ACTION_NAMES")
 load("@rules_cc//cc:find_cc_toolchain.bzl", find_cpp_toolchain = "find_cc_toolchain")
 load("@rules_cc//cc/common:cc_common.bzl", "cc_common")
 load("//rust:defs.bzl", "rust_common")
-load("//rust:rust_common.bzl", "BuildInfo")
+load("//rust:rust_common.bzl", "BuildInfo", "CrateGroupInfo", "DepInfo")
 
 # buildifier: disable=bzl-visibility
 load(
@@ -545,8 +545,19 @@ def _cargo_build_script_impl(ctx):
                 build_script_inputs.append(dep_build_info.out_dir)
 
     for dep in ctx.attr.deps:
-        for dep_build_info in dep[rust_common.dep_info].transitive_build_infos.to_list():
-            build_script_inputs.append(dep_build_info.out_dir)
+        dep_infos = []
+        if DepInfo in dep:
+            dep_infos = [dep[DepInfo]]
+        else:
+            dep_infos = [
+                dep_variant_info.dep_info
+                for dep_variant_info in dep[CrateGroupInfo].dep_variant_infos.to_list()
+                if dep_variant_info.dep_info
+            ]
+
+        for dep_info in dep_infos:
+            for dep_build_info in dep_info.transitive_build_infos.to_list():
+                build_script_inputs.append(dep_build_info.out_dir)
 
     experimental_symlink_execroot = ctx.attr._experimental_symlink_execroot[BuildSettingInfo].value or \
                                     _feature_enabled(ctx, "symlink-exec-root")
@@ -608,7 +619,7 @@ cargo_build_script = rule(
         ),
         "deps": attr.label_list(
             doc = "The Rust build-dependencies of the crate",
-            providers = [rust_common.dep_info],
+            providers = [[DepInfo], [CrateGroupInfo]],
             cfg = "exec",
         ),
         "link_deps": attr.label_list(
@@ -617,7 +628,6 @@ cargo_build_script = rule(
                 have the links attribute and therefore provide environment
                 variables to this build script.
             """),
-            providers = [rust_common.dep_info],
         ),
         "links": attr.string(
             doc = "The name of the native library this crate links against.",

rust/private/rust.bzl

@@ -23,6 +23,8 @@ load(
     "AllocatorLibrariesImplInfo",
     "AllocatorLibrariesInfo",
     "BuildInfo",
+    "CrateGroupInfo",
+    "CrateInfo",
     "LintsInfo",
 )
 load("//rust/private:rustc.bzl", "collect_extra_rustc_flags", "is_no_std", "rustc_compile_action")
@@ -70,15 +72,24 @@ def _assert_correct_dep_mapping(ctx):
                     ),
                 )
     for dep in ctx.attr.proc_macro_deps:
-        type = dep[rust_common.crate_info].type
-        if type != "proc-macro":
-            fail(
-                "{} listed {} in its proc_macro_deps, but it is not proc-macro, it is a {}. It should probably instead be listed in deps.".format(
-                    ctx.label,
-                    dep.label,
-                    type,
-                ),
-            )
+        if CrateInfo in dep:
+            types = [dep[CrateInfo].type]
+        else:
+            types = [
+                dep_variant_info.crate_info.type
+                for dep_variant_info in dep[CrateGroupInfo].dep_variant_infos.to_list()
+                if dep_variant_info.crate_info
+            ]
+
+        for type in types:
+            if type != "proc-macro":
+                fail(
+                    "{} listed {} in its proc_macro_deps, but it is not proc-macro, it is a {}. It should probably instead be listed in deps.".format(
+                        ctx.label,
+                        dep.label,
+                        type,
+                    ),
+                )
 
 def _rust_library_impl(ctx):
     """The implementation of the `rust_library` rule.
@@ -732,7 +743,7 @@ _common_attrs = {
             List of `rust_proc_macro` targets used to help build this library target.
         """),
         cfg = "exec",
-        providers = [rust_common.crate_info],
+        providers = [[CrateInfo], [CrateGroupInfo]],
     ),
     "rustc_env": attr.string_dict(
         doc = dedent("""\

test/dep_env/BUILD.bazel

@@ -1,13 +1,19 @@
 """Tests for passing configuration to cargo_build_script rules"""
 
+load("@rules_cc//cc:cc_library.bzl", "cc_library")
 load("//cargo:defs.bzl", "cargo_build_script", "cargo_dep_env")
-load("//rust:defs.bzl", "rust_library", "rust_test")
+load("//rust:defs.bzl", "rust_library", "rust_library_group", "rust_test")
 load(":dep_env.bzl", "create_dep_dir")
 
+cc_library(
+    name = "ignored",
+)
+
 cargo_build_script(
     name = "set_a_build",
     srcs = ["set_a.rs"],
     edition = "2018",
+    link_deps = [":ignored"],
     links = "X",
 )
 
@@ -26,6 +32,11 @@ rust_library(
     deps = [":set_a_build"],
 )
 
+rust_library_group(
+    name = "set_a_group",
+    deps = [":set_a"],
+)
+
 cargo_dep_env(
     name = "set_b",
     src = "set_b.env",
@@ -63,6 +74,14 @@ cargo_build_script(
     deps = [":set_a"],
 )
 
+cargo_build_script(
+    name = "read_c_group",
+    srcs = ["read_c.rs"],
+    edition = "2018",
+    link_deps = [":set_c"],
+    deps = [":set_a_group"],
+)
+
 cargo_build_script(
     name = "read_dep_dir",
     srcs = ["read_dep_dir.rs"],

test/rust_crate_group/BUILD.bazel

@@ -1,4 +1,15 @@
-load("@rules_rust//rust:defs.bzl", "rust_library", "rust_library_group", "rust_test")
+load("@rules_rust//rust:defs.bzl", "rust_library", "rust_library_group", "rust_proc_macro", "rust_test")
+
+rust_proc_macro(
+    name = "proc_dep1",
+    srcs = ["proc_dep1.rs"],
+    edition = "2021",
+)
+
+rust_library_group(
+    name = "proc_group",
+    deps = [":proc_dep1"],
+)
 
 rust_library(
     name = "dep1",
@@ -24,12 +35,14 @@ rust_library(
     name = "library",
     srcs = ["lib.rs"],
     edition = "2021",
+    proc_macro_deps = [":proc_group"],
     deps = [":dep1_and_2"],
 )
 
 rust_test(
     name = "test",
     srcs = ["test.rs"],
     edition = "2021",
+    proc_macro_deps = [":proc_group"],
     deps = [":dep1_and_2"],
 )

test/rust_crate_group/lib.rs

@@ -1,4 +1,4 @@
 fn _test() {
-    dep1::dep1();
+    proc_dep1::id!(dep1::dep1());
     dep2::dep2();
 }

test/rust_crate_group/proc_dep1.rs

@@ -0,0 +1,6 @@
+use proc_macro::TokenStream;
+
+#[proc_macro]
+pub fn id(input: TokenStream) -> TokenStream {
+    input
+}

test/rust_crate_group/test.rs

@@ -1,5 +1,5 @@
 #[test]
 fn test() {
-    dep1::dep1();
+    proc_dep1::id!(dep1::dep1());
     dep2::dep2();
 }