ScopeBuddy/flake.nix at main · OpenGamingCollective/ScopeBuddy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
{
  description = "ScopeBuddy – gamescope wrapper for Wayland";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }:
  let
    systems = [ "x86_64-linux" "aarch64-linux" ];
    forAllSystems = nixpkgs.lib.genAttrs systems;
  in
  {
    packages = forAllSystems (system:
      let
        pkgs = import nixpkgs { inherit system; };
      in {
        default = pkgs.stdenvNoCC.mkDerivation {
          pname = "scopebuddy";
          version = "git";
          src = self;

          nativeBuildInputs = [ pkgs.makeWrapper ];

          installPhase = ''
            install -Dm755 bin/scopebuddy $out/bin/scopebuddy
            ln -s $out/bin/scopebuddy $out/bin/scb

            wrapProgram $out/bin/scopebuddy \
              --prefix PATH : ${pkgs.lib.makeBinPath [
                pkgs.gamescope
                pkgs.perl
                pkgs.jq
                pkgs.wlr-randr
              ]}
          '';
        };
      }
    );

    apps = forAllSystems (system: {
      default = {
        type = "app";
        program = "${self.packages.${system}.default}/bin/scopebuddy";
      };
    });
  };
}