intellij-community/platform/jewel/int-ui/int-ui-standalone/build.gradle.kts at fbc46c12cc318c3a6b32c7e95628cf5a1aa7cdc8 · JetBrains/intellij-community · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
import io.gitlab.arturbosch.detekt.Detekt
import org.jetbrains.jewel.buildlogic.metalava.GenerateMetalavaApiTask
import org.jetbrains.jewel.buildlogic.theme.IntelliJThemeGeneratorTask
import org.jmailen.gradle.kotlinter.tasks.LintTask

plugins {
    jewel
    `jewel-check-public-api`
    alias(libs.plugins.composeDesktop)
    alias(libs.plugins.compose.compiler)
    `intellij-theme-generator`
}

dependencies {
    api(projects.ui)
    implementation(libs.jbr.api)
    implementation(libs.jna.core)
}

intelliJThemeGenerator {
    register("intUiLight") {
        themeClassName = "org.jetbrains.jewel.intui.core.theme.IntUiLightTheme"
        themeFilePath = "../../platform/platform-resources/src/themes/expUI/expUI_light.theme.json"
        targetDir = project.file("generated/theme/")
    }

    register("intUiDark") {
        themeClassName = "org.jetbrains.jewel.intui.core.theme.IntUiDarkTheme"
        themeFilePath = "../../platform/platform-resources/src/themes/expUI/expUI_dark.theme.json"
        targetDir = project.file("generated/theme/")
    }
}

tasks {
    val themeGeneratorTasks = withType<IntelliJThemeGeneratorTask>()
    themeGeneratorTasks.configureEach { finalizedBy(ktfmtFormatMain) }

    ktfmtFormatMain {
        // Ensure the ktfmtFormatMain task is not considered UP-TO-DATE when
        // we've regenerated the theme definitions (it doesn't always pick
        // it up for some reason)
        outputs.upToDateWhen { themeGeneratorTasks.none { it.state.executed } }
    }

    val generateThemes by
        register<Task>("generateThemes") {
            description = "Updates the ThemeDescription dumps and reformats them."
            dependsOn(themeGeneratorTasks)
            dependsOn(ktfmtFormatMain)
        }

    withType<GenerateMetalavaApiTask> { dependsOn(generateThemes) }

    ktfmtCheckMain {
        mustRunAfter(generateThemes)
        mustRunAfter(ktfmtFormatMain)
    }

    withType<LintTask> {
        mustRunAfter(generateThemes)
        mustRunAfter(ktfmtFormatMain)
    }

    withType<Detekt>().configureEach {
        mustRunAfter(generateThemes)
        mustRunAfter(ktfmtFormatMain)
    }

    detektMain {
        mustRunAfter(generateThemes)
        mustRunAfter(ktfmtFormatMain)
    }
}