-
Notifications
You must be signed in to change notification settings - Fork 19
/
Copy path_P155_DucoSerialExternalHumiditySensor.ino
221 lines (195 loc) · 7.87 KB
/
_P155_DucoSerialExternalHumiditySensor.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
//#################################### Plugin 155: DUCO Serial Box Sensors ##################################
//
// DUCO Serial Gateway to read out the exernal installed Box Sensors
//
// https://github.com/arnemauer/Ducobox-ESPEasy-Plugin
// http://arnemauer.nl/ducobox-gateway/
//#######################################################################################################
#include "_Plugin_Helper.h"
#define PLUGIN_155
#define PLUGIN_ID_155 155
#define PLUGIN_NAME_155 "DUCO Serial GW - External Humidity Sensor"
#define PLUGIN_READ_TIMEOUT_155 1500 // DUCOBOX askes "live" CO2 sensor info, so answer takes sometimes a second.
#define PLUGIN_LOG_PREFIX_155 String("[P155] DUCO Ext. Hum. Sensor: ")
#define PLUGIN_VALUENAME1_155 "Temperature"
#define PLUGIN_VALUENAME2_155 "Relative_humidity"
boolean Plugin_155_init = false;
// when calling 'PLUGIN_READ', if serial port is in use set this flag and check in PLUGIN_ONCE_A_SECOND if serial port is free.
bool P155_waitingForSerialPort[TASKS_MAX];
bool P155_readTemperature[TASKS_MAX]; // true = read temperature, false = read humidity
typedef enum {
P155_CONFIG_NODE_ADDRESS = 0,
P155_CONFIG_LOG_SERIAL = 1,
} P155PluginConfigs;
typedef enum {
P155_DUCO_PARAMETER_TEMP = 73,
P155_DUCO_PARAMETER_CO2 = 74,
P155_DUCO_PARAMETER_RH = 75,
} P155DucoParameters;
boolean Plugin_155(byte function, struct EventStruct *event, String& string){
boolean success = false;
switch (function){
case PLUGIN_DEVICE_ADD:{
Device[++deviceCount].Number = PLUGIN_ID_155;
Device[deviceCount].Type = DEVICE_TYPE_DUMMY;
Device[deviceCount].VType = Sensor_VType::SENSOR_TYPE_TEMP_HUM;
Device[deviceCount].Ports = 0;
Device[deviceCount].PullUpOption = false;
Device[deviceCount].InverseLogicOption = false;
Device[deviceCount].FormulaOption = false;
Device[deviceCount].DecimalsOnly = true;
Device[deviceCount].ValueCount = 2;
Device[deviceCount].SendDataOption = true;
Device[deviceCount].TimerOption = true;
Device[deviceCount].GlobalSyncOption = true;
break;
}
case PLUGIN_GET_DEVICENAME: {
string = F(PLUGIN_NAME_155);
break;
}
case PLUGIN_GET_DEVICEVALUENAMES:{
strcpy_P(ExtraTaskSettings.TaskDeviceValueNames[0], PSTR(PLUGIN_VALUENAME1_155));
strcpy_P(ExtraTaskSettings.TaskDeviceValueNames[1], PSTR(PLUGIN_VALUENAME2_155));
break;
}
case PLUGIN_WEBFORM_LOAD:{
addFormNumericBox(F("Sensor Node address"), F("Plugin_155_NODE_ADDRESS"), PCONFIG(P155_CONFIG_NODE_ADDRESS), 0, 5000);
addFormCheckBox(F("Log serial messages to syslog"), F("Plugin155_log_serial"), PCONFIG(P155_CONFIG_LOG_SERIAL));
success = true;
break;
}
case PLUGIN_WEBFORM_SAVE:{
PCONFIG(P155_CONFIG_NODE_ADDRESS) = getFormItemInt(F("Plugin_155_NODE_ADDRESS"));
PCONFIG(P155_CONFIG_LOG_SERIAL) = isFormItemChecked(F("Plugin155_log_serial"));
success = true;
break;
}
case PLUGIN_EXIT: {
if(serialPortInUseByTask == event->TaskIndex){
serialPortInUseByTask = 255;
}
String log = PLUGIN_LOG_PREFIX_155;
log += F("EXIT PLUGIN_155");
addLogMove(LOG_LEVEL_INFO, log);
clearPluginTaskData(event->TaskIndex); // clear plugin taskdata
success = true;
break;
}
case PLUGIN_INIT:{
if(!Plugin_155_init && !ventilation_gateway_disable_serial){
Serial.begin(115200, SERIAL_8N1);
}
String log = PLUGIN_LOG_PREFIX_155;
log += F("Init plugin done.");
addLogMove(LOG_LEVEL_INFO, log);
P155_waitingForSerialPort[event->TaskIndex] = false;
P155_readTemperature[event->TaskIndex] = true; // read temperature first,
Plugin_155_init = true;
success = true;
break;
}
case PLUGIN_READ:{
if (Plugin_155_init && (PCONFIG(P155_CONFIG_NODE_ADDRESS) != 0) && !ventilation_gateway_disable_serial){
String log;
if(loglevelActiveFor(LOG_LEVEL_DEBUG)){
log = PLUGIN_LOG_PREFIX_155;
log += F("start read, eventid:");
log += event->TaskIndex;
addLogMove(LOG_LEVEL_DEBUG, log);
}
// check if serial port is in use by another task, if serial is in use set flag P155_waitingForSerialPort.
if(serialPortInUseByTask == 255){
serialPortInUseByTask = event->TaskIndex;
// toggle P155_readTemperature for this task to read temperature/humidity;
P155_readTemperature[event->TaskIndex] = !P155_readTemperature[event->TaskIndex];
if(P155_readTemperature[event->TaskIndex]){ // true = read temperature
startReadExternalSensors(PLUGIN_LOG_PREFIX_155, DUCO_DATA_EXT_SENSOR_TEMP, PCONFIG(P155_CONFIG_NODE_ADDRESS));
}else{ // false = read humidity
startReadExternalSensors(PLUGIN_LOG_PREFIX_155, DUCO_DATA_EXT_SENSOR_RH, PCONFIG(P155_CONFIG_NODE_ADDRESS));
}
}else{
if(loglevelActiveFor(LOG_LEVEL_DEBUG)){
char serialPortInUse[40];
snprintf(serialPortInUse, sizeof(serialPortInUse)," %u, set flag to read data later.", serialPortInUseByTask);
log = PLUGIN_LOG_PREFIX_155;
log += F("Serial port in use by taskid");
log += serialPortInUse;
addLogMove(LOG_LEVEL_DEBUG, log);
}
P155_waitingForSerialPort[event->TaskIndex] = true;
}
}
success = true;
break;
}
case PLUGIN_ONCE_A_SECOND:{
if(!ventilation_gateway_disable_serial){
// if this task is waiting for the serial port and the port is not used, start plugin_read.
if(P155_waitingForSerialPort[event->TaskIndex]){
if(serialPortInUseByTask == 255){
Plugin_155(PLUGIN_READ, event, string);
P155_waitingForSerialPort[event->TaskIndex] = false;
}
}
if(serialPortInUseByTask == event->TaskIndex){
if( (millis() - ducoSerialStartReading) > PLUGIN_READ_TIMEOUT_155){
if(loglevelActiveFor(LOG_LEVEL_DEBUG)){
String log = PLUGIN_LOG_PREFIX_155;
log += F("Serial reading timeout");
addLogMove(LOG_LEVEL_DEBUG, log);
}
DucoTaskStopSerial(PLUGIN_LOG_PREFIX_155);
serialPortInUseByTask = 255;
}
}
}
success = true;
break;
}
case PLUGIN_SERIAL_IN: {
// if we unexpectedly receive data we need to flush and return success=true so espeasy won't interpret it as an serial command.
if(serialPortInUseByTask == 255){
DucoSerialFlush();
success = true;
}
if(serialPortInUseByTask == event->TaskIndex){
uint8_t result =0;
bool stop = false;
bool receivedNewValue = false;
while( (result = DucoSerialInterrupt()) != DUCO_MESSAGE_FIFO_EMPTY && stop == false){
switch(result){
case DUCO_MESSAGE_ROW_END: {
if(P155_readTemperature[event->TaskIndex]){ // true = read temperature
receivedNewValue = readExternalSensorsProcessRow(PLUGIN_LOG_PREFIX_155, event->BaseVarIndex, DUCO_DATA_EXT_SENSOR_TEMP, PCONFIG(P155_CONFIG_NODE_ADDRESS), PCONFIG(P155_CONFIG_LOG_SERIAL));
}else{ // false = read humidity
receivedNewValue = readExternalSensorsProcessRow(PLUGIN_LOG_PREFIX_155, (event->BaseVarIndex + 1), DUCO_DATA_EXT_SENSOR_RH, PCONFIG(P155_CONFIG_NODE_ADDRESS), PCONFIG(P155_CONFIG_LOG_SERIAL));
}
if(receivedNewValue) sendData(event);
duco_serial_bytes_read = 0; // reset bytes read counter
break;
}
case DUCO_MESSAGE_END: {
DucoThrowErrorMessage(PLUGIN_LOG_PREFIX_155, result);
DucoTaskStopSerial(PLUGIN_LOG_PREFIX_155);
stop = true;
break;
}
}
}
success = true;
}
break;
}
case PLUGIN_FIFTY_PER_SECOND: {
if(serialPortInUseByTask == event->TaskIndex){
if(serialSendCommandInProgress){
DucoSerialSendCommand(PLUGIN_LOG_PREFIX_155);
}
}
success = true;
break;
}
}
return success;
}