Add contrib/thrift-maven-plugin to CMake build process.

Author: jmkeyes

CMakeLists.txt

@@ -128,6 +128,12 @@ if(BUILD_PYTHON)
     endif()
 endif()
 
+if(BUILD_CONTRIB)
+    if(BUILD_MAVEN_PLUGIN)
+        add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/contrib/thrift-maven-plugin)
+    endif()
+endif()
+
 # Create the uninstall target
 add_custom_target(uninstall "${CMAKE_COMMAND}" -P "${PROJECT_SOURCE_DIR}/build/cmake/uninstall.cmake")
 

build/cmake/DefineOptions.cmake

@@ -31,6 +31,7 @@ endif()
 CMAKE_DEPENDENT_OPTION(BUILD_TESTING "Build with unit tests" ON "HAVE_COMPILER" OFF)
 CMAKE_DEPENDENT_OPTION(BUILD_TUTORIALS "Build Thrift tutorials" ON "HAVE_COMPILER" OFF)
 option(BUILD_LIBRARIES "Build Thrift libraries" ON)
+option(BUILD_CONTRIB "Build Thrift contrib" ON)
 
 # Libraries to build
 
@@ -125,6 +126,13 @@ find_package(Python3
 CMAKE_DEPENDENT_OPTION(BUILD_PYTHON "Build Python library" ON
                        "BUILD_LIBRARIES;WITH_PYTHON;Python3_Interpreter_FOUND;Python3_Development_FOUND" OFF)
 
+## Maven Plugin
+option(WITH_MAVEN_PLUGIN "Build Maven plugin" ON)
+find_package(Java QUIET)
+find_package(Maven QUIET)
+CMAKE_DEPENDENT_OPTION(BUILD_MAVEN_PLUGIN "Build Maven plugin" ON
+                       "BUILD_CONTRIB;WITH_JAVA;JAVA_FOUND;MAVEN_FOUND" OFF)
+
 # Common library options
 # https://cmake.org/cmake/help/latest/variable/BUILD_SHARED_LIBS.html
 # Default on Windows is static, shared mode library support needs work...
@@ -167,6 +175,8 @@ message(STATUS "  Build compiler:                             ${BUILD_COMPILER}"
 message(STATUS "  Build libraries:                            ${BUILD_LIBRARIES}")
 message(STATUS "  Build tests:                                ${BUILD_TESTING}")
 MESSAGE_DEP(HAVE_COMPILER "Disabled because BUILD_COMPILER=OFF and no valid THRIFT_COMPILER is given")
+message(STATUS "  Build contrib:                              ${BUILD_CONTRIB}")
+MESSAGE_DEP(BUILD_CONTRIB "Disabled because BUILD_CONTRIB=OFF")
 message(STATUS "  Build type:                                 ${CMAKE_BUILD_TYPE}")
 message(STATUS)
 message(STATUS "Language libraries:")
@@ -218,6 +228,12 @@ if(MSVC)
     message(STATUS "  Using static runtime library:               ${WITH_MT}")
 endif(MSVC)
 message(STATUS)
+message(STATUS "Contributed:")
+message(STATUS)
+message(STATUS "  Build Maven plugin:                         ${BUILD_MAVEN_PLUGIN}")
+MESSAGE_DEP(WITH_MAVEN_PLUGIN "Disabled by WITH_MAVEN_PLUGIN=OFF")
+MESSAGE_DEP(JAVA_FOUND "Java Runtime missing")
+MESSAGE_DEP(MAVEN_FOUND "Maven missing")
 message(STATUS)
 message(STATUS "----------------------------------------------------------")
 endmacro(PRINT_CONFIG_SUMMARY)

build/cmake/FindMaven.cmake

@@ -0,0 +1,30 @@
+#
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+#   http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+#
+
+
+#  MAVEN_FOUND - system has Maven
+#  MAVEN_EXECUTABLE - the Maven executable
+#
+# It will search the environment variable MAVEN_HOME if it is set
+
+include(FindPackageHandleStandardArgs)
+
+find_program(MAVEN_EXECUTABLE NAMES mvn PATHS $ENV{MAVEN_HOME}/bin NO_CMAKE_FIND_ROOT_PATH)
+find_package_handle_standard_args(Maven DEFAULT_MSG MAVEN_EXECUTABLE)
+mark_as_advanced(MAVEN_EXECUTABLE)

contrib/thrift-maven-plugin/CMakeLists.txt

@@ -0,0 +1,74 @@
+#
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+#   http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+#
+
+if(NOT THRIFTMAVENPLUGIN_INSTALL_DIR)
+    if(IS_ABSOLUTE "${CONTRIB_INSTALL_DIR}")
+        set(THRIFTMAVENPLUGIN_INSTALL_DIR "${CONTRIB_INSTALL_DIR}/thrift-maven-plugin")
+    else()
+        set(THRIFTMAVENPLUGIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${CONTRIB_INSTALL_DIR}/thrift-maven-plugin")
+    endif()
+endif()
+
+set(PRELEASE "true")
+if (CMAKE_BUILD_TYPE MATCHES DEBUG)
+    set(PRELEASE "false")
+endif ()
+
+set(MAVEN_OUTPUT_JAR "${CMAKE_CURRENT_SOURCE_DIR}/target/thrift-maven-plugin-${thrift_VERSION}.jar")
+
+file(GLOB_RECURSE THRIFTMAVENPLUGIN_SOURCES LIST_DIRECTORIES false
+    "${CMAKE_CURRENT_SOURCE_DIR}/src/*"
+    "${CMAKE_CURRENT_SOURCE_DIR}/pom.xml")
+
+add_custom_command(OUTPUT "${MAVEN_OUTPUT_JAR}"
+    COMMENT "Building Maven plugin using Maven"
+    COMMAND ${MAVEN_EXECUTABLE} clean package
+        -B -DskipTests
+        -Drelease=${PRELEASE}
+        -Dthrift.version=${thrift_VERSION}
+    DEPENDS ${THRIFTMAVENPLUGIN_SOURCES}
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+add_custom_target(ThriftMavenPlugin ALL DEPENDS "${MAVEN_OUTPUT_JAR}")
+
+# Enable publishing from CMake if the publishing information is provided
+add_custom_target(ThriftMavenPluginMavenPublish
+    COMMENT "Publishing Maven plugin to Apache Maven staging"
+    DEPENDS ThriftMavenPlugin
+    COMMAND ${MAVEN_EXECUTABLE} deploy
+        -B -DskipTests
+        -Drelease=${PRELEASE}
+        -Dthrift.version=${thrift_VERSION}
+    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+# Hook the CMake install process to the results from make ALL.
+# This works best when 'make all && sudo make install/fast' is used.
+install(FILES "${MAVEN_OUTPUT_JAR}" DESTINATION ${THRIFTMAVENPLUGIN_INSTALL_DIR})
+
+if(BUILD_TESTING)
+    add_test(NAME ThriftMavenPluginTest
+        COMMAND ${MAVEN_EXECUTABLE} test
+            -B
+            -Drelease=${PRELEASE}
+            -Dthrift.version=${thrift_VERSION}
+            -Dthrift.compiler=${THRIFT_COMPILER}
+        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
+endif()