ESP 32 S3 - ST 7789 display, Multiple SPI connection Issue

[Nethan325]

Hi, I am using an ESP32S3 N16R8 module, and the display is ST7789, I am finding it difficult to print the angle values obtained from the encoder, which uses SPI communication to the display. I am using Arduino IDE by the way, both the display and encoder use the same MOSI and SCK I tried defining different modes for the encoder. What i feel is that the display seems to hold the SPI communication all the time, (my display does not have a CS pin).

These were my pin configurations

// For ESP32 Dev board (only tested with ILI9341 display)
// The hardware SPI can be mapped to any pins

#define TFT_MISO 13
#define TFT_MOSI 11
#define TFT_SCLK 12
#define TFT_CS   9  // Chip select control pin
#define TFT_DC   16  // Data Command control pin
#define TFT_RST  17  // Reset pin (could connect to RST pin)
//#define TFT_RST  -1  // Set TFT_RST to -1 if display RESET is connected to ESP32 board RST

This was the code i used to display angle on to the display

#include <SPI.h>
#include <TFT_eSPI.h>


/* ---------------- TFT Setup ---------------- */
TFT_eSPI tft = TFT_eSPI();
#define SCREEN_W 240
#define SCREEN_H 240

/* ---------------- AS5048A Encoder Setup ---------------- */
#define PIN_CS    10
#define PIN_SCK   12
#define PIN_MOSI  11
#define PIN_MISO  13
#define AS5048_ANGLE_REG  0x3FFF

SPISettings as5048SPI(1000000, MSBFIRST, SPI_MODE1);

/* ---------------- Filter Parameters ---------------- */
const float ALPHA = 0.10;
const float DEAD_BAND = 0.05;

float filteredAngle = 0.0;
float stableAngle   = 0.0;
bool firstSample    = true;

/* ---------------- Utility: Even Parity ---------------- */
uint16_t addEvenParity(uint16_t v) {
  uint8_t ones = 0;
  for (int i = 0; i < 15; i++) {
    if (v & (1 << i)) ones++;
  }
  if (ones % 2) v |= 0x8000;
  return v;
}

/* ---------------- Read Raw Angle ---------------- */
uint16_t readRawAngle() {
  uint16_t cmd = addEvenParity(0x4000 | AS5048_ANGLE_REG);
  uint16_t resp;

  SPI.beginTransaction(as5048SPI);

  digitalWrite(PIN_CS, LOW);
  SPI.transfer16(cmd);
  digitalWrite(PIN_CS, HIGH);

  delayMicroseconds(2);

  digitalWrite(PIN_CS, LOW);
  resp = SPI.transfer16(0x0000);
  digitalWrite(PIN_CS, HIGH);

  SPI.endTransaction();

  return resp & 0x3FFF;  // 14-bit angle
}

/* ---------------- Convert to Degrees ---------------- */
float readAngleDegrees() {
  return (readRawAngle() * 360.0f) / 16384.0f;
}

/* ---------------- Filters ---------------- */
float lowPassFilter(float angle) {
  if (firstSample) {
    filteredAngle = angle;
    firstSample = false;
  } else {
    filteredAngle = ALPHA * angle + (1.0f - ALPHA) * filteredAngle;
  }
  return filteredAngle;
}

float deadbandFilter(float angle) {
  if (fabs(angle - stableAngle) < DEAD_BAND) return stableAngle;
  stableAngle = angle;
  return angle;
}

/* ---------------- Setup ---------------- */
void setup() {
  Serial.begin(115200);

  pinMode(PIN_CS, OUTPUT);
  digitalWrite(PIN_CS, HIGH);
  SPI.begin(PIN_SCK, PIN_MISO, PIN_MOSI, PIN_CS);

  tft.init();
  tft.setRotation(0);
  tft.fillScreen(TFT_BLACK);
  tft.setTextColor(TFT_WHITE, TFT_BLACK);

  // Display logo/brand first
  const char* brand = "LUSTREJ";
  const char* tagline = "where craft meets precision";
  int brandFont = 4;
  int taglineFont = 2;

  int brandWidth = tft.textWidth(brand, brandFont);
  int taglineWidth = tft.textWidth(tagline, taglineFont);
  int brandX = (tft.width() - brandWidth) / 2;
  int brandY = (tft.height() / 2) - 18;
  int taglineX = (tft.width() - taglineWidth) / 2;
  int taglineY = brandY + 32;

  tft.setCursor(brandX, brandY, brandFont);
  tft.println(brand);
  delay(200);
  tft.setCursor(taglineX, taglineY, taglineFont);
  tft.println(tagline);
  delay(1500);

  tft.fillScreen(TFT_BLACK);  // Clear screen for angle display
  tft.setTextSize(3);
  tft.setCursor(20, SCREEN_H / 2 - 10);
  tft.println("Angle:");
}

/* ---------------- Main Loop ---------------- */
void loop() {
  float angle = readAngleDegrees();

  // Wrap angle to 0-360
  if (angle < 0.0f) angle += 360.0f;
  if (angle >= 360.0f) angle -= 360.0f;

  angle = lowPassFilter(angle);
  angle = deadbandFilter(angle);

  // Print to Serial
  Serial.print("Angle: ");
  Serial.println(angle, 2);

  // Display on TFT
  tft.fillRect(20, SCREEN_H / 2 + 20, 200, 40, TFT_BLACK);  // Clear previous value
  tft.setCursor(20, SCREEN_H / 2 + 20);
  tft.printf("%.2f°", angle);

  delay(50);  // 20 Hz update rate
}

Can you please help me find out what went wrong

[Bodmer]

Decause the TFT does not have a CS pin it cannot share the SPI bus with other perihperals.

The CS (chip select, also known as SS ie Slave Select) line controls which peripheral (TFT or angle sensor in this case) should use the bus. Because the TFT does not have an accessible one it will be low and permanently selected on the circuit board. This means the TFT will always drive the bus and always accept all commands on the SPI bus. There is nothing the library can do to fix this. Either use a TFT with a CS signal or move the TFT (or angle sensor) to the second HSPI SPI bus on different signal pins.

More info about the SPI bus here:
https://en.wikipedia.org/wiki/Serial_Peripheral_Interface

[Nethan325]

Thank you for the clarification.

[elirahman]

Hi..
I have similiar issue. but in my case I'm using LCD TFT ST7789 and IC Flash memory W25Q128. I using ESP32S3 BPi Pico-S3.
In my case, the LCD can work properly, but i failed read data from Flash memory, and make the ESP32 Stack. I try modified User_setup.h file , and i uncomment #define TFT_SPI_OVERLAP. The result i can read Flash memory, but the LCD not displaying anything.
I check my module LCD TFT and yess, the CS PIN connected to GND. According to your suggestion to using LCD with dedicated CS Pin, I modified my LCD module. I cut the CS Pin line from GND line and re-route/jumper the CS Pin to ESP32 GPIO. my LCD CS in pin number 42 and FLASH CS in pin number 4.
The result, my LCD Work properly but i still cannot read data from Flash memory.

FYI. i trying using another Library from Adafruit. (<Adafruit_ST7789.h>). Using this library, LCD can Work properly and i Can read/write Flash memory. Before I jumper CS Pin LCD direct to ESP32, LCD alwasy flickering when read/write Flash memory. after I modified the CS pin, no flickcering anymore. It mean my modified work fine.
But, in the next time, i still want to use library TFT eSPI because support of another library like TFT eWidget.

Can you help me please to find what's wrong.

Thank You

[Bodmer]

The TFT has to be on a different SPI bus to the FLASH. Which SPI bus is the FLASH connected to?

[elirahman]

The TFT has to be on a different SPI bus to the FLASH. Which SPI bus is the FLASH connected to?

SPI Bus LCD and Flash memori in same line. different CS Pin. I use single SPI bus because the other GPIO is already in use
MOSI --> GPIO_11
MISO --> GPIO_13
SCK --> GPIO_12
LCD_RES --> GPIO_47
LCD_DC --> GPIO_17
LCD_CS --> GPIO_42
FLASH_CS --> GPIO_04