OpenSpec/flake.nix at 7703cafa9a41282d36467715a61737063842e1cc · Fission-AI/OpenSpec · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
{
  description = "OpenSpec - AI-native system for spec-driven development";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        nodejs = pkgs.nodejs_22;
        packageJson = pkgs.lib.importJSON ./package.json;
      in
      {
        packages.default = pkgs.stdenv.mkDerivation (finalAttrs: {
          pname = "openspec";
          version = packageJson.version;

          src = ./.;

          nativeBuildInputs = [
            nodejs
            pkgs.pnpm
            pkgs.pnpmConfigHook
            pkgs.makeWrapper
          ];

          pnpmDeps = pkgs.fetchPnpmDeps {
            inherit (finalAttrs) pname version src;
            hash = "sha256-vAlqVFaBN7KMlyP4HKbsMkaYrA5Yf2l5a+PLCZ6KOzs=";
            fetcherVersion = 3;
          };

          buildPhase = ''
            runHook preBuild
            pnpm run build
            runHook postBuild
          '';

          installPhase = ''
            runHook preInstall

            mkdir -p $out/lib/openspec
            cp -r dist $out/lib/openspec/
            cp -r bin $out/lib/openspec/
            cp -r node_modules $out/lib/openspec/
            cp package.json $out/lib/openspec/

            mkdir -p $out/bin
            makeWrapper ${nodejs}/bin/node $out/bin/openspec \
              --add-flags "$out/lib/openspec/bin/openspec.js"

            runHook postInstall
          '';

          meta = with pkgs.lib; {
            description = "AI-native system for spec-driven development";
            homepage = "https://github.com/Fission-AI/OpenSpec";
            license = licenses.mit;
            maintainers = [ ];
            mainProgram = "openspec";
            platforms = platforms.all;
          };
        });

        devShells.default = pkgs.mkShell {
          buildInputs = [
            nodejs
            pkgs.pnpm
          ];
        };

        apps.default = flake-utils.lib.mkApp {
          drv = self.packages.${system}.default;
        };
      }
    );
}