Add Gradle tasks for start/stop AA server

Author: Lipen

jacodb-ets/build.gradle.kts

@@ -1,5 +1,7 @@
 import com.github.gradle.node.npm.task.NpmTask
 import java.io.FileNotFoundException
+import java.io.IOException
+import java.net.Socket
 
 plugins {
     kotlin("plugin.serialization")
@@ -40,6 +42,73 @@ tasks.register<NpmTask>("runArkAnalyzerServer") {
     args = listOf("run", "server")
 }
 
+val port = 50051
+val serverPidFile = layout.buildDirectory.file("server.pid")
+val serverLogFile = layout.buildDirectory.file("server.log")
+
+tasks.register("startArkAnalyzerServer") {
+    group = "arkanalyzer"
+    description = "Start the ArkAnalyzer server in background."
+    doLast {
+        val process = ProcessBuilder("npm", "run", "server")
+            .directory(file("arkanalyzer"))
+            .redirectOutput(serverLogFile.get().asFile)
+            .redirectErrorStream(true)
+            .apply {
+                val env = environment()
+                env["ARKANALYZER_PORT"] = port.toString()
+            }
+            .start()
+
+        val pid = process.pid()
+        serverPidFile.get().asFile.writeText(pid.toString())
+        println("ArkAnalyzer server started with PID $pid")
+        println("Logs are being written to: ${serverLogFile.get().asFile.absolutePath}")
+
+        // Wait until the server is ready
+        val maxRetries = 10
+        val retryDelay = 100L // in milliseconds
+        repeat(maxRetries) {
+            try {
+                Socket("localhost", port).use { socket ->
+                    if (socket.isConnected) {
+                        println("ArkAnalyzer server is ready on port $port")
+                        return@doLast
+                    }
+                }
+            } catch (_: IOException) {
+                // Server not ready yet, retry
+            }
+            Thread.sleep(retryDelay)
+        }
+        throw RuntimeException(
+            "ArkAnalyzer server did not start within the expected time. " +
+                "Check the logs at ${serverLogFile.get().asFile.absolutePath} for more details."
+        )
+    }
+}
+
+tasks.register("stopArkAnalyzerServer") {
+    group = "arkanalyzer"
+    description = "Stop the ArkAnalyzer server."
+    doLast {
+        if (!serverPidFile.get().asFile.exists()) {
+            println("ArkAnalyzer server is not running (PID file not found).")
+            return@doLast
+        }
+        val pid = serverPidFile.get().asFile.readText().trim().toLong()
+        println("Stopping ArkAnalyzer server with PID $pid")
+        try {
+            ProcessBuilder("kill", pid.toString()).start().waitFor()
+            println("ArkAnalyzer server with PID $pid stopped.")
+        } catch (e: Exception) {
+            println("Failed to stop ArkAnalyzer server with PID $pid: ${e.message}")
+        } finally {
+            serverPidFile.get().asFile.delete()
+        }
+    }
+}
+
 // Example usage:
 // ```
 // export ARKANALYZER_DIR=~/dev/arkanalyzer