config/cmake: find MPI if the MPI component is requested

Otherwise projects using `conduit::conduit_mpi` may get errors about
`MPI::MPI_C` not being a target without finding it themselves. Instead
of requesting users to find MPI themselves, let them request support via
an MPI component.

Author: mathstuf

src/config/ConduitConfig.cmake.in

@@ -61,7 +61,8 @@ if(NOT CONDUIT_FOUND)
 
     set(Conduit_FOUND TRUE)
 
-    set(_conduit_known_components)
+    set(_conduit_known_components
+      MPI)
     foreach(_conduit_component IN LISTS Conduit_FIND_COMPONENTS)
       if (NOT _conduit_component IN_LIST _conduit_known_components)
         set("Conduit_${_conduit_component}_FOUND" 0)

src/config/conduit_setup_deps.cmake

@@ -46,6 +46,39 @@ if(CONDUIT_USE_OPENMP)
     endif()
 endif()
 
+###############################################################################
+# Setup MPI
+###############################################################################
+if("MPI" IN_LIST Conduit_FIND_COMPONENTS)
+    set(Conduit_MPI_NOT_FOUND_MESSAGE "")
+
+    if(NOT CONDUIT_USE_CMAKE_MPI_TARGETS)
+        # The compiler is expected to have MPI implicitly available; MPI is
+        # found.
+    elseif(CONDUIT_RELAY_MPI_ENABLED)
+        if(NOT TARGET MPI::MPI_C)
+            set(_conduit_find_mpi_args "")
+            if(Conduit_FIND_QUIETLY)
+                list(APPEND _conduit_find_mpi_args QUIET)
+            endif()
+
+            find_dependency(MPI ${_conduit_find_mpi_args} COMPONENTS C)
+            unset(_conduit_find_mpi_args)
+        endif()
+
+        if(NOT TARGET MPI::MPI_C)
+            set(Conduit_MPI_NOT_FOUND_MESSAGE "MPI could not be found: ${MPI_NOT_FOUND_MESSAGE}")
+        endif()
+    else()
+        set(Conduit_MPI_NOT_FOUND_MESSAGE "MPI support is not available")
+    endif()
+
+    set(Conduit_MPI_FOUND 1)
+    if(Conduit_MPI_NOT_FOUND_MESSAGE)
+        set(Conduit_MPI_FOUND 0)
+    endif()
+endif()
+
 ###############################################################################
 # Setup Caliper
 ###############################################################################