settings.gradle

/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * Copyright 2018-2025 Agorapulse.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
pluginManagement {
    repositories {
        gradlePluginPortal()
    }
    plugins {
        id 'org.kordamp.gradle.settings'            version kordampVersion
        id 'org.kordamp.gradle.groovy-project'      version kordampVersion
        id 'org.kordamp.gradle.checkstyle'          version kordampVersion
        id 'org.kordamp.gradle.codenarc'            version kordampVersion
        id 'org.kordamp.gradle.guide'               version kordampVersion
        id 'org.kordamp.gradle.coveralls'           version kordampVersion
        id 'org.ajoberstar.git-publish'             version gitPublishPluginVersion
        id 'io.github.gradle-nexus.publish-plugin'  version nexusPluginVersion
    }
}

buildscript {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
        classpath("org.jetbrains.kotlin.plugin.allopen:org.jetbrains.kotlin.plugin.allopen.gradle.plugin:$kotlinVersion")
        classpath("com.google.devtools.ksp:com.google.devtools.ksp.gradle.plugin:$kspVersion")
        classpath("io.micronaut.gradle:micronaut-minimal-plugin:$micronautGradlePluginVersion")
    }
}


plugins {
    id 'org.kordamp.gradle.settings'
    id 'com.gradle.enterprise' version '3.15.1'
}

gradleEnterprise {
    buildScan {
        publishAlways()
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
    }
}


projects {
    directories = ['subprojects', 'examples', 'docs', 'benchmarks', 'platforms']

    plugins {
        dir('subprojects') {
            id 'io.micronaut.minimal.library'
        }
    }
}

rootProject.name = 'micronaut-aws-sdk'