build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "net.ltgt.gradle:gradle-apt-plugin:0.8"
    }
}

allprojects {
    apply plugin: "net.ltgt.apt"
    apply plugin: "java"
    apply plugin: "idea"

    repositories {
        mavenCentral()
    }

    dependencies {
        compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.7'
        compile group: 'ch.qos.logback', name: 'logback-core', version: '1.1.2'
        compile group: 'ch.qos.logback', name: 'logback-classic', version: '1.1.2'
        compile group: 'com.fasterxml.jackson.dataformat', name: 'jackson-dataformat-yaml', version: '2.7.5'
        compile group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.7.5'
        compile group: 'com.fasterxml.jackson.core', name: 'jackson-annotations', version: '2.7.5'
        compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.7.5'
        compile group: 'com.google.guava', name: 'guava', version: '19.0'

        compile group: 'com.google.dagger', name: 'dagger', version: '2.6'
        apt group: 'com.google.dagger', name: 'dagger-compiler', version: '2.6'

        compile group: 'org.apache.commons', name: 'commons-csv', version: '1.4'
        compile group: 'org.apache.commons', name: 'commons-math3', version: '3.6.1'

    }
}

project(':core') {

}


project(':rio') {
    repositories {
        maven {
            it.name = "WPI"
            it.url = "http://first.wpi.edu/FRC/roborio/maven/release"
        }
    }

    configurations {
        source
    }

    dependencies {
        compile project(':core')

        compile 'edu.wpi.first.wpilib.networktables.java:NetworkTables:+:desktop'
        compile 'edu.wpi.first.wpilib.networktables.java:NetworkTables:+:arm'
        compile 'edu.wpi.first.wpilibj:wpilibJavaFinal:+'

        source 'edu.wpi.first.wpilib.networktables.java:NetworkTables:+:sources'
        source 'edu.wpi.first.wpilibj:wpilibJavaFinal:+:sources'
    }

    evaluationDependsOn(':core')

    def robotClass = 'org.teamtators.rotator.Robot'

    jar {
        from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
        manifest {
            attributes(
                    'Main-Class': 'edu.wpi.first.wpilibj.RobotBase',
                    'Robot-Class': robotClass
            )
        }
    }
}

project(':desktop') {
    apply plugin: 'application'

    dependencies {
        compile project(':core')
    }

    evaluationDependsOn(':core')

    mainClassName = 'org.teamtators.rotator.Main'

    def jarManifest = {
        attributes 'Main-Class': mainClassName
    }

    jar {
        from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
        manifest jarManifest
    }

    run {
        workingDir = file('../')
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '3.0'
}