dotfiles/flake.nix at main · AsPulse/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
{
  description = "AsPulse's public dotfiles";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    nixpkgs-module.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    neovim-nightly-overlay.url = "github:nix-community/neovim-nightly-overlay";
    claude-code-nix.url = "github:sadjow/claude-code-nix";
    lazygit.url = "github:jesseduffield/lazygit";
    flake-utils.url = "github:numtide/flake-utils";
    opencode.url = "github:anomalyco/opencode";
    herdr.url = "github:ogulcancelik/herdr/v0.7.3";
    # skills/tellur-authoring を取り込むためだけの入力なので flake としては評価しない。
    tellur.url = "github:comnipl/tellur";
    tellur.flake = false;
    nix-index-database.url = "github:nix-community/nix-index-database";
    nix-index-database.inputs.nixpkgs.follows = "nixpkgs-module";
    llm-agents.url = "github:numtide/llm-agents.nix";
  };

  outputs =
    {
      self,
      nixpkgs,
      nixpkgs-module,
      flake-utils,
      neovim-nightly-overlay,
      lazygit,
      claude-code-nix,
      opencode,
      herdr,
      tellur,
      nix-index-database,
      llm-agents,
      ...
    }:
    let
      overlays = [
        neovim-nightly-overlay.overlays.default
        lazygit.overlays.default
      ];

    in
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };
        pkgs-module = import nixpkgs-module {
          inherit system overlays;
          config.allowUnfree = true;
        };

      in
      {
        packages.zellij = pkgs.zellij;

        formatter = pkgs.writeShellApplication {
          name = "aspulse-dotfiles-formatter";
          runtimeInputs = with pkgs; [
            stylua
            nixfmt-rfc-style
          ];
          text = ''
            stylua --glob '**/*.lua' neovim
            fd "$@" -t f -e nix -x nixfmt '{}'
          '';
        };

        checks.formatting-neovim =
          pkgs.runCommand "check-neovim-formatting"
            {
              buildInputs = with pkgs; [ stylua ];
              src = self;
            }
            ''
              cd $src
              stylua --check --glob '**/*.lua' neovim
              touch $out
            '';

        checks.formatting-nix =
          pkgs.runCommand "check-nix-formatting"
            {
              buildInputs = with pkgs; [
                nixfmt-rfc-style
                fd
                gitMinimal
              ];
              src = self;
            }
            ''
              cp -r --no-preserve=mode $src src
              cd src
              git init --quiet && git add .
              fd "$@" -t f -e nix -x nixfmt '{}'
              if ! git diff --exit-code; then
                exit 1
              fi
              touch $out
            '';

        desktopModules =
          { ... }@args:
          import ./desktop/configuration.nix (
            args
            // {
              pkgs = pkgs-module;
            }
          );

        homeModules =
          { ... }@args:
          import ./home/home.nix (
            args
            // {
              pkgs = pkgs-module;
              inherit
                opencode
                claude-code-nix
                herdr
                tellur
                nix-index-database
                llm-agents
                ;
            }
          );
      }
    );
}