Fix ambiguous native dependencies in proc_macros and staticlibs (#1611)

`rustc` doesn't know how to deal with native dependencies that have the same name (specifying the full path to the native library does not currently work). `rules_rust` deals with this issue in `bin` and `cdylib` crate types by appending a hash to the different dependencies, so instead of `-lnative-dep -lnative-dep` the linking command line ends up being `-lnative-dep-{hash1} -lnative-dep-{hash2}`. This PR also applies the mechanism to `staticlib` and `proc-macro` crate types.

Author: scentini

rust/private/rustc.bzl

@@ -599,12 +599,7 @@ def collect_inputs(
     # flattened on each transitive rust_library dependency.
     additional_transitive_inputs = []
     ambiguous_libs = {}
-    if crate_info.type in ("staticlib", "proc-macro"):
-        additional_transitive_inputs = _collect_libs_from_linker_inputs(
-            dep_info.transitive_noncrates.to_list(),
-            use_pic,
-        )
-    elif crate_info.type in ("bin", "dylib", "cdylib"):
+    if crate_info.type not in ("lib", "rlib"):
         linker_inputs = dep_info.transitive_noncrates.to_list()
         ambiguous_libs = _disambiguate_libs(ctx.actions, toolchain, crate_info, dep_info, use_pic)
         additional_transitive_inputs = _collect_libs_from_linker_inputs(linker_inputs, use_pic) + [

test/unit/ambiguous_libs/BUILD.bazel

@@ -0,0 +1,4 @@
+load(":ambiguous_libs_test.bzl", "ambiguous_libs_test_suite")
+
+############################ UNIT TESTS #############################
+ambiguous_libs_test_suite(name = "ambiguous_libs_test_suite")

test/unit/ambiguous_libs/ambiguous_libs_test.bzl

@@ -0,0 +1,93 @@
+"""Unittests for ambiguous native dependencies."""
+
+load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
+load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
+
+def _ambiguous_deps_test_impl(ctx):
+    env = analysistest.begin(ctx)
+    tut = analysistest.target_under_test(env)
+    rustc_action = [action for action in tut.actions if action.mnemonic == "Rustc"][0]
+
+    # We depend on two C++ libraries named "native_dep", which we need to pass to the command line
+    # in the form of "-lstatic=native-dep-{hash}. The hash should differ.
+    link_args = [arg for arg in rustc_action.argv if arg.startswith("-lstatic=native_dep-")]
+    asserts.equals(env, 2, len(link_args))
+    asserts.false(env, link_args[0] == link_args[1])
+
+    return analysistest.end(env)
+
+ambiguous_deps_test = analysistest.make(_ambiguous_deps_test_impl)
+
+def _create_test_targets():
+    rust_library(
+        name = "rlib_with_ambiguous_deps",
+        srcs = ["foo.rs"],
+        edition = "2018",
+        deps = [
+            "//test/unit/ambiguous_libs/first_dep:native_dep",
+            "//test/unit/ambiguous_libs/second_dep:native_dep",
+        ],
+    )
+
+    rust_binary(
+        name = "binary",
+        srcs = ["bin.rs"],
+        edition = "2018",
+        deps = [":rlib_with_ambiguous_deps"],
+    )
+
+    rust_proc_macro(
+        name = "proc_macro",
+        srcs = ["foo.rs"],
+        edition = "2018",
+        deps = [":rlib_with_ambiguous_deps"],
+    )
+
+    rust_shared_library(
+        name = "shared_library",
+        srcs = ["foo.rs"],
+        edition = "2018",
+        deps = [":rlib_with_ambiguous_deps"],
+    )
+
+    rust_static_library(
+        name = "static_library",
+        srcs = ["foo.rs"],
+        edition = "2018",
+        deps = [":rlib_with_ambiguous_deps"],
+    )
+
+    ambiguous_deps_test(
+        name = "bin_with_ambiguous_deps_test",
+        target_under_test = ":binary",
+    )
+    ambiguous_deps_test(
+        name = "staticlib_with_ambiguous_deps_test",
+        target_under_test = ":static_library",
+    )
+    ambiguous_deps_test(
+        name = "proc_macro_with_ambiguous_deps_test",
+        target_under_test = ":proc_macro",
+    )
+    ambiguous_deps_test(
+        name = "cdylib_with_ambiguous_deps_test",
+        target_under_test = ":shared_library",
+    )
+
+def ambiguous_libs_test_suite(name):
+    """Entry-point macro called from the BUILD file.
+
+    Args:
+        name: Name of the macro.
+    """
+    _create_test_targets()
+
+    native.test_suite(
+        name = name,
+        tests = [
+            ":bin_with_ambiguous_deps_test",
+            ":staticlib_with_ambiguous_deps_test",
+            ":proc_macro_with_ambiguous_deps_test",
+            ":cdylib_with_ambiguous_deps_test",
+        ],
+    )

test/unit/ambiguous_libs/bin.rs

@@ -0,0 +1 @@
+fn main() {}

test/unit/ambiguous_libs/first_dep/BUILD.bazel

@@ -0,0 +1,8 @@
+load("@rules_cc//cc:defs.bzl", "cc_library")
+
+cc_library(
+    name = "native_dep",
+    srcs = ["first.cc"],
+    hdrs = ["first.h"],
+    visibility = ["//test/unit/ambiguous_libs:__pkg__"],
+)

test/unit/ambiguous_libs/first_dep/first.cc

@@ -0,0 +1,5 @@
+#include "first.h"
+
+int get_one() {
+    return 1;
+}

test/unit/ambiguous_libs/first_dep/first.h

@@ -0,0 +1 @@
+int get_one();

test/unit/ambiguous_libs/foo.rs

@@ -0,0 +1 @@
+

test/unit/ambiguous_libs/second_dep/BUILD.bazel

@@ -0,0 +1,8 @@
+load("@rules_cc//cc:defs.bzl", "cc_library")
+
+cc_library(
+    name = "native_dep",
+    srcs = ["second.cc"],
+    hdrs = ["second.h"],
+    visibility = ["//test/unit/ambiguous_libs:__pkg__"],
+)

test/unit/ambiguous_libs/second_dep/second.cc

@@ -0,0 +1,5 @@
+#include "second.h"
+
+int get_two() {
+    return 2;
+}

test/unit/ambiguous_libs/second_dep/second.h

@@ -0,0 +1 @@
+int get_two();