-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathNeptuneLander_V1.asm
392 lines (296 loc) · 8.96 KB
/
NeptuneLander_V1.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
; 10 SYS (2080)
*=$0801
BYTE $0E, $08, $0A, $00, $9E, $20, $28
BYTE $32, $30, $38, $30, $29, $00, $00, $00
; Sprite Data
*=$2A80
; Load Sprites 1-> 5 padded to 64 bytes
incbin "NeptuneLander.spt", 1, 6 ,true
incbin "DereksExplosions.spt", 5, 16, true
; CharacterSet
*=$3000
incbin "LandScape.cst", 0, 255
*=$0820
jmp GameStart
;*************************************************************************
;* Game Working Variable Space *
;*************************************************************************
; Binary Fraction Format :-
; First Byte is Fraction = 1/128 -> 1/2
; Second Byte is Whole Number
LunaLanderXFrac
brk
LunaLanderXLo
brk
LunaLanderXHi
brk
LunaLanderYFrac
brk
LunaLanderY
brk
LunaLanderSpNo
BYTE 0
LunaLanderColour
brk
ThrustSpNo
BYTE 1
ThrustFrameNo
brk
ThrustColour
brk
ManuoverSpNo
BYTE 2
ManuoverFrameNo
brk
ManuoverColour
brk
VerticalVelocityFrac
brk
VerticalVelocity
brk
GravityFrac
brk
Gravity
brk
ThrustFrac
brk
Thrust
brk
HorizontalVelocityFrac
brk
HorizontalVelocity
brk
HorizontalInertiaFrac
brk
HorizontalInertia
brk
GameLoopFrameTracker
brk
FrameSkipRate
BYTE 03
CollidedWithBackground
brk
VerticalBarValue
brk
FuelBarValueFrac
brk
FuelBarValue
brk
ThrustCostFrac
BYTE 64
ThrustCost
brk
incasm "libSprite.asm"
incasm "libMath.asm"
incasm "libInput.asm"
incasm "libConstants.asm"
incasm "libScreen.asm"
incasm "libPrint.asm"
incasm "libBarsAndGauges.asm"
GameStart
jsr SetUpLevelOneScene
jsr SetUpLunarSprite
jsr SetUpCustomCharacters
jsr SetUpGameVariables
LIBBARSANDGAUGES_INITYBAR_AV $044E,12
lda #Green
sta $D916
LIBBARSANDGAUGES_INITYBAR_AV $044D,12
lda #Red
sta $D9DD
sta $DA05
GameLoop
LIBSCREEN_WAIT_V 255
lda #1
sta EXTCOL
;LIBSCREEN_DEBUG16BIT_VVAA 1,1,VerticalVelocity, VerticalVelocityFrac
;LIBSCREEN_DEBUG8BIT_VVA 8,1,LunaLanderY
lda CollidedWithBackground
cmp #False
beq @NoGameDeathScene
jmp GameDeathScene
@NoGameDeathScene
lda GameLoopFrameTracker
bne GameLooper
jsr ReadInputAndUpdateVariables
jsr UpdateSpritePosition
jsr DidWeCollideWithScene
jsr UpdateBarsAndGauges
GameLooper
jsr libSpritesUpdate
lda GameLoopFrameTracker
clc
adc #$01
and FrameSkipRate
sta GameLoopFrameTracker
lda #0
sta EXTCOL
jmp GameLoop
rts
GameDeathScene
LIBSPRITE_ISANIMPLAYING_A LunaLanderSpNo
bne GameLooper
jsr libInputUpdate
LIBINPUT_GETHELD GameportFireMask
bne GameLooper
jmp GameStart
SetUpLunarSprite
lda #60
sta LunaLanderXLo
sta LunaLanderY
lda #0
sta LunaLanderXHi
sta LunaLanderSpNo
sta LunaLanderColour
lda #Red
sta ThrustColour
sta ManuoverColour
; POKE 53273, PEEK(53273) OR 2
lda VICIRQ
ora #2
sta VICIRQ
; 20 POKE 2040,170 : REM SPRITE POINT * 64 = 170 * 64 = 10880
; 25 POKE 2041,186
LIBSPRITE_SETFRAME_AV LunaLanderSpNo, spLunaLander
LIBSPRITE_SETFRAME_AV ThrustSpNo, spNoThrust
LIBSPRITE_SETFRAME_AV ManuoverSpNo, spNoThrust
;poke 53269,3
LIBSPRITE_ENABLE_AV LunaLanderSpNo, True
LIBSPRITE_ENABLE_AV ThrustSpNo, True
LIBSPRITE_ENABLE_AV ManuoverSpNo, True
; 30 Y = 60 : POKE 53249,Y : POKE 53251,Y
; 40 X = 60 : POKE 53248,X : POKE 53250,X
LIBSPRITE_SETPOSITION_AAAA LunaLanderSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
LIBSPRITE_SETPOSITION_AAAA ThrustSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
LIBSPRITE_SETPOSITION_AAAA ManuoverSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
; POKE 53287,0
LIBSPRITE_SETCOLOR_AA LunaLanderSpNo, LunaLanderColour
; POKE 53288,2
LIBSPRITE_SETCOLOR_AA ThrustSpNo, ThrustColour
LIBSPRITE_SETCOLOR_AA ManuoverSpNo, ManuoverColour
LIBSPRITE_SETMULTICOLORS_VV Yellow, LightGray
LIBSPRITE_MULTICOLORENABLE_AV LunaLanderSpNo, False
rts
SetUpCustomCharacters
LIBSCREEN_SETCHARMEMORY 12
rts
ScnLevelOne
TEXT "{white}{clear}{down*8}gg{down}bc{down}d{down}h{down}{left}j{down}h{down}{left}j{down}{left}i{down}{left}k{down}{left*2}e{down}{left*3}@a{down}{left*3}e{down}{left*2}e{down}{left}d{down}d{down}d{down}dlllk{up}{left}i"
TEXT "{up}{left}j{up}{left}h{up}{left}e{up}e{up}@a{up}e{up}k{up}{left}i{up}k{up}{left}i{up}lllk{up}{left}i{up}{left}d{up}{left*2}d{up}{left}@a{up}e{up}k{up}{left}i{up}f{down}dgg{down}h{down}{left}j{down}h{down}{left}j"
TEXT "{down}{left}i{down}{left}k{down}{left}h{down}{left}j{down}h{down}{left}j{down}{left}e{down}{left*2}e{down}{left}h{down}{left}j{down}d{down}bcllllebc{down}bc{down}d"
BYTE 0
SetUpLevelOneScene
LIBPRINT_PRINTSTRING_A ScnLevelOne
rts
;80 VV = 0 : G = 3/112 : T = 3/112 : HV = 0 : HI = 1/28
SetUpGameVariables
lda #0
sta VerticalVelocity
sta HorizontalVelocity
sta Gravity
sta Thrust
sta HorizontalInertia
lda #False
sta CollidedWithBackground
lda #2
sta GravityFrac
lda #4
sta ThrustFrac
lda #2
sta HorizontalInertiaFrac
lda #8
sta FuelBarValueFrac
lda #0
sta FuelBarValue
rts
ReadInputAndUpdateVariables
jsr libInputUpdate
LIBINPUT_GETHELD GameportLeftMask
bne @TestRight
;130 IF A = 10 THEN HV = HV + HI : TS = 185 :REM A
LIBMATH_ADD16BIT_AAA HorizontalVelocityFrac, HorizontalInertiaFrac, HorizontalVelocityFrac
ldx #spThrustLeft
stx ManuoverFrameNo
jsr AddFuelConsumption
@TestRight
LIBINPUT_GETHELD GameportRightMask
bne @TestFire
;120 IF A = 18 THEN HV = HV - HI : TS = 184 : REM D
LIBMATH_SUB16BIT_AAA HorizontalVelocityFrac, HorizontalInertiaFrac, HorizontalVelocityFrac
ldx #spThrustRight
stx ManuoverFrameNo
jsr AddFuelConsumption
@TestFire
LIBINPUT_GETHELD GameportFireMask
bne @NoInput
;110 IF A = 22 THEN VV = VV - T : TS=183 :
@FireDetected
LIBMATH_SUB16BIT_AAA VerticalVelocityFrac, ThrustFrac, VerticalVelocityFrac
ldx #spThrustDown
stx ThrustFrameNo
jsr AddFuelConsumption
jsr AddFuelConsumption
jmp @GravityByPass
@NoInput
LIBINPUT_GETHELD GameportNoInputMask
cmp #GameportNoInputMask
bne @InputProcessed
ldx #spNoThrust
stx ThrustFrameNo
stx ManuoverFrameNo
;200 VV = VV + G : IF VV > 2 THEN VV = 2
@InputProcessed
LIBMATH_ADD16BIT_AAA VerticalVelocityFrac, GravityFrac, VerticalVelocityFrac
@GravityByPass
lda VerticalVelocity
cmp #2
bne @InputFinish
lda #1
sta VerticalVelocity
lda #0
sta VerticalVelocityFrac
@InputFinish
rts
UpdateSpritePosition
; 210 Y = (Y+VV) : X = (X+HV)
LIBMATH_ADD16BIT_AAA LunaLanderYFrac, VerticalVelocityFrac, LunaLanderYFrac
LIBMATH_ADD16BIT_AAA LunaLanderXFrac, HorizontalVelocityFrac, LunaLanderXFrac
;215 POKE 2041,TS : POKE 53250, XL : POKE 53251, Y
;216 POKE 53249, Y : POKE 53248,XL : POKE 53264, XH : REM CC=CC+1
LIBSPRITE_SETFRAME_AA ThrustSpNo, ThrustFrameNo
LIBSPRITE_SETFRAME_AA ManuoverSpNo, ManuoverFrameNo
LIBSPRITE_SETPOSITION_AAAA LunaLanderSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
LIBSPRITE_SETPOSITION_AAAA ThrustSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
LIBSPRITE_SETPOSITION_AAAA ManuoverSpNo, LunaLanderXHi, LunaLanderXLo, LunaLanderY
rts
DidWeCollideWithScene
LIBSPRITE_DIDCOLLIDEWITHDATA_A LunaLanderSpNo
beq DidNotCollide
;lda #2
;sta EXTCOL
lda #True
sta CollidedWithBackground
LIBSPRITE_SETCOLOR_AV LunaLanderSpNo, Yellow
LIBSPRITE_MULTICOLORENABLE_AV LunaLanderSpNo, True
LIBSPRITE_PLAYANIM_AVVVV LunaLanderSpNo, 5, 16, 3, False
DidNotCollide
rts
UpdateBarsAndGauges
lda VerticalVelocityFrac
sta VerticalBarValue
lda VerticalVelocity
lsr
ror VerticalBarValue
lsr
ror VerticalBarValue
lsr
ror VerticalBarValue
lda VerticalBarValue
eor #$FF
LIBBARSANDGAUGES_SHOWYBAR_AV $044E, $2C
lda FuelBarValue
LIBBARSANDGAUGES_SHOWYGAUGE_AV $044D, $00
rts
AddFuelConsumption
LIBMATH_ADD16BIT_AAA FuelBarValueFrac, ThrustCostFrac, FuelBarValueFrac
rts