script-ch2.rpy

# Chapter 2 static content. Poem responses called from here are in script-poemresponses.rpy

label ch2_main:
    scene bg club_day
    with dissolve_scene_half
    play music t2
    "Another day passes, and it's time for the club meeting already."
    "I've gotten a little more comfortable here over the past couple days."
    "Entering the clubroom, the usual scene greets me."
    show sayori 2x at t11 zorder 2
    s "Hi [player]~"
    mc "Yo, Sayori."
    mc "Looks like you're in a good mood today."
    s 1q "Ehehe~"
    s "I'm just still not used to you being in the club, that's all."
    mc "I see..."
    mc "...That's a pretty simple thing to get you in a good mood."
    mc "But I guess it's always the simple things with you, anyway."
    s 1d "Speaking of which..."
    s "I'm kinda hungry..."
    s "Will you come with me to buy a snack?"
    mc "No thanks."
    s 4h "Eh??"
    s "T-That's not like you at all!!"
    mc "I have my reasons."
    mc "Why don't we take a look at your purse, Sayori?"
    s 4l "E-Eh?"
    show sayori at s11
    s "Why that...all of a sudden?"
    mc "No reason, really."
    mc "I just wanted to look at it."
    s 1l "A-Ah..."
    show sayori at t11 zorder 2
    "Sayori nervously retrieves her coin purse."
    "She fumbles with the latch and gets it open."
    "Then, she turns it upside-down and lets its contents spill onto the desk."
    "Only two small coins fall out."
    s 5a "A-Ahaha..."
    mc "I knew it..."
    mc "I can see right through you, Sayori."
    s 5c "That's not fair!"
    s "How did you even know?"
    mc "It's simple."
    mc "If you had enough money in the first place, you would have bought a snack before coming to the clubroom."
    mc "So, either you're not hungry and wanted an excuse to take a walk..."
    mc "Or, you planned to conveniently forget that you spent all your money, so that I would lend you some!"
    mc "But there's one more thing..."
    mc "...You're always hungry!"
    mc "And so, that only leaves the one option!"
    s 4p "Uwaaa~!"
    s "I give up!"
    s "Don't make me feel guiltyyy!"
    mc "If you feel guilty, that means you deserve to feel guilty..."
    show yuri 1c at t33 zorder 2
    y "Ahaha."
    "Yuri suddenly giggles."
    show sayori 4g
    mc "Eh?"
    "I didn't notice that she was listening in."
    "Her face is in her book, as always."
    show yuri 3n at h33
    y "A-Ah!"
    y "I wasn't listening or anything--!"
    y 3o "It was just...something in my book..."
    show sayori at f32 zorder 3
    s 1h "Yuriiii..."
    s "Tell [player] to let me borrow some money..."
    show sayori at t32 zorder 2
    show yuri at f33 zorder 3
    y 3h "That's--!"
    y "Don't get me involved like that, Sayori..."
    y "Besides..."
    y 1k "You should only buy what you can responsibly afford..."
    y "And frankly, after pulling a mischievous little stunt like that, your suffering is fair enough retribution."
    show sayori 1b
    mc "..."
    y 3n "Ah--!"
    y "Did I just..."
    y 4c "I-I didn't mean that!!"
    y "I got too absorbed into my book..."
    y "Uu..."
    show yuri at t33 zorder 2
    show sayori at f32 zorder 3
    s 1r "Ahaha!"
    s 3x "I really like when you speak your mind, Yuri..."
    s "It doesn't happen much, but it's a fun side of you!"
    show sayori at t32 zorder 2
    show yuri at f33 zorder 3
    y 3v "That's..."
    y "There's no way you could think that..."
    show yuri at t33 zorder 2
    show sayori at f32 zorder 3
    s 1x "You were right, though..."
    s "I did something bad and now I have to accept the revolution."
    show sayori at t32 zorder 2
    show yuri at f33 zorder 3
    y 3h "Retribution..."
    show yuri at t33 zorder 2
    show sayori at f32 zorder 3
    s 1l "That!"
    show sayori at t32 zorder 2
    show yuri at f33 zorder 3
    y "Still, coming from you, Sayori..."
    y 1a "I guess there's a little devil inside all of us, isn't there?"
    show yuri at t33 zorder 2
    show sayori at f32 zorder 3
    s 1q "Ehehe..."
    show sayori at t32 zorder 2
    mc "Don't let her fool you."
    mc "Sayori knows exactly what she's doing."
    mc "After all, she told you guys she was bringing me to the club before she even told me..."
    show sayori at f32 zorder 3
    s 1h "B-But...!"
    s "You wouldn't have come if it weren't for the cupcakes..."
    s "So I had to trick Natsuki into making them!"
    show sayori at t32 zorder 2
    mc "Come on, give me more credit than that, Sayori."
    show sayori at f32 zorder 3
    s 1l "Ehehe..."
    play sound "sfx/slap.ogg"
    show white zorder 4:
        alpha 0.6
        linear 0.25 alpha 0.0
    show sayori 4p at hf32 zorder 3
    "{i}Pwap!{/i}"
    hide white
    s 4p "Kyaa--!"
    "Out of nowhere, something smacks Sayori in the face and tumbles onto the desk."
    s 4j "Ow..."
    s "What was--"
    s 4n "Eh??"
    s "A-A cookie!"
    "Sure enough, it's a giant cookie wrapped in plastic."
    "Sayori glances around."
    s 4m "I-Is this a miracle??"
    s "It's because I paid my restitution!"
    show sayori at t32 zorder 2
    mc "Retribution..."
    show sayori 4n
    show yuri at f33 zorder 3
    y 1u "Actually, that one almost worked..."
    show yuri at t33 zorder 2
    show natsuki 3z at f31 zorder 3
    n "Ahahaha!"
    n "I {i}was{/i} just gonna give it to you."
    n 3d "But then I heard you blab about the cupcakes."
    n "It was totally worth seeing your reaction, though. Ahaha!"
    show natsuki at t31 zorder 2
    show sayori at f32 zorder 3
    s 4m "N-Natsuki!"
    s "That's so nice of you!"
    s 4s "I'm so happy..."
    "Sayori hugs the cookie."
    show sayori at t32 zorder 2
    mc "Jeez, just eat it..."
    "Sayori rapidly tears open the wrapper and takes a big bite."
    show sayori at f32 zorder 3
    s 4q "Sho good..."
    show sayori at hf32 zorder 3
    s 4o "Mmf--!"
    "Sayori suddenly clasps her hands over her mouth."
    s 4p "I bit my tongue..."
    show sayori at t32 zorder 2
    show natsuki at f31 zorder 3
    n 3a "Ehehe."
    n "You're going through a lot over just one cookie."
    "Natsuki takes a bite of her own cookie."
    show natsuki at t31 zorder 2
    show sayori at f32 zorder 3
    s 1c "Ah, yours looks really good too, Natsuki!"
    s "Can I try it?"
    show sayori at t32 zorder 2
    show natsuki at f31 zorder 3
    n 4e "Jeez..."
    n "Beggars can't be choosers!"
    show natsuki at t31 zorder 2
    show sayori at f32 zorder 3
    s 1h "But yours is chocolate..."
    show sayori at t32 zorder 2
    show natsuki at f31 zorder 3
    n 4c "Yeah, why do you think I gave you that one?"
    show natsuki at t31 zorder 2
    show sayori at f32 zorder 3
    s 1g "Fine..."
    s 1q "Still, I'm really happy that you shared this one with me."
    s "Ehehe~"
    show sayori at t21 zorder 2 behind natsuki
    "Sayori gets out of her seat and goes behind Natsuki, then wraps her arms around her."
    n 12c "Ah-- Jeez..."
    n "I get it, I get it."
    "Cookie still in hand, Natsuki reaches up to nudge Sayori off of her."
    show sayori 1n at h21
    s "...{i}Om.{/i}"
    "Sayori suddenly leans down and takes a bite out of Natsuki's cookie."
    n 1p "{i}H-Hey!!{/i}"
    n "Did you seriously just do that?!"
    s 1q "Uhuhuhu!"
    show sayori at lhide
    hide sayori
    "Mouth full, Sayori trots away to safety."
    show yuri 1c
    "Yuri and I laugh as well."
    show yuri 1a
    show natsuki at f31 zorder 3
    n 1w "Jeez! You're such a kid sometimes!"
    n 1h "Monika! Can you tell Sayori--"
    n 1c "--Eh?"
    "Natsuki glances around."
    "Monika isn't in the clubroom."
    n 4q "Ugh..."
    n "Where's Monika, anyway?"
    show natsuki at t31 zorder 2
    show yuri 2f at f33 zorder 3
    y "Good question..."
    y "Have any of you heard anything about her being late today?"
    show sayori 1b at f32 zorder 3
    show yuri at t33 zorder 2
    s "Not me..."
    show sayori at t32 zorder 2
    mc "Yeah, I haven't either."
    show yuri at f33 zorder 3
    y 2l "Hm..."
    y "That's a bit unusual."
    show yuri at t33 zorder 2
    show sayori at f32 zorder 3
    s 1g "I hope she's okay..."
    show sayori at t32 zorder 2
    show natsuki 3k at f31 zorder 3
    n "Of course she's okay."
    n "She probably just had something to do today."
    n 3t "She's pretty popular, after all..."
    show natsuki at t31 zorder 2
    show sayori 4m at f32 zorder 3
    s "Eh?"
    s "You don't think she..."
    s "She has a...!"
    show sayori at t32 zorder 2
    show yuri 1a at f33 zorder 3
    y "Ahaha. I wouldn't be surprised."
    y "She's probably more desirable than all of us combined."
    show yuri at t33 zorder 2
    show sayori 1r at f32 zorder 3
    s "Ehehe, that's true..."
    show sayori at t32 zorder 2
    show natsuki 1p at f31 zorder 3
    n "Excuse me?!"
    hide natsuki
    hide sayori
    hide yuri
    with wipeleft
    "Suddenly, the door swings open."
    show monika 1g at l41
    m "Sorry! I'm super sorry!"
    mc "Ah, there you are..."
    m "I didn't mean to be late..."
    m "I hope you guys weren't worried or anything!"
    show sayori 4n at f42 zorder 3
    s "Eh??"
    s "Monika chose the club over her boyfriend after all!"
    s "You're so strong-willed!"
    show sayori at t42 zorder 2
    show monika at f41 zorder 3
    m 1l "B-Boyfriend...?"
    m "What on Earth are you talking about?"
    "Monika quizzically glances at me."
    show monika at t41 zorder 2
    mc "Ah, never mind that..."
    mc "What held you up, anyway?"
    show monika at f41 zorder 3
    m 1e "Ah..."
    m "Well, my last period today was study hall."
    m "To be honest, I kind of just lost track of time..."
    m "Ahaha..."
    show monika at t41 zorder 2
    show natsuki 2c at f43 zorder 3
    n "That makes no sense, though."
    n "You would have heard the bell ring, at least."
    show natsuki at t43 zorder 2
    show monika at f41 zorder 3
    m 1m "I must not have heard it, since I was practicing piano..."
    show monika at t41 zorder 2
    show yuri 1e at f44 zorder 3
    y "Piano...?"
    y "I wasn't aware you played music as well, Monika."
    show yuri at t44 zorder 2
    show monika at f41 zorder 3
    m 1l "Ah, I don't, really...!"
    m "I kind of just started recently."
    m 1m "I've always wanted to learn piano."
    show monika at t41 zorder 2
    show sayori 4x at f42 zorder 3
    s "That's so cool!"
    s "You should play something for us, Monika!"
    show sayori at t42 zorder 2
    show monika at f41 zorder 3
    m "That's..."
    "Monika looks at me."
    m 1a "Maybe once I get a little bit better, I will."
    show monika at t41 zorder 2
    show sayori at f42 zorder 3
    s 4q "Yay~!"
    show sayori at t42 zorder 2
    mc "That sounds cool."
    mc "I'd also look forward to it."
    show monika at f41 zorder 3
    m 1b "Is that so?"
    m "In that case..."
    m "I won't let you down, [player]."
    show sayori at thide zorder 1
    show natsuki at thide zorder 1
    show yuri at thide zorder 1
    show monika 5 at t11 zorder 2
    hide sayori
    hide natsuki
    hide yuri
    "Monika smiles sweetly."
    mc "Ah..."
    mc "I didn't mean any pressure or anything like that!"
    m 1a "Ahaha, don't worry."
    m "I've been practicing a whole lot recently."
    m "And I'd really love the chance to share once I'm ready."
    mc "I see..."
    mc "In that case, best of luck."
    m 1j "Thanks~!"
    m 1a "So, I didn't miss anything, did I?"
    mc "Not...not really."
    show monika at thide zorder 1
    hide monika
    "I choose to leave out Sayori's mischievous escapade."
    "I'm sure Natsuki will end up complaining to her, anyway."
    "It looks like everyone has already settled down."
    "Sayori somehow already finished her entire cookie."
    "Yuri is back to her book, and Natsuki disappeared into the closet."

    
    #Call exclusive scene
    $ nextscene = poemwinner[0] + "_exclusive_" + str(eval(poemwinner[0][0] + "_appeal"))
    call expression nextscene from _call_expression_3
        
    #After exclusive scene, we go back to poem responses

    return


label ch2_end:
    stop music fadeout 1.0
    scene bg club_day
    show monika 4b at t32 zorder 2
    with wipeleft_scene
    play music t3
    m "Okay, everyone!"
    m "We're all done reading each other's poems, right?"
    m "I have something extra planned today, so if everyone could come sit at the front of the room..."
    show natsuki 3c at f31 zorder 3
    n "Is this about the festival?"
    show natsuki at t31 zorder 2
    show monika 1j at f32 zorder 3
    m "Well, sort of~"
    show monika 1a at t32 zorder 2
    show natsuki 1m at f31 zorder 3
    n "Ugh. Do we really have to do something for the festival?"
    n "It's not like we can put together anything good in just a few days."
    n "We'll just end up embarrassing ourselves instead of getting any new members."
    show yuri 2g at f33 zorder 3
    show natsuki at t31 zorder 2
    y "That's a concern of mine as well."
    y "I don't really do well with last-minute preparations..."
    show yuri at t33 zorder 2
    show monika at f32 zorder 3
    m 1b "Don't worry so much!"
    m "We're going to keep it simple, okay?"
    m 1a "We won't need much more than a few decorations."
    m "Sayori has been working on posters, and I've designed some pamphlets we can give out during the event."
    show monika at t32 zorder 2
    show natsuki 3c at f31 zorder 3
    n "Okay, that's great and all..."
    n "But that doesn't tell us what we're actually going to be doing for the event."
    show natsuki at t31 zorder 2
    show monika at f32 zorder 3
    m 1d "Ah, sorry! I thought you heard about it already."
    m 1b "We're going to be performing!"
    show monika at t32 zorder 2
    show natsuki at f31 zorder 3
    n 3h "Performing?"
    show natsuki at t31 zorder 2
    show yuri at f33 zorder 3
    y 3n "P..."
    y 3o "Um, Monika..."
    show yuri at t33 zorder 2
    show monika at f32 zorder 3
    m 1k "Yeah! We're going to be having a poetry performance."
    m 1b "Each of us are going to choose a poem to recite during the event."
    m "But the cool part is, we're also going to let anyone else come up and recite poems too!"
    m 1a "Sayori's putting it on all the posters in case anyone wants to prepare ahead of time."
    show yuri at t44 zorder 2
    show monika at t43 zorder 2
    show natsuki at t42 zorder 2
    show sayori 4q at l41
    s "Ehehe~"
    "Sayori, who's been coloring a poster, holds it up for us to see."
    show natsuki 4w at f42 zorder 3
    n "Are you kidding me, Monika?"
    n "You didn't...you didn't already start putting those posters up, did you?"
    show natsuki at t42 zorder 2
    show monika at f43 zorder 3
    m 1d "Eh? Well, I did..."
    m "Do you really think it's that bad of an idea...?"
    show monika at t43 zorder 2
    show natsuki 1s at f42 zorder 3
    n "Well, no."
    n "It's not a bad idea."
    n 1w "But I didn't sign up for this, you know!"
    n 1x "There is {i}no{/i} way I'm going to be performing in front of a group of people like that!"
    show natsuki at t42 zorder 2
    show yuri at f44 zorder 3
    y 3r "I...I agree with Natsuki!"
    y 3w "I could never...in my life...do something like that..."
    "Imagining it, Yuri shakes her head in fear."
    show yuri at t44 zorder 2
    show sayori 1g at f41 zorder 3
    s "Guys..."
    show sayori at t41 zorder 2
    show monika at f43 zorder 3
    m 1g "No, Sayori..."
    m "I understand where they're coming from."
    m "Remember that Natsuki and Yuri have never shared their poems with anyone until just a couple days ago..."
    m "It's a lot to ask for them to recite their poems out loud to a whole room full of people."
    m 1r "I guess I kind of overlooked that."
    m "So, I'm sorry."
    show monika at t43 zorder 2
    show natsuki 5g at f42 zorder 3
    n "..."
    show natsuki at t42 zorder 2
    show monika at f43 zorder 3
    m 1i "...But!"
    m "I still think we should give it our best!"
    m 1d "We're the only ones responsible for the fate of this club."
    m "If we start the event and each put on a good performance..."
    m 3a "Then it will inspire others to do the same!"
    m "And the more people who perform, the better we'll be able to show everyone what literature is all about!"
    show monika at t43 zorder 2
    show sayori 1r at f41 zorder 3
    s "Yeah!"
    s 1x "It's about expressing your feelings..."
    s "Being intimate with yourself..."
    s "Finding new horizons..."
    s "And having fun!"
    show sayori at t41 zorder 2
    show monika at f43 zorder 3
    m 4b "That's right!"
    m "And it's those reasons that we're all in this club today."
    m 4e "Don't you want to share that with others?"
    m "To inspire them to find the same feelings that brought you here in the first place?"
    m 1e "I know you do."
    m "I know we all do."
    m 1b "And if all it takes is standing in front of the room for two minutes and reciting a poem..."
    m "...Then I know you can do it!"
    show monika 1a at t43 zorder 2
    show natsuki 5s at f42 zorder 3
    n "..."
    show natsuki at t42 zorder 2
    show yuri 4b at f44 zorder 3
    y "..."
    show yuri at t44 zorder 2
    show sayori 1g
    "Natsuki and Yuri remain silent."
    "Sayori looks worried."
    "I guess that leaves me no choice..."
    mc "I agree..."
    mc "I don't think it's too much to ask."
    mc "I think that Sayori and Monika have been trying really hard to get new members."
    mc "The least we can do is help them out a little bit."
    show natsuki at f42 zorder 3
    n 5h "Well...maybe, but..."
    n "..."
    "It looks like Natsuki doesn't have any arguments left."
    n "Uu..."
    n 1q "...Okay, fine!"
    n "I guess I'll just have to get it over with."
    show natsuki at t42 zorder 2
    show sayori at f41 zorder 3
    s 4r "Alright~!"
    show sayori 4a at t41 zorder 2
    show monika at f43 zorder 3
    m 1e "Phew..."
    m "Thanks, Natsuki."
    m "What about you, Yuri...?"
    show monika at t43 zorder 2
    show yuri at f44 zorder 3
    y "..."
    "Yuri dejectedly glances around at everyone else's expectant faces."
    y "Sigh..."
    y "I-I guess I don't really have a choice..."
    show yuri at t44 zorder 2
    show sayori at f41 zorder 3
    s 4r "Ahaha! That's everyone!"
    s "You're the best, Yuri~"
    show sayori 4a at t41 zorder 2
    show yuri at f44 zorder 3
    y "This club is seriously going to be the death of me..."
    show yuri at t44 zorder 2
    show monika at f43 zorder 3
    m 1l "Oh gosh..."
    m 1n "You'll be fine, Yuri."
    m "But anyway..."
    m 1b "Let's move onto the main event!"
    m "I want each of you to choose a poem of yours."
    m "We're going to practice reciting them in front of each other."
    show monika 1a at t43 zorder 2
    show natsuki at f42 zorder 3
    n 1p "N-N-No way!!"
    show natsuki at t42 zorder 2
    show yuri 3n at f44 zorder 3
    y "Monika...!"
    y "This is too sudden...!"
    show yuri at t44 zorder 2
    show monika at f43 zorder 3
    m 2a "Well, if you can't recite your poem in front of the club, how do you expect to do it in front of strangers?"
    show monika at t43 zorder 2
    show yuri 4c at f44 zorder 3
    show natsuki 1o
    y "Oh no..."
    show yuri at t44 zorder 2
    show monika at f43 zorder 3
    m 2a "Don't worry."
    m "I'll start off to help everyone feel a little more comfortable."
    show monika at t43 zorder 2
    show sayori 1r at f41 zorder 3
    s "Can I go next??"
    show sayori at t41 zorder 2
    show monika at f43 zorder 3
    m "Ahaha. Of course."
    m 2d "Now, let's see..."
    "Monika flips through her notebook to the specific poem she has in mind for herself."
    "She then stands behind the podium."
    show monika at t11 zorder 2
    show sayori at thide zorder 1
    show natsuki at thide zorder 1
    show yuri at thide zorder 1
    hide sayori
    hide natsuki
    hide yuri
    m 1a "The title of this poem is {i}The Way They Fly{/i}."
    m 1r "Ahem..."
    show monika 1a
    "Monika begins reciting her poem."
    "Her clear, confident voice fills the room."
    "More than that, her inflection is pristine."
    "She knows exactly how to apply emotion behind each line she recites, bringing the words to life."
    "Is this something she's done before, or is she simply a natural?"
    "I glance around me."
    "Everyone has their eyes on Monika."
    "Sayori looks amazed."
    "Yuri has an intense expression on her face that I don't understand."
    show monika 1j
    "Finally, Monika finishes the recitation."
    "The four of us applaud."
    "Monika takes a breath and smiles."
    show monika 1a
    show sayori 4m at f33 zorder 3
    s "That...that was so good, Monika!"
    show sayori at t33 zorder 2
    show monika at f32 zorder 3
    m 1j "Ahaha, thank you very much."
    m 1a "I was just hoping to set a good example."
    m "Are you ready to go next, Sayori?"
    show monika at t32 zorder 2
    show yuri 2r at l31
    y "I...I'll go next!!"
    show sayori at h33
    s 1n "Uwah! Yuri's fired up all of a sudden!"
    "Yuri clutches a sheet of paper between her hands and stands up."
    "Keeping her head down, she walks quickly over to the podium."
    show monika at thide zorder 1
    show sayori at thide zorder 1
    show yuri at t11 zorder 2
    hide monika
    hide sayori
    y 2v "This poem is called--!"
    "Yuri anxiously glances at each of us."
    s "You can do it, Yuri..."
    y "It...It's called...{i}Afterimage of a Crimson Eye{/i}."
    "Yuri's voice shakes as she starts reading the poem."
    "Just a moment ago, she practically refused to do this."
    "Why is she suddenly putting in so much effort?"
    show yuri 2l
    "As Yuri gets past the first couple of lines, her voice changes."
    "It's almost like what happens when Yuri gets absorbed into her books."
    "Her quivering words transform into the sharp syllables of a fierce and confident woman."
    "The poem is full of twists and turns in its structure that she enunciates with perfect timing."
    "This must be a rare glimpse into the whirling fire Yuri keeps concealed inside her head...!"
    show yuri 2t
    "Suddenly, she's finished."
    "Everyone is stunned."
    "Yuri snaps back into reality and glances around her, as if she bewildered even herself."
    y 3o "I..."
    "...It's up to me to save this situation."
    "I'm the first to start applauding."
    "Everyone joins me afterward, and we give Yuri the recognition she deserves."
    "It's not that we didn't want to applaud for her."
    "But we were caught so off-guard that we must have forgotten."
    "As we applaud, Yuri holds the poem to her chest and rushes back into her seat."
    show yuri at lhide
    hide yuri
    show monika 1a at t11 zorder 2
    m "Yuri, that was really good."
    m "Thank you for sharing."
    y "..."
    "Looks like Yuri is down for the count..."
    show sayori 1q at t31 zorder 2
    s "Okaay~"
    s "I guess I'm next, then!"
    "Sayori hops out of her chair and cheerfully walks to the podium."
    show sayori at t11 zorder 2
    show monika at thide zorder 1
    hide monika
    s 1x "This one's called...{i}My Meadow{/i}."
    s "Ah..."
    s 1s "...Ahaha!"
    s 4s "Sorry, I giggled..."
    s 4q "Ehehe..."
    mc "Sayori..."
    s 1l "It's a lot harder than I thought!"
    s "How did you guys do it so easily?"
    show monika 3a at t31 zorder 2
    show sayori 1b
    m "Ah..."
    m "Try not to think of it like you're reciting to other people."
    m "Imagine you're reciting it to yourself, like in front of a mirror, or in your own head."
    m "It's your poem, so it'll come out the best that way."
    show sayori 1i
    s "I see, I see..."
    s "Okay, then..."
    show monika at thide zorder 1
    hide monika
    show sayori 1c
    "Sayori begins her poem."
    "Somehow, it feels like her soft voice was made as a perfect match."
    "The poem isn't aimlessly cheery like Sayori is."
    "It's serene and bittersweet."
    "If I were to read this on paper, I probably wouldn't think much of it..."
    "But hearing it come from Sayori's voice almost gives it a whole new meaning."
    "Maybe this is what Sayori meant when she said she likes my poems."
    "It's like I get to reach more deeply into someone I thought I knew through and through."
    "Sayori finishes, and we applaud."
    s 3q "I did it~!"
    mc "Good job, Sayori."
    s "Ehehe, even [player] liked it."
    s "I guess that's a good sign~"
    mc "What does that even mean...?"
    show monika 2b at f31 zorder 3
    m "It came out nicely, Sayori."
    m "The atmosphere of the poem fits you really nicely."
    m "But it might be that other poems wouldn't work quite as well with that kind of delivery..."
    show monika at t31 zorder 2
    show sayori at f32 zorder 3
    s 1g "Eh? I don't really understand..."
    show sayori at t32 zorder 2
    show monika at f31 zorder 3
    m 1a "In other words, I've seen poems of yours where that sort of gentle delivery wouldn't work as well."
    m "They might need a little more force behind them, depending on what you're reading..."
    show monika at t31 zorder 2
    show sayori at f32 zorder 3
    s 1x "Oh, I know what you mean!"
    s "That's...well, I've been practicing that kind of thing..."
    s 5 "It's just embarrassing to do in front of everyone..."
    s "Ehehe..."
    show sayori at t32 zorder 2
    show monika at f31 zorder 3
    m 4a "Then next time, I'm going to make you pick a poem that challenges you a little more."
    m "We don't have much time before the festival, you know?"
    show monika at t31 zorder 2
    show sayori at f32 zorder 3
    s 1q "Okaaaaay."
    show sayori at t32 zorder 2
    show monika at f31 zorder 3
    m 1a "Now, who's next...?"
    m "Natsuki?"
    show natsuki 5s at f33 zorder 3
    show monika at t31 zorder 2
    n "Hmph."
    n "Don't make me go before [player]."
    n "It's not like I can compare to you guys, anyway..."
    n "Might as well let [player] lower everyone's standards a little before I have to do it."
    show natsuki at t33 zorder 2
    show sayori at f32 zorder 3
    s 1g "Natsuki..."
    show sayori at t32 zorder 2
    mc "It's fine, it's fine."
    mc "I might as well get it over with."
    mc "But it's not like I have much of a selection of what to read..."
    mc "I'll just have to go with what I wrote for today."
    "I stand up and step in front of the podium."
    show natsuki 2c at t44 zorder 2
    show sayori 1a at t43 zorder 2
    show monika 1a at t42 zorder 2
    show yuri 1e at t41 zorder 2
    "Everyone has their eyes on me, making me feel terribly awkward."
    "I recite my poem."
    "Since I'm not exactly confident in my own writing, it's hard to put energy into it."
    "Despite that, once I finish, I receive applause anyway."
    mc "Sorry I'm not really as good as everyone else..."
    show monika at f42 zorder 3
    m 1a "Don't worry about it so much."
    m "I think it's less about your abilities, and more about your lack of confidence in your writing."
    m "That's something that'll improve over time, though."
    show monika at t42 zorder 2
    mc "Yeah... Maybe."
    show monika at f42 zorder 3
    m 1j "Alright, then!"
    m 1a "That just leaves you, Natsuki."
    show monika at t42 zorder 2
    show natsuki at f44 zorder 3
    n 2g "Yeah, yeah."
    n "I'm going."
    "Natsuki begrudgingly gets out of her seat and makes her way to the podium."
    show sayori at thide zorder 1
    show monika at thide zorder 1
    show yuri at thide zorder 1
    show natsuki at t11 zorder 2
    hide sayori
    hide monika
    hide yuri
    n 2c "The poem is called..."
    n 2q "It's called..."
    n 1x "W-Why are you all looking at me?!"
    m "Because you're presenting..."
    n 2x "Hmph..."
    n 2h "Anyway...the poem is called {i}Jump{/i}."
    "Natsuki takes a breath."
    show natsuki 2c
    "Once she starts reciting the poem, her sour attitude disappears a little."
    "While she's still a little unenthused, her poem has a rhythm and rhyme to it."
    "It's Natsuki's trademark style, and it works surprisingly well when spoken aloud."
    "The words feel like they bounce up and down, as if giving life to the poem."
    show natsuki 2s
    "Natsuki finishes, and everyone applauds."
    "She huffs back to her seat."
    show monika 2a at f31 zorder 3
    m "That wasn't so bad, was it?"
    show monika at t31 zorder 2
    show natsuki 5w at f32 zorder 3
    n "Easy for you to say..."
    n "You'd better not make me do that again."
    show natsuki at t32 zorder 2
    show monika 1d at f31 zorder 3
    m "Ah, well..."
    m "Do you at least feel prepared enough to recite a poem in front of other people?"
    show monika at t31 zorder 2
    show natsuki 2c at f32 zorder 3
    n "I mean, doing it in front of other people will be way easier!"
    n "I can put on whatever face I want for other people."
    n 2q "But when it's just my friends..."
    n "It's just...embarrassing."
    show natsuki at t32 zorder 2
    show sayori 1b at f33 zorder 3
    s "That's a surprise, Natsuki..."
    s "I think it would be the other way around for me."
    show sayori at t33 zorder 2
    show natsuki at f32 zorder 3
    n "Well, that's just how it is, so..."
    show natsuki at t32 zorder 2
    show monika at f31 zorder 3
    m 1a "Well, I guess in that case..."
    m "You won't have much to worry about for the festival."
    m 2b "That said, I want to thank everyone for coming through."
    m "It might be hard, but I hope that you all have an idea of what it's like now."
    m 4b "Make sure you pick a poem and get enough practice before the festival, okay?"
    m "I'll be making pamphlets, so let me know ahead of time what you'll be reciting."
    show monika at t31 zorder 2
    mc "Jeez..."
    mc "I should probably find some other poem to recite instead."
    show monika at f31 zorder 3
    m 1j "That's fine, too!"
    m 1a "It doesn't have to be your own."
    m "I'm already pleasantly surprised that you're putting in all this effort for the club."
    m 5 "It makes me really happy."
    show monika at t31 zorder 2
    mc "Ah... Yeah, no problem..."
    play music t8 fadeout 1.0
    show monika at t11 zorder 2
    show sayori at thide zorder 1
    show natsuki at thide zorder 1
    hide sayori
    hide natsuki
    m 4b "Okay, everyone!"
    m "I think that's about it for today."
    m "I know the festival is coming up, but let's try to write poems for tomorrow, as well."
    m "It's been working out really nicely so far, so I'd like to continue that."
    m "As for the festival, we'll finish planning tomorrow, and then we'll have the weekend to prepare."
    m "Monday's the big day!"
    show sayori 4r at t31 zorder 2
    s "I can't wait~!"
    show yuri 4b at t33 zorder 2
    y "I can do this... I can do this..."
    mc "Alright--"
    hide sayori
    hide monika
    hide yuri
    with wipeleft
    "I stand up."
    "There's no way I'll be able to find the same enthusiasm as Sayori and Monika, but I'll do my best to get through it."
    "If it's for the sake of the club..."
    "And impressing Monika..."
    "Then I'll have to do my best."
    show sayori 1a at t32 zorder 2
    mc "Ready to go, Sayori?"
    show sayori at h32
    s 1x "Yep!"
    show natsuki 2d at f33 zorder 3
    n "Look at you two, always going home together like that."
    show monika 5 at f31 zorder 3
    show natsuki at t33 zorder 2
    m "It's kind of adorable, isn't it?"
    show monika at t31 zorder 2
    show sayori at f32 zorder 3
    s 1q "Ehehe~"
    show sayori at t32 zorder 2
    mc "Jeez, guys..."
    mc "Don't make such a big deal out of it."
    show natsuki at t44 zorder 2
    show sayori at t43 zorder 2
    show monika at t42 zorder 2
    show yuri 1u at f41 zorder 3
    y "It must be a little nice, though..."
    show yuri at t41 zorder 2
    mc "Well..."
    mc "Ah..."
    "How am I supposed to respond to that?"
    show sayori at f43 zorder 3
    s 1d "It's okay, [player], you don't have to say it."
    show sayori at t43 zorder 2
    mc "...Whatever. Let's go already."
    scene bg residential_day
    with wipeleft_scene
    $ ch2_winner = poemwinner[1].capitalize()
    if ch2_winner == "Sayori":
        $ ch2_winner = "Yuri"
    "I walk home with Sayori once more."
    "Even though it's only been a few days, a lot of things have already changed."
    "But today, Sayori is being a little quieter than usual on the way home."
    mc "Hey, Sayori..."
    show sayori 1k at t11
    s "..."
    s 1n "...Sorry! I was spacing out!"
    mc "Ah, no wonder..."
    s 1d "Um..."
    s "I was...thinking about something from earlier."
    s "I like how we get to..."
    s 1y "I-I mean..."
    "Sayori fumbles with her words."
    s 1a "So...let's just say that one day, [ch2_winner] asked to walk home with you..."
    mc "Huh?!"
    s "What would you do?"
    mc "What kind of question is that...?"
    mc "You're kind of putting me on the spot here..."
    s 1y "Ehehe..."
    menu:
        "Well..."
        "I would walk home with [ch2_winner].":
            if ch2_winner == "Natsuki":
                call ch2_end_natsuki from _call_ch2_end_natsuki
            elif ch2_winner == "Yuri":
                call ch2_end_yuri from _call_ch2_end_yuri
            else:
                call ch2_end_monika from _call_ch2_end_monika
        "I would still walk home with Sayori.":
            call ch2_end_sayori from _call_ch2_end_sayori

    "Then again, the festival is only a few days away..."
    "Who knows what will happen in that time?"
    return
label ch2_end_sayori:
    mc "Sayori..."
    mc "You really think I would ditch you for [ch2_winner]?"
    s 1e "Eh?!"
    s "B-But..."
    if ch2_winner == "Natsuki":
        s "She's so cute and fun to be around..."
    else:
        s "She's so beautiful and smart..."
    mc "Jeez..."
    mc "I already see her in the club every day."
    mc "Besides, you always seem to really like going home together..."
    mc "I wouldn't just ruin that for you."
    s 1y "You're so silly, [player]..."
    s "You think about me too much sometimes."
    s "[ch2_winner] would deserve it if she wanted it, so..."
    mc "Sayori, I've already made up my mind."
    mc "I really can't figure you out sometimes..."
    s "Sorry..."
    mc "Besides, what's the point in speculating something that's never going to happen?"
    s 1k "Hm..."
    show sayori at thide
    hide sayori
    "The conversation trails off."
    "It's kind of a weird thing for Sayori to care so much about..."
    "But I want to respect her and keep her happy, too."
    return

label ch2_end_natsuki:
    mc "Walking home with Natsuki, huh..."
    "Why does the thought of that make my heart pound...?"
    mc "I mean..."
    mc "I think I would be afraid of what she'd do to me if I turned her down..."
    s 1x "Isn't she so cute and fun to be around?"
    jump ch2_end_shared

label ch2_end_yuri:
    mc "Walking home with Yuri, huh..."
    "Why does the thought of that make my heart pound...?"
    mc "I mean..."
    mc "Given how hard it is for her to socialize, I would feel awful turning her down, so..."
    s 1x "Isn't she so beautiful and smart?"
    jump ch2_end_shared
label ch2_end_monika:
    mc "Walking home with Monika, huh..."
    "Why does the thought of that make my heart pound...?"
    mc "I mean..."
    mc "If she asked, I probably wouldn't reject her. That would be mean..."
    s 1x "Isn't she so nice and thoughtful?"
    jump ch2_end_shared

label ch2_end_shared:
    mc "That has nothing to do with what I just said!"
    s 4s "Ahaha! You admitted it!"
    mc "Jeez..."
    mc "There's not even any point in speculating something that's never going to happen."
    s 1d "Well, maybe..."
    s "But I just like to think about it."
    s 1y "It's not long before you won't need me anymore, you know?"
    mc "Need you...?"
    mc "Sayori..."
    mc "I can't figure out how you're seeing things in your head right now."
    s "Sorry..."
    mc "Everyone is different..."
    mc "Nobody in the club is a replacement for you."
    s 1k "Hmm..."
    s "If you say so..."
    show sayori at thide
    hide sayori
    "The conversation trails off, and I'm left feeling awkward."
    "But it was kind of her fault for trapping me with such a weird question..."
    "I can't just lie to her."
    "But if there's something that makes her happy, I would hate to take that away from her."
    "That's why I said there's no point in speculating."
    return