big update for more terminal commands

Author: Mistium

:path/cp.osl

@@ -0,0 +1,41 @@
+local src = args[1]
+local dst = args[2]
+
+if src == null or dst == null (
+  terminal.writeLine("cp: missing file operand")
+  terminal.writeLine("Usage: cp <source> <destination>")
+  return
+)
+
+local srcPath = terminal.resolvePath(src)
+if !src.contains(".") (
+  srcPath ++= ".folder"
+)
+
+file "exists" srcPath
+if !exists (
+  terminal.writeLine("cp: cannot stat '" ++ src ++ "': No such file or directory")
+  return
+)
+
+local dstPath = terminal.resolvePath(dst)
+local isDstDir = false
+
+if !dst.contains(".") (
+  dstPath ++= ".folder"
+  isDstDir = true
+)
+
+file "exists" dstPath
+if exists (
+  isDstDir = true
+)
+
+if isDstDir (
+  local name = srcPath.split("/")[-1]
+  dstPath = dstPath.trim(1, -8) ++ "/" ++ name
+)
+
+local content = open(srcPath)
+file "set_file" dstPath content
+terminal.writeLine("copied '" ++ src ++ "' to '" ++ dst ++ "'")

:path/cut.osl

@@ -0,0 +1,88 @@
+local input = null
+
+if terminal.stdin != null (
+  input = terminal.stdin
+) else if args.len > 0 (
+  local target = args[args.len]
+  if !target.startsWith("-") (
+    local filePath = terminal.resolvePath(target)
+    file "exists" filePath
+    if exists (
+      input = open(filePath)
+    ) else (
+      terminal.writeLine("cut: " ++ target ++ ": No such file or directory")
+      return
+    )
+  )
+)
+
+if input == null (
+  terminal.writeLine("cut: missing operand")
+  return
+)
+
+local delimiter = "\t"
+local fields = null
+local chars = null
+local i = 1
+while i <= args.len (
+  local arg = args[i]
+  if arg.startsWith("-d") (
+    if arg.len > 2 (
+      delimiter = arg[3]
+    ) else (
+      delimiter = args[i + 1]
+      i += 1
+    )
+  ) else if arg.startsWith("-f") (
+    if arg.len > 2 (
+      fields = arg.trim(3, -1).split(",")
+    ) else (
+      fields = args[i + 1].split(",")
+      i += 1
+    )
+  ) else if arg.startsWith("-c") (
+    if arg.len > 2 (
+      chars = arg.trim(3, -1)
+    ) else (
+      chars = args[i + 1]
+      i += 1
+    )
+  )
+  i += 1
+)
+
+local lines = input.split("\n")
+
+for l lines.len (
+  local line = lines[l]
+  local output = ""
+  
+  if chars != null (
+    if chars.contains("-") (
+      local parts = chars.split("-")
+      local start = parts[1].toNum() ?? 1
+      local end = parts[2].toNum() ?? line.len
+      output = line.trim(start, end)
+    ) else (
+      local idx = chars.toNum()
+      if idx != null (
+        output = line[idx] ?? ""
+      )
+    )
+  ) else if fields != null (
+    local cols = line.split(delimiter)
+    local parts = []
+    for f fields.len (
+      local idx = fields[f].toNum()
+      if idx != null and idx <= cols.len (
+        void parts.append(cols[idx])
+      )
+    )
+    output = parts.join(delimiter)
+  ) else (
+    output = line
+  )
+  
+  terminal.writeLine(output)
+)

:path/false.osl

@@ -0,0 +1 @@
+terminal.writeLine(false)

:path/file.osl

@@ -0,0 +1,67 @@
+local target = args[1]
+
+if target == null (
+  terminal.writeLine("file: missing operand")
+  return
+)
+
+local filePath = terminal.resolvePath(target)
+file "exists" filePath
+
+if !exists (
+  terminal.writeLine("file: cannot open '" ++ target ++ "': No such file or directory")
+  return
+)
+
+local data = open(filePath, ["type"])
+local fileType = data[1]
+
+if fileType == ".folder" (
+  terminal.writeLine(target ++ ": directory")
+  return
+)
+
+local content = open(filePath)
+local lines = content.split("\n")
+local lineCount = lines.len
+local maxLineLen = 0
+
+for i lines.len (
+  if lines[i].len > maxLineLen (
+    maxLineLen = lines[i].len
+  )
+)
+
+local hasBinary = false
+local hasNonASCII = false
+
+for i content.len (
+  local c = content[i].toNum()
+  if c != null (
+    if c == 0 (
+      hasBinary = true
+    )
+    if c > 127 (
+      hasNonASCII = true
+    )
+  )
+)
+
+local desc = filePath
+if hasBinary (
+  desc = "binary data"
+) else if hasNonASCII (
+  desc = "Unicode text, UTF-8 text"
+) else (
+  desc = "ASCII text"
+)
+
+if maxLineLen > 500 (
+  desc ++= ", with very long lines (" ++ maxLineLen ++ ")"
+) else if maxLineLen > 100 (
+  desc ++= ", with long lines (" ++ maxLineLen ++ ")"
+)
+
+desc ++= " (" ++ lineCount ++ " lines)"
+
+terminal.writeLine(target ++ ": " ++ desc)

:path/find.osl

@@ -0,0 +1,81 @@
+local searchPath = terminal.pwd
+local namePattern = null
+local typeFilter = null
+
+for i args.len (
+    local arg = args[i]
+    if arg == "." or i == 1 (
+        if arg != "." (
+            searchPath = terminal.resolvePath(arg)
+        )
+    ) else if arg.startsWith("-name") (
+        namePattern = args[i + 1]
+    ) else if arg.startsWith("-type") (
+        typeFilter = args[i + 1]
+    )
+)
+
+local results = []
+local startUuid = open(searchPath ++ ".folder", "uuid")[1]
+local stack = [[startUuid, 1]]
+
+while stack.len > 0 (
+    local current @= stack.pop()
+    local uuid = current[1]
+    local depth = current[2]
+
+    if depth > 50 (
+        continue
+    )
+    
+    file "exists" uuid
+    if !exists (
+        continue
+    )
+
+    local items = open(uuid)
+    for j items.len (
+        local itemUuid = items[j]
+        local itemData = open(itemUuid, ["name", "type"])
+        local itemName = itemData[1] ++ itemData[2]
+        local isDir = itemData[2] == ".folder"
+
+        local match = true
+        if namePattern != null (
+            local pattern = namePattern
+            if pattern[1] == "*" and pattern[-1] == "*" (
+                match = itemName.contains(pattern.trim(2, -2))
+            ) else if pattern[1] == "*" (
+                match = itemName.endsWith(pattern.trim(2, -1))
+            ) else if pattern[-1] == "*" (
+                match = itemName.startsWith(pattern.trim(1, -2))
+            ) else (
+                match = itemName == pattern
+            )
+        )
+        if typeFilter != null (
+            if typeFilter == "d" and !isDir (
+                match = false
+            ) else if typeFilter == "f" and isDir (
+                match = false
+            )
+        )
+
+        if match (
+            void results.append(itemUuid)
+        )
+
+        if isDir (
+            void stack.append([itemUuid, depth + 1])
+        )
+    )
+)
+
+for r results.len (
+    array data = open(results[r], ["location", "name", "type"])
+    string path = data[1] ++ "/" ++ data[2] ++ data[3]
+    if path.startsWith(searchPath) (
+        path = path.replaceFirst(searchPath, ".")
+    )
+    terminal.writeLine(path)
+)

:path/head.osl

@@ -1,7 +1,36 @@
-local input = terminal.stdin ?? args[2]
-local count = args[1] ?? 10
-local lines = input.split("\n", count)
+local input = null
+local count = 10
+local filePath = null
 
-void lines.map(v -> (
-  terminal.writeLine(v)
-))
+for i args.len (
+  if args[i].startsWith("-n") (
+    count = args[i].trim(3, -1).toNum() ?? args[i + 1].toNum() ?? 10
+  ) else if args[i].toNum() != null (
+    count = args[i].toNum()
+  ) else if !args[i].startsWith("-") (
+    filePath = terminal.resolvePath(args[i])
+  )
+)
+
+if terminal.stdin != null (
+  input = terminal.stdin
+) else if filePath != null (
+  file "exists" filePath
+  if exists (
+    input = open(filePath)
+  ) else (
+    terminal.writeLine("head: cannot open '" ++ args[args.len] ++ "': No such file or directory")
+    return
+  )
+)
+
+if input == null (
+  terminal.writeLine("head: missing operand")
+  return
+)
+
+local lines = input.split("\n")
+
+for i count.clamp(1, lines.len) (
+  terminal.writeLine(lines[i])
+)

:path/history.osl

@@ -0,0 +1,28 @@
+local file = null
+local numLines = null
+
+for i args.len (
+  if args[i].toNum() != null (
+    numLines = args[i].toNum()
+  )
+)
+
+file "open" "~/:path/history.txt" "onlyaccess"
+local history = fileGet(4).split("\n").filter(v -> v.len > 0)
+file "close"
+
+if numLines == null (
+  for i history.len (
+    terminal.writeLine("  " ++ (i + 1) ++ "  " ++ history[i])
+  )
+) else (
+  local start = history.len - numLines
+  if start < 1 (
+    start = 1
+  )
+  for i history.len (
+    if i >= start (
+      terminal.writeLine("  " ++ (i + 1) ++ "  " ++ history[i])
+    )
+  )
+)

:path/ls.osl

@@ -1,5 +1,5 @@
 local targetPath = terminal.pwd
-if args.len > 0 and args[1] != "-a" and !args[1].startsWith("-") (
+if typeof(args[1]) == "string" and args[1] != "-a" and !args[1].startsWith("-") (
   targetPath = terminal.resolvePath(args[1])
   if !targetPath.endsWith(".folder") (
     targetPath ++= ".folder"