feat(string): ARK-292, add string:lstrip, string:rstrip and string:strip to remove whitespaces from strings

Author: SuperFola

String.ark

@@ -342,6 +342,57 @@
     (set _index (+ 1 _index)) })
   _output }))
 
+# _dir = 1 -> left to right, -1 -> right to left
+(let __strip_in_dir (fun (_str _dir)
+  (if (emptyOrWhitespace? _str)
+    ""
+    {
+      (mut _i (if (= 1 _dir) 0 (- (len _str) 1)))
+      (mut _whitespaces (or (= (@ _str _i) " ") (= (@ _str _i) "\t") (= (@ _str _i) "\n") (= (@ _str _i) "\r")))
+
+      (while (and _whitespaces (< _i (len _str)) (>= _i 0)) {
+        (let _c (@ _str _i))
+        (if (and (!= _c " ") (!= _c "\t") (!= _c "\n") (!= _c "\r"))
+          (set _whitespaces false)
+          (set _i (+ _dir _i))) })
+
+      (if (= 1 _dir)
+        (slice _str _i (len _str))
+        (slice _str 0 (+ 1 _i))) })))
+
+# @brief Removes whitespaces from the left side of a string
+# @details The original string isn't modified
+# @param _str string to sanitize
+# =begin
+# (import std.String)
+# (print (string:lstrip " a b c"))  # "a b c"
+# =end
+# @author https://github.com/SuperFola
+(let lstrip (fun (_str)
+  (__strip_in_dir _str 1)))
+
+# @brief Removes whitespaces from the right side of a string
+# @details The original string isn't modified
+# @param _str string to sanitize
+# =begin
+# (import std.String)
+# (print (string:rstrip " a b c     "))  # " a b c"
+# =end
+# @author https://github.com/SuperFola
+(let rstrip (fun (_str)
+  (__strip_in_dir _str -1)))
+
+# @brief Removes whitespaces from both sides of a string
+# @details The original string isn't modified
+# @param _str string to sanitize
+# =begin
+# (import std.String)
+# (print (string:strip " a b c    "))  # "a b c"
+# =end
+# @author https://github.com/SuperFola
+(let strip (fun (_str)
+  (rstrip (lstrip _str))))
+
 # @brief Strip the margin of a multiline string
 # @param _str multiline string, margin is (space)*(|)
 # =begin

tests/string-tests.ark

@@ -61,6 +61,25 @@
     (test:eq "hello" (string:join ["hello"] ";"))
     (test:eq "" (string:join [] ";;"))
 
+    (test:eq "abc" (string:lstrip "abc"))
+    (test:eq "abc" (string:lstrip " \t\n\rabc"))
+    (test:eq "abc \t\n\r" (string:lstrip "abc \t\n\r"))
+    (test:eq "" (string:lstrip ""))
+    (test:eq "" (string:lstrip " \t\n\r"))
+
+    (test:eq "abc" (string:rstrip "abc"))
+    (test:eq "abc" (string:rstrip "abc \t\n\r"))
+    (test:eq " \t\n\rabc" (string:rstrip " \t\n\rabc"))
+    (test:eq "" (string:rstrip ""))
+    (test:eq "" (string:rstrip " \t\n\r"))
+
+    (test:eq "abc" (string:strip "\t\n\r abc \t\n\r"))
+    (test:eq "" (string:strip "\t\n\r "))
+    (test:eq "abc" (string:strip "abc"))
+    (test:eq "" (string:strip ""))
+    (test:eq "abc" (string:strip " \t\n\rabc"))
+    (test:eq "abc" (string:strip "abc \t\n\r"))
+
     (test:eq "" (string:stripMargin ""))
     (test:eq "   hello" (string:stripMargin "   hello"))
     (test:eq "hello" (string:stripMargin "   |hello"))