build.gradle

import edu.wpi.first.gradlerio.GradleRIOPlugin
import edu.wpi.first.gradlerio.frc.FRCJavaArtifact
import edu.wpi.first.gradlerio.frc.RoboRIO
import java.text.SimpleDateFormat

plugins {
    id "java"
    id "idea"
    id "org.jetbrains.kotlin.jvm" version "1.2.50"
    id "edu.wpi.first.GradleRIO" version "2018.06.21"
}

ext.kotlinVersion = "1.2.50"
ext.sertainVersion = "1.2.1"
ext.ktlintVersion = "0.19.0"
ext.gsonVersion = "2.8.5"

check.dependsOn "ktlint"
compileKotlin.dependsOn "versionTxt"
tasks.whenTaskAdded { task ->
    if (task.name == "deploy" || task.name == "deployMain") task.dependsOn "assemble"
}

repositories {
    google()
    jcenter()
    maven { url "https://jitpack.io" }
}

configurations {
    ktlint
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"

    compile "org.sert2521.sertain:core:$sertainVersion"
    compile "com.google.code.gson:gson:$gsonVersion"

    compile wpilib()
    compile navx()
    compile ctre()
    compile pathfinder()
    compile openrio.powerup.matchData()

    ktlint "com.github.shyiko:ktlint:$ktlintVersion"
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

deploy {
    targets {
        target("roborio", RoboRIO) {
            team = getTeamOrDefault(2521)
        }
    }

    artifacts {
        artifact("main", FRCJavaArtifact) {
            targets << "roborio"

            debug = getDebugOrDefault(false)
        }
    }
}

wpi {
    wpilibVersion = "2018.4.1"
    ntcoreVersion = "4.1.0"
    opencvVersion = "3.2.0"
    cscoreVersion = "1.3.0"
    wpiutilVersion = "3.2.0"

    ctreVersion = "5.5.1.0"
    navxVersion = "3.0.348"

    shuffleboardVersion = "1.3.1"
}

jar {
    from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    manifest GradleRIOPlugin.javaManifest("org.sert2521.powerup.Poe")
}

task ktlint(type: JavaExec) {
    main = "com.github.shyiko.ktlint.Main"
    classpath = configurations.ktlint
    args "src/**/*.kt"
}

def getGitHash = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine "git", "rev-parse", "HEAD"
        standardOutput = stdout
    }
    return stdout.toString().trim()
}

def getGitBranch = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine "git", "rev-parse", "--abbrev-ref", "HEAD"
        standardOutput = stdout
    }
    return stdout.toString().trim()
}

def getGitFilesChanged = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine "git", "diff", "--name-only", "HEAD"
        standardOutput = stdout
    }
    return stdout.toString().trim().replace("\n", ", ")
}

task versionTxt()  {
    doLast {
        String resourcesDir = "$projectDir/src/main/resources"
        new File("$resourcesDir/branch.txt").text = getGitBranch()
        new File("$resourcesDir/commit.txt").text = getGitHash()
        new File("$resourcesDir/changes.txt").text = getGitFilesChanged()
        new File("$resourcesDir/buildtime.txt").text =
                new SimpleDateFormat("dd-MM-yyyy HH:mm:ss").format(new Date())
    }
}

wrapper {
    gradleVersion = "4.9"
}