build.gradle

/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * Copyright 2020-2026 Agorapulse.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
plugins {
    id 'lifecycle-base'
}

if (!project.hasProperty('mavenCentralUsername'))       ext.mavenCentralUsername       = System.getenv('MAVEN_CENTRAL_USERNAME') ?: '**UNDEFINED**'
if (!project.hasProperty('mavenCentralPassword'))       ext.mavenCentralPassword       = System.getenv('MAVEN_CENTRAL_PASSWORD') ?: '**UNDEFINED**'
if (!project.hasProperty('signingInMemoryKeyId'))       ext.signingInMemoryKeyId       = System.getenv('SIGNING_KEY_ID') ?: '**UNDEFINED**'
if (!project.hasProperty('signingInMemoryKeyPassword')) ext.signingInMemoryKeyPassword = System.getenv('SIGNING_PASSWORD') ?: '**UNDEFINED**'
if (!project.hasProperty('signingInMemoryKey'))         ext.signingInMemoryKey         = System.getenv('SIGNING_SECRET_KEY_PATH') ? rootProject.file(System.getenv('SIGNING_SECRET_KEY_PATH')).text : '**UNDEFINED**'

allprojects {
    repositories {
        mavenCentral()
    }
}

subprojects {
    plugins.withId('com.agorapulse.gradle.micronaut-library') {
        micronaut {
            importMicronautPlatform = true
            testRuntime 'spock'
            processing {
                incremental false
            }
        }
    }

    plugins.withId('com.vanniktech.maven.publish') {
        mavenPublishing {
            publishToMavenCentral(true)
            signAllPublications()

            pom {
                name = 'Micronaut Segment'
                description = 'Segment.com analytics integration for Micronaut'
                inceptionYear = '2021'
                url = "https://github.com/${slug}"
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'musketyr'
                        name = 'Vladimir Orany'
                        url = 'https://github.com/musketyr/'
                    }
                }
                scm {
                    url = "https://github.com/${slug}.git"
                    connection = "scm:git:git://github.com/${slug}.git"
                    developerConnection = "scm:git:ssh://git@github.com/${slug}.git"
                }
            }
        }

        signing {
            useInMemoryPgpKeys(rootProject.ext.signingInMemoryKey, rootProject.ext.signingInMemoryKeyPassword)
            sign publishing.publications
        }
    }
}