build.gradle

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.4.2'
}

group = 'com.avrix'
version = '1.0.0'

def buildPath = System.getenv('BUILD_PATH') ?: 'build'
def baseSuffix = "API"
def baseArchiveName = "${rootProject.name.capitalize()}-${baseSuffix}"

repositories {
    mavenCentral()
}

dependencies {
    // AvrixLoader
    compileOnly(rootProject)
    compileOnly(fileTree(dir: 'libs', include: '*.jar'))

    // Test
    testImplementation platform('org.junit:junit-bom:6.1.0')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testImplementation 'org.assertj:assertj-core:3.27.7'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation("org.slf4j:slf4j-simple:2.0.18")
    testImplementation("org.spongepowered:configurate-yaml:4.2.0")
}

test {
    useJUnitPlatform()
}

processResources {
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
    filesMatching('**/metadata.yml') {
        filter { String line -> line.replace('%API_VERSION%', version.toString()) }
    }
}

shadowJar {
    archiveBaseName.set(baseArchiveName)
    archiveClassifier.set('')
    destinationDirectory.set(file(buildPath))

    manifest {
        attributes(
                'Implementation-Title': "${rootProject.name.capitalize()}-${baseSuffix}",
                'Implementation-Version': version
        )
    }
}